FUNZIONE CONTA.SE di EXCEL – Conta celle che non sono vuote, maggiori/minori di, o contengono un valore specifico

Author: Amanda Li Last Modified: 2025-05-30

Quando si lavora su un foglio di lavoro Excel, contare il numero di celle, come ad esempio contare celle vuote o non vuote, celle maggiori o minori di un determinato valore, o celle che contengono un testo specifico, può essere un compito comune per molti di noi. Per gestire questi calcoli, la funzione CONTA.SE in Excel potrebbe esserti d'aiuto.

Sintassi della funzione CONTA.SE in Excel

Funzione CONTA.SE per celle vuote o non vuote

Conta celle vuote con la funzione CONTA.SE
Conta celle non vuote con la funzione CONTA.SE
Conta celle non vuote con due clic

Funzione CONTA.SE per celle minori di, maggiori di o uguali a un valore specifico

CONTA.SE minore di, maggiore di, uguale a o diverso da con formule
CONTA.SE minore di, maggiore di, uguale a o diverso da con pochi clic

Funzione CONTA.SE per celle che contengono un valore specifico

Conta celle contenenti parole o caratteri specifici con la funzione CONTA.SE
Conta celle contenenti parole o caratteri specifici con pochi clic

Sintassi della funzione CONTA.SE in Excel

Come una delle funzioni statistiche in Excel, CONTA.SE conta le celle che soddisfano criteri specificati in un intervallo definito. La sintassi della funzione CONTA.SE è:

=CONTA.SE(intervallo; criteri)

La sintassi contiene due argomenti – intervallo e criteri:

intervallo: si riferisce all'intervallo di celle che desideri contare.
criteri: si riferisce alla condizione che desideri utilizzare per contare le celle. Ad esempio, puoi usare “>=80” come criterio per cercare le celle con valori maggiori o uguali a 80 nell'intervallo selezionato.

Per applicare la funzione in Excel, dovresti digitare =CONTA.SE(intervallo; criteri) in una cella di destinazione. Ad esempio, =CONTA.SE(A1:B8;">=80").

La funzione CONTA.SE restituisce un valore numerico – il numero di celle che volevi contare.

Ora che abbiamo una comprensione più chiara della funzione CONTA.SE, procediamo con alcuni esempi pratici.

Funzione CONTA.SE per celle vuote o non vuote

Ad esempio, ho un elenco di celle che contengono diversi tipi di dati, come testo, valori booleani (VERO e FALSO), numeri, date ed errori. Esiste una formula CONTA.SE universale per contare solo le celle vuote o non vuote indipendentemente dai tipi di dati presenti nel tuo intervallo specificato?

Conta celle vuote con la funzione CONTA.SE

Ora, lascia che ti presenti la formula CONTA.SE. Con questa formula, indipendentemente da quanti tipi di dati siano presenti nell'intervallo, ti fornirà il numero esatto e corretto delle celle vuote:

=CONTA.SE(intervallo;"")
√ Nota: Non c'è alcun testo tra virgolette, il che significa che le celle che vuoi contare sono vuote.

Per utilizzare la funzione CONTA.SE per contare le celle vuote, digita la formula =CONTA.SE(A1:A9;"") in una cella di destinazione, quindi premi INVIO:

>>>

☞ In Excel, esiste anche una funzione chiamata CONTA.VUOTE, che restituisce il numero di celle vuote in un intervallo specificato. La sua sintassi è =CONTA.VUOTE(intervallo). Per l'esempio sopra, puoi usare la formula: =CONTA.VUOTE(A1:A9).

Conta celle non vuote con la funzione CONTA.SE

Per contare le celle che non sono vuote, ecco la formula:

=CONTA.SE(intervallo;"<>")
√ Nota: <> in Excel significa diverso da. Quindi, la formula sopra conta tutte le celle che sono diverse da vuoto, o possiamo dire, non vuote.

Per utilizzare la funzione CONTA.SE per contare le celle che non sono vuote, digita la formula =CONTA.SE(A1:A9;"<>") in una cella di destinazione, quindi premi INVIO:

Count non-blank cells with COUNTIF function

>>>

☞ In Excel, esiste anche una funzione chiamata CONTA.VALORI, che restituisce il numero di celle contenenti qualsiasi valore in un intervallo specificato. La sua sintassi è =CONTA.VALORI(intervallo). Per l'esempio sopra, puoi usare la formula: =CONTA.VALORI(A1:A9).

Tuttavia, se vuoi contare solo le celle con testo ed escludere i valori booleani (VERO e FALSO), numeri, date o errori, utilizza la seguente formula:

=CONTA.SE(A1:A9;"*")
√Nota: Un singolo asterisco (*) corrisponde solo al valore in formato testuale.

count cells with only text with COUNTIF function

>>>

