Come contare i valori univoci in base a più criteri in Excel?

In questo articolo, vi mostrerò alcuni esempi per contare i valori univoci in base a uno o più criteri in una scheda di lavoro. I seguenti passaggi dettagliati potrebbero esservi utili.

Conta i valori univoci in base a un criterio

Conta i valori univoci in base a due date specificate

Conta i valori univoci in base a due criteri

Conta i valori univoci in base a tre criteri

Conta i valori univoci in base a un criterio

Ad esempio, ho il seguente intervallo di dati e ora voglio contare i prodotti univoci venduti da Tom.

Inserisci questa formula in una cella vuota dove desideri ottenere il risultato, ad esempio G2:

=SOMMA(SE("Tom"=$C$2:$C$20; 1/(CONTA.PIÙ.SE($C$2:$C$20; "Tom"; $A$2:$A$20; $A$2:$A$20)); 0)), quindi premi contemporaneamente i tasti Maiusc + Ctrl + Invio per ottenere il risultato corretto, vedi screenshot:

Nota: Nella formula sopra, “Tom” è il criterio del nome in base al quale vuoi contare, C2:C20 sono le celle che contengono il criterio del nome, A2:A20 sono le celle in cui vuoi contare i valori univoci.

Conta i valori univoci in base a due date specificate

Per calcolare i valori univoci tra due date specificate, ad esempio, voglio contare i prodotti univoci nell'intervallo di date dal 01/09/2016 al 30/09/2016, applica questa formula:

=SOMMA(SE($D$2:$D$20<=DATA(2016; 9; 30)*($D$2:$D$20>=DATA(2016; 9; 1)); 1/CONTA.PIÙ.SE( $A$2:$A$20; $A$2:$A$20; $D$2:$D$20; "<="&DATA(2016; 9; 30);$D$2:$D$20; ">="&DATA(2016; 9; 1))); 0), quindi premi contemporaneamente i tasti Maiusc + Ctrl + Invio per ottenere il risultato univoco, vedi screenshot:

Nota: Nella formula sopra, le date 01/09/2016 e 30/09/2016 sono la data di inizio e la data di fine in base alle quali vuoi contare, D2:D20 sono le celle che contengono il criterio della data, A2:A20 sono le celle in cui vuoi contare i valori univoci.

Conta i valori univoci in base a due criteri

Se vuoi contare i prodotti univoci venduti da Tom a Settembre, la seguente formula può aiutarti.

Inserisci questa formula in una cella vuota per ottenere il risultato, ad esempio H2.

=SOMMA(SE(("Tom"=$C$2:$C$20)*($D$2:$D$20<=DATA(2016; 9; 30)*($D$2:$D$20>=DATA(2016; 9; 1))); 1/CONTA.PIÙ.SE($C$2:$C$20; "Tom"; $A$2:$A$20; $A$2:$A$20; $D$2:$D$20; "<="&DATA(2016; 9; 30);$D$2:$D$20; ">="&DATA(2016; 9; 1))); 0) quindi premi contemporaneamente i tasti Maiusc + Ctrl + Invio per ottenere il risultato univoco, vedi screenshot:

Note:

1. Nella formula sopra, “Tom” è il criterio del nome, 01/09/2016 e 30/09/2016 sono le due date in base alle quali vuoi contare, C2:C20 sono le celle che contengono il criterio del nome, D2:D20 sono le celle che contengono la data, A2:A20 è l'intervallo di celle in cui vuoi contare i valori univoci.

2. Se hai bisogno di usare un criterio “o” per contare i valori univoci, ad esempio, calcolare i prodotti venduti da Tom o nella regione Sud, applica questa formula:

=SOMMA(--(FREQUENZA(SE(("Tom"=$C$2:$C$20)+("Sud"=$B$2:$B$20); CONTA.SE($A$2:$A$20; "<"&$A$2:$A$20); ""); CONTA.SE($A$2:$A$20; "<"&$A$2:$A$20))>0)), e ricorda di premere contemporaneamente i tasti Maiusc + Ctrl + Invio per ottenere il risultato univoco, vedi screenshot:

Conta i valori univoci in base a tre criteri

Per contare i prodotti univoci con tre criteri, la formula potrebbe essere più complessa. Ad esempio, calcolare i prodotti univoci venduti da Tom a Settembre e nella regione Nord. Procedi come segue:

Inserisci questa formula in una cella vuota per ottenere il risultato, ad esempio I2:

=SOMMA(SE(("Tom"=$C$2:$C$20)*($D$2:$D$20<=DATA(2016; 9; 30))*($D$2:$D$20>=DATA(2016; 9; 1))*("Nord"=$B$2:$B$20); 1/CONTA.PIÙ.SE($C$2:$C$20; "Tom"; $A$2:$A$20; $A$2:$A$20; $D$2:$D$20; "<="&DATA(2016; 9; 30); $D$2:$D$20; ">="&DATA(2016; 9; 1); $B$2:$B$20; "Nord")); 0), quindi premi contemporaneamente i tasti Maiusc + Ctrl + Invio per ottenere il risultato univoco, vedi screenshot: