Come trovare la posizione del primo/ultimo numero in una stringa di testo in Excel?

Ad esempio, hai un elenco di stringhe di testo che sono una combinazione di lettere e numeri. Se vuoi trovare la posizione del primo o dell'ultimo numero in ogni stringa, cosa faresti? In realtà, utilizzare una formula ti aiuterà a trovare rapidamente la posizione del primo/ultimo numero in una stringa di testo specificata. In questo tutorial, ti mostreremo i dettagli su come affrontare questo problema.

Trova la posizione del primo numero in una stringa di testo in Excel
Trova la posizione dell'ultimo numero in una stringa di testo in Excel

Trova la posizione del primo numero in una stringa di testo in Excel

Come mostrato nello screenshot sottostante, per trovare le posizioni dei primi numeri nelle stringhe di testo, procedi nel seguente modo.

1. Seleziona la cella B2, copia e incolla una delle seguenti formule nella Barra delle formule:

1). Formula 1: =MIN(SEARCH({0,1,2,3,4,5,6,7,8,9},A2&"0123456789"));

2). Formula 2: =MATCH(TRUE,ABS(CODE(MID(A2,ROW($A$1:INDEX(A:A,LEN(A2))),1))-52.5)<5,0) + Ctrl + Shift + Enter;

3). Formula 3: =MIN(IF(ISERROR(FIND({1;2;3;4;5;6;7;8;9;0},A2)),"",FIND({1;2;3;4;5;6;7;8;9;0},A2))).

2. Quindi la posizione del primo numero della prima stringa viene visualizzata nella cella B2. Ora trascina la maniglia di riempimento fino alla cella B7 per riempire l'intervallo sottostante.

Verranno quindi elencate tutte le posizioni dei primi numeri di tutte le stringhe.

Trova la posizione dell'ultimo numero in una stringa di testo in Excel

Dopo aver trovato la posizione del primo numero, ora iniziamo a trovare la posizione dell'ultimo numero nelle stringhe.

In questa sezione, ci sono due formule per te.

Formula 1: =MAX(IF(ISNUMBER(VALUE(MID(A2,ROW(INDIRECT("1:" & LEN(A2))),1))),ROW(INDIRECT("1:" & LEN(A2))))) + Ctrl + Shift + Enter;

Formula 2: =MAX(IFERROR(FIND({1,2,3,4,5,6,7,8,9,0},A2,ROW(INDIRECT("1:"&LEN(A2)))),0)) + Ctrl + Shift + Enter

1. Seleziona la cella B2, copia e incolla una delle formule sopra nella Barra delle formule, quindi premi contemporaneamente i tasti Ctrl + Shift + Enter. Quindi puoi vedere il risultato visualizzato in B2.

2. Seleziona la cella B2, trascina la maniglia di riempimento fino alla cella B7 per riempire automaticamente l'intervallo.

Ora vedrai le posizioni degli ultimi numeri in ciascuna stringa di testo.

Articoli correlati:

• Come trovare le prime celle vuote in una colonna in Excel?
• Come trovare celle con formattazione condizionale in Excel?
• Come trovare celle con convalida dati in Excel?