Conta celle non vuote con due clic

Se hai installato Kutools per Excel nel tuo Excel, con la sua funzionalità Seleziona Celle Non Vuote, puoi selezionare tutte le celle non vuote in una volta sola e ottenere il numero di cui hai bisogno.

Kutools per Excel offre oltre 300 funzionalità avanzate per semplificare compiti complessi, aumentando creatività ed efficienza. Integrato con capacità di intelligenza artificiale, Kutools automatizza le attività con precisione, rendendo la gestione dei dati senza sforzo. Informazioni dettagliate su Kutools per Excel... Prova gratuita...

1. Puoi andare alla scheda Kutools in Excel, trovare Seleziona, e fare clic su Seleziona Celle Non Vuote dall'elenco a discesa. Vedi screenshot:

2. Tutte le celle non vuote verranno selezionate e apparirà una finestra pop-up per informarti il numero di celle non vuote come mostrato nello screenshot qui sotto:

Clicca per scaricare Kutools per Excel per una prova gratuita di 30 giorni.

Funzione CONTA.SE per celle minori di, maggiori di o uguali a un valore specifico

Qui abbiamo elencato due metodi principali per contare le celle con valori minori di, maggiori di, uguali a o diversi da un valore specifico in Excel.

CONTA.SE minore di, maggiore di, uguale a o diverso da con formule

Per utilizzare una formula per contare le celle con valori minori di, maggiori di, uguali a o diversi da un valore specifico, devi fare buon uso degli Operatori di Confronto (<, >, =, ≠).

√ Nota: Il metodo può essere utilizzato anche per contare le celle con date precedenti (minore di <), successive (maggiore di >) o uguali a (=) la data che specifichi.

Ora, diamo un'occhiata ad alcuni esempi reali in base alla tabella sottostante:

Per contare il numero di studenti il cui punteggio totale è superiore a (>) 140, usa la formula:
=CONTA.SE(E2:E8;">140") >>> Il risultato è 5

Per contare il numero di studenti il cui punteggio di matematica è inferiore a (<) il punteggio di Coco (il valore nella cella D3), usa la formula:
=CONTA.SE(D2:D8;"<"&D3) >>> Il risultato è 2
√ Nota: Per utilizzare un riferimento di cella nella funzione CONTA.SE con operatori di confronto, dovrai inserire gli operatori tra virgolette e aggiungere una e commerciale (&) prima del riferimento di cella.

Per contare il numero di studenti il cui punteggio di inglese è maggiore o uguale a (≥) il punteggio di Eddie (il valore nella cella C4), usa la formula:
=CONTA.SE(C2:C8;">="&C4)-1 >>> Il risultato è 5
√ Nota: Il motivo per sottrarre 1 è che i criteri C2:C8;">="&C4 chiedono a CONTA.SE di contare tutte le celle corrispondenti, inclusa quella con il punteggio di inglese di Eddie, quindi dobbiamo sottrarla dalla formula. Se hai bisogno di includere Eddie, elimina “-1” dalla formula.

Per contare il numero di studenti che provengono da (=) India, usa la formula:
=CONTA.SE(B2:B8;"India") OPPURE =CONTA.SE(B2:B8;B2) >>> Il risultato è 3
√ Nota: Il valore nel riferimento di cella B2 è India, quindi sia “India” che B2 funzionano bene come criteri qui. Nella funzione CONTA.SE, i criteri sono non fanno distinzione tra maiuscole e minuscole. Quindi, la stringa “India” e “INDIA” non faranno differenza nel risultato della formula.

Per contare il numero di studenti che non provengono da (≠) India, usa la formula:
=CONTA.SE(B2:B8;"<>India") OPPURE =CONTA.SE(B2:B8;"<>"&B2) >>> Il risultato è 4

☞ La funzione CONTA.SE funziona solo quando c'è una condizione; per situazioni con più condizioni, dovresti utilizzare la funzione CONTA.PIÙ.SE. Ad esempio, per contare il numero di studenti il cui punteggio di inglese è compreso tra 60 e 90 (>60, <90), usa la formula: =CONTA.PIÙ.SE(B2:B8;">60";B2:B8;"<90").
Clicca per saperne di più sulla funzione CONTA.PIÙ.SE…

CONTA.SE minore di, maggiore di, uguale a o diverso da con pochi clic

Per contare le celle con valori minori di, maggiori di, uguali a o diversi da un valore specifico in modo più conveniente, puoi applicare la funzionalità Seleziona Celle Specifiche di Kutools per Excel.

Dopo aver installato Kutools per Excel, segui i seguenti passaggi:

1. Trova la scheda Kutools, vai su Seleziona, e fai clic su Seleziona Celle Specifiche dall'elenco a discesa.

2. Ora vedrai una finestra pop-up, segui quanto segue:

Di seguito è riportato un esempio per contare il numero di studenti il cui punteggio di matematica è inferiore a (<) il punteggio di Coco con Kutools.

√ Nota: Il programma restituirà il risultato del conteggio e selezionerà le celle che soddisfano i tuoi criteri. Puoi copiarle se necessario.

Clicca per scaricare Kutools per Excel per una prova gratuita di 30 giorni.

Funzione CONTA.SE per celle che contengono un valore specifico

Per utilizzare CONTA.SE per contare le celle che contengono un valore specifico (ad esempio le celle con la lettera Y), o addirittura per contare le celle con un valore specifico in una posizione specifica (ad esempio le celle che iniziano con la lettera Y), dobbiamo conoscere i caratteri jolly.

Ci sono tre caratteri jolly - asterisco (*), punto interrogativo (?) e tilde (~) disponibili in Excel per la funzione CONTA.SE:

• Asterisco (*) - Corrisponde a qualsiasi numero di caratteri. Ad esempio, *ice potrebbe significare nice, service, ice, @#$ice, ecc.
• Punto interrogativo (?) - Corrisponde a qualsiasi singolo carattere. Ad esempio, mo?? potrebbe significare more, moon, mo&%, moaa, ecc.
• Tilde (~) - Corrisponde al carattere jolly effettivo. Ad esempio, ~* significa un asterisco letterale, ~~ significa una tilde letterale.

√ Nota: I valori booleani (VERO e FALSO), numeri, date ed errori non sono contati come caratteri. Quindi, se ci sono elementi sopra indicati nell'intervallo di celle selezionato, sarà necessario convertirli in testo.

☞ Ulteriori informazioni:
Come Cambiare O Convertire Numero In Testo In Excel?
Come Convertire Data In Stringa Numerica O Formato Testo In Excel?
Come Sostituire Gli Errori Di Formula # Con 0, Vuoto O Testo Specifico In Excel?
Come Convertire Booleano Vero/Falso In Numero (1/0) O Testo In Excel?

Conta celle contenenti parole o caratteri specifici con la funzione CONTA.SE

Poiché già conosciamo i caratteri jolly, è tempo di imparare come utilizzare una formula CONTA.SE per contare le celle che contengono caratteri o parole specifici. Vediamo gli esempi seguenti:

Per contare il numero di ragazzi nella classe, usa la formula:
=CONTA.SE(B2:B9;"MASCHIO") >>> Il risultato è 5

Per contare il numero di nomi che contengono i caratteri “jeff” (il valore nella cella A6), usa la formula:
=CONTA.SE(A2:A9;"*jeff*") OPPURE =CONTA.SE(A2:A9;"*"&A6&"*") >>> Il risultato è 2

Per contare il numero di nomi che contengono la lettera “e”, usa la formula:
=CONTA.SE(A2:A9;"*e*") >>> Il risultato è 5

Per contare il numero di nomi che non contengono la lettera “e”, usa la formula:
=CONTA.SE(A2:A9;"<>*e*") >>> Il risultato è 3

Per contare il numero di nomi che iniziano con la lettera “e”, usa la formula:
=CONTA.SE(A2:A9;"e*") >>> Il risultato è 2

Per contare il numero di nomi che terminano con la lettera “e”, usa la formula:
=CONTA.SE(A2:A9;"*e") >>> Il risultato è 1

Per contare il numero di nomi con la lettera “m” come terzo carattere, usa la formula:
=CONTA.SE(A2:A9;"??m*") >>> Il risultato è 2

Conta celle contenenti parole o caratteri specifici con pochi clic

Con il nostro componente aggiuntivo Excel installato, procedi come segue:

1. Vai alla scheda Kutools, trova Seleziona, e fai clic su Seleziona Celle Specifiche dall'elenco a discesa.

2. Nella finestra di dialogo Seleziona Celle Specifiche, seleziona l'intervallo di celle che desideri contare, quindi fai clic su Cella sotto Tipo di selezione, scegli una condizione dall'elenco a discesa del Tipo specifico in base alle tue esigenze.

Qui, ti darò due esempi di utilizzo di Kutools per contare le celle che contengono parole o caratteri specifici.

• Per contare il numero di ragazzi nella classe, fai clic Uguale a nell'elenco a discesa, e digita Maschio nella casella di input a destra, oppure puoi selezionare una cella con il valore “Maschio” nel foglio di lavoro facendo clic pulsante.

Il programma restituirà il risultato del conteggio e selezionerà le celle che soddisfano i tuoi criteri. Puoi copiarle se necessario.

• Per contare il numero di nomi che contengono i caratteri “jeff”, fai clic Contiene nell'elenco a discesa, e digita jeff, oppure puoi selezionare la cella A6 nel foglio di lavoro facendo clic pulsante.