Come spostare file specifici da una cartella a un'altra in Excel?

Supponiamo di avere una cartella grande che contiene diversi tipi di file, come docx, jpg, xlsx, ecc., come mostrato nello screenshot seguente. Ora voglio spostare alcuni tipi di file specifici dalla cartella a una nuova cartella senza doverli spostare uno per uno manualmente. Avete qualche buona idea per risolvere questo compito in Excel?

Sposta file specifici da una cartella a un'altra con il codice VBA

Sposta file specifici da una cartella a un'altra con il codice VBA

Per spostare tutti i tipi specifici di file da una cartella a un'altra nel modo più rapido possibile, il seguente codice VBA potrebbe esserti utile, procedi come segue:

1. Tieni premuti i tasti ALT + F11 per aprire la finestra Microsoft Visual Basic for Applications.

2. Clicca su Inserisci > Modulo e incolla il seguente codice nella finestra del Modulo.

Codice VBA: Sposta tipi specifici di file da una cartella a un'altra:

Sub MoveFiles()
'Updateby Extendoffice
    Dim xFd As FileDialog
    Dim xTFile As String
    Dim xExtArr As Variant
    Dim xExt As Variant
    Dim xSPath As String
    Dim xDPath As String
    Dim xSFile As String
    Dim xCount As Long
    Set xFd = Application.FileDialog(msoFileDialogFolderPicker)
    xFd.Title = "Please select the original folder:"
    If xFd.Show = -1 Then
        xSPath = xFd.SelectedItems(1)
    Else
        Exit Sub
    End If
    If Right(xSPath, 1) <> "\" Then xSPath = xSPath + "\"
    xFd.Title = "Please select the destination folder:"
    If xFd.Show = -1 Then
        xDPath = xFd.SelectedItems(1)
    Else
        Exit Sub
    End If
    If Right(xDPath, 1) <> "\" Then xDPath = xDPath + "\"
    xExtArr = Array("*.xlsx*", "*.jpg")
    For Each xExt In xExtArr
        xTFile = Dir(xSPath & xExt)
        Do While xTFile <> ""
            xSFile = xSPath & xTFile
            FileCopy xSFile, xDPath & xTFile
            Kill xSFile
            xTFile = Dir
            xCount = xCount + 1
        Loop
    Next
    MsgBox "Total number of moved files is: " & xCount, vbInformation, "Kutools for Excel"
End Sub

Nota: Nel codice sopra, "*.xlsx*", "*.jpg" nello script: xExtArr = Array("*.xlsx*", "*.jpg") sono i tipi di file che vuoi spostare, puoi cambiarli con altri o aggiungere altri tipi di file secondo necessità.

3. Quindi premi il tasto F5 per eseguire questo codice, e apparirà una finestra che ti ricorda di selezionare la cartella di origine da cui vuoi spostare i file, vedi screenshot:

4. Poi clicca OK, e apparirà un'altra finestra, scegli la cartella di destinazione in cui vuoi spostare i file, vedi screenshot:

5. Dopodiché clicca OK, apparirà una finestra di avviso che ti informa quanti file sono stati spostati, chiudila, e vedrai che i file jpg, xlsx specifici sono stati spostati nella cartella designata, vedi screenshot: