Come eseguire più macro dal menu di scelta rapida in Excel?

Se ci sono più macro VBA nella tua cartella di lavoro, devi aprire la finestra VBA e poi scegliere la macro quando hai bisogno di eseguire il codice. In questo articolo, vorrei parlare di come eseguire le macro dal menu di scelta rapida per rendere il tuo lavoro più efficiente, come mostrato nello screenshot a sinistra.

Esegui più macro dal menu di scelta rapida con codici VBA

Esegui più macro dal menu di scelta rapida con codici VBA

Per eseguire i codici delle macro all'interno di una cartella di lavoro dal menu di scelta rapida, i seguenti passaggi potrebbero esserti utili, procedi come segue:

1. Tieni premuti i tasti Alt + F11 per aprire la finestra Microsoft Visual Basic for Applications.

2. Dopodiché, fai doppio clic su ThisWorkbook nel riquadro Progetto a sinistra, quindi copia e incolla il seguente codice VBA nel modulo vuoto.

Private Sub Workbook_Open()
Run "LoadMacro"
End Sub
Private Sub Workbook_Activate()
Run "LoadMacro"
End Sub
Private Sub Workbook_Deactivate()
Run "ClearMacro"
End Sub
Private Sub Workbook_BeforeClose(Cancel As Boolean)
Run "ClearMacro"
ThisWorkbook.Save
End Sub

3. Ancora nella finestra Microsoft Visual Basic for Applications, fai clic su Inserisci > Modulo, e incolla il seguente codice in questo modulo.

Private Sub LoadMacro()
Dim xArrMenu As Variant
Dim xStrLine, xSreBtnName As String
Dim xObjCBCF, xObjCntrAll As CommandBarControl
Dim xObjCBCs As CommandBars
Dim xObjCBBtn As CommandBarButton
Dim xIntLine, xFNum As Integer
Dim xObjComponent As Object
Run "ClearMacro"
Set xObjCBCF = Application.CommandBars("Cell").Controls.Add(msoControlPopup, before:=1)
xObjCBCF.Caption = " Run Macro "
xObjCBCF.BeginGroup = False
For Each xObjComponent In ActiveWorkbook.VBProject.VBComponents
    If xObjComponent.Type = 1 Then
        For xIntLine = 1 To xObjComponent.CodeModule.CountOfLines
        xStrLine = xObjComponent.CodeModule.Lines(xIntLine, 1)
        xStrLine = Trim(xStrLine)
            If (InStr(xStrLine, "()") > 0) And (Left(xStrLine, 11) = "Private Sub" Or Left(xStrLine, 3) = "Sub") Then
            xSreBtnName = ""
            If "Private Sub" = Left(xStrLine, 11) Then
                xSreBtnName = Trim(Mid(xStrLine, 12, InStr(xStrLine, "()") - 12))
            ElseIf "Sub" = Left(xStrLine, 3) Then
               xSreBtnName = Trim(Mid(xStrLine, 4, InStr(xStrLine, "()") - 4))
            End If
            If xSreBtnName <> "" And xSreBtnName <> "RightClickReset" And xSreBtnName <> "LoadMacro" And xSreBtnName <> "ActionMacro" Then
                Set xObjCBBtn = xObjCBCF.Controls.Add
                With xObjCBBtn
                    .FaceId = 186
                    .Style = msoButtonIconAndCaption
                    .Caption = xSreBtnName
                    .OnAction = "ActionMacro"
                End With
            End If
            End If
        Next xIntLine
    End If
Next xObjComponent
End Sub
Private Sub ClearMacro()
On Error Resume Next
CommandBars("Cell").Controls(" Run Macro ").Delete
Err.Clear
CommandBars("Cell").Reset
End Sub
Private Sub ActionMacro()
On Error GoTo Err1
With Application
Run .CommandBars("Cell").Controls(1).Controls(.Caller(1)).Caption
End With
Exit Sub
Err1:
    MsgBox "Invalid"
End Sub

4. Dopo aver incollato i codici, fai clic su Strumenti > Riferimenti, e verrà visualizzata una finestra di dialogo Riferimenti-VBAProject; quindi seleziona l'opzione Microsoft Visual Basic for Applications Extensibility 5.3 nella casella di riferimenti disponibili, vedi screenshot:

5. Quindi fai clic su OK per uscire dalla finestra di dialogo, ora dovresti salvare questa cartella di lavoro in formato Cartella di lavoro con Macro di Excel, vedi screenshot:

6. Infine, riavvia la cartella di lavoro per rendere effettivi i codici, e ora, quando fai clic con il tasto destro su una cella, un'opzione Esegui Macro viene inserita nel menu di scelta rapida, e tutte le macro della tua cartella di lavoro sono elencate nel sottomenu come mostrato nello screenshot seguente:

7. A questo punto puoi eseguire il codice semplicemente facendoci clic sopra.