Skip to main content

Come creare una lista dinamica dei primi 10 o n elementi in Excel?

Author: Xiaoyang Last Modified: 2025-05-30

Una classifica viene utilizzata per ordinare aziende o individui in base ai valori. Supponiamo di avere un elenco dei voti degli studenti di una classe e ora si desidera creare una lista dinamica dei primi 10 studenti, come mostrato nello screenshot sottostante. In questo articolo, introdurrò alcune formule per creare una lista dei primi 10 o n elementi in un foglio di lavoro di Excel.

Crea una lista dinamica dei primi 10 elementi in Excel

In Excel 2019 e versioni precedenti, per estrarre la lista dei primi 10 elementi o la lista dei primi 10 elementi con criteri, è necessario applicare le seguenti formule:

Formule per creare una lista dinamica dei primi 10 elementi

1. Per prima cosa, estrai i primi 10 valori dall'intervallo dati, inserisci la seguente formula in una cella vuota - G2, e trascina il quadratino di riempimento verso il basso per ottenere i primi 10 valori, vedi screenshot:

=GRANDE($B$2:$B$20;RIGHE(B$2:B2))
Nota: In questa formula, B2:B20 è l'elenco di dati da cui vuoi ottenere i primi 10 valori, e B2 è la prima cella dell'elenco dati.

apply a formula to extract the top 10 values

2. Successivamente, applica la seguente formula nella cella F2 e premi contemporaneamente i tasti Ctrl + Maiusc + Invio per ottenere il primo risultato, vedi screenshot:

=INDICE($A$2:$A$20;PICCOLO(SE($B$2:$B$20=G2;RIF.RIGA($B$2:$B$20)-RIF.RIGA($B$1));CONTA.SE($G$2:G2;G2)))
Nota: Nella formula sopra, A2:A20 è l'elenco di dati da cui vuoi estrarre i nomi dei primi 10 valori, B2:B20 è l'elenco di dati che contiene tutti i valori, G2 è la cella del valore più grande estratto dalla colonna B e B1 è la cella di intestazione dell'elenco dei valori.

use a formula to get relative item

3. Dopo aver ottenuto il primo risultato, seleziona la cella della formula e trascina il quadratino di riempimento verso il basso per ottenere gli altri nomi immediatamente, vedi screenshot:

drag and fill the formula to other cells

a screenshot of kutools for excel ai

Sblocca la Magia di Excel con Kutools AI

  • Esecuzione Intelligente: Esegui operazioni sulle celle, analizza i dati e crea grafici — tutto guidato da semplici comandi.
  • Formule Personalizzate: Genera formule su misura per ottimizzare i tuoi flussi di lavoro.
  • Codifica VBA: Scrivi e implementa codice VBA senza sforzo.
  • Interpretazione delle Formule: Comprendi facilmente formule complesse.
  • Traduzione del Testo: Superare le barriere linguistiche all'interno dei tuoi fogli di calcolo.
Potenzia le tue capacità di Excel con strumenti alimentati dall'IA. Scarica Ora ed esperisci un'efficienza mai vista prima!
Formule per creare una lista dinamica dei primi 10 elementi con criteri

A volte potrebbe essere necessario ottenere la lista dei primi 10 elementi in base a determinati criteri. Ad esempio, per ottenere i primi 10 nomi e punteggi della Classe1, come mostrato nello screenshot sottostante.

create a dynamic top 10 list with criteria

1. Per ottenere la lista dei primi 10 elementi, è necessario estrarre i primi 10 punteggi con questa formula:

=GRANDE(SE($B$2:$B$25=$F$2;$C$2:$C$25);RIGA(I2)-RIGA(I$1))

2. Quindi premi contemporaneamente i tasti Ctrl + Maiusc + Invio per ottenere il primo risultato, quindi trascina questa formula verso il basso per visualizzare gli altri valori, vedi screenshot:

apply a formula to extract the top 10 values based on criteria

3. Successivamente, copia e incolla la seguente formula nella cella I2, e premi contemporaneamente i tasti Ctrl + Maiusc + Invio per estrarre il primo risultato, quindi trascina questa formula per riempire le altre celle, e verranno visualizzati i primi 10 nomi.

=INDICE($A$2:$A$25;PICCOLO(SE(($C$2:$C$25=J2)*($B$2:$B$25=$F$2);RIF.RIGA($C$2:$C$25)-RIF.RIGA($C$1));CONTA.SE(J2:$J$2;J2)))

Crea una lista dinamica dei primi 10 elementi in Office 365

Le formule sopra descritte possono essere difficili da comprendere; se stai utilizzando Office 365, con le sue funzioni INDICE, ORDINA e SEQUENZA, puoi creare formule semplici per completare questo compito.

Formula per creare una lista dinamica dei primi 10 elementi

Per ottenere la lista dei primi 10 elementi, utilizza la seguente formula:

=INDICE(ORDINA(A2:B20;2;-1);SEQUENZA(10);{1;2})

Quindi, premi semplicemente il tasto Invio, e tutti i dati della lista dei primi 10 elementi verranno visualizzati immediatamente, vedi screenshot:

use a formula to create a dynamic top 10 list in Office 365

Suggerimenti:

Funzione ORDINA:

=ORDINA(matrice; [indice_ordinamento]; [ordine_ordinamento]; [per_col])

  • matrice: L'intervallo di celle che desideri ordinare;
  • [indice_ordinamento]: Il numero della colonna o riga in base al quale ordinare l'array. Ad esempio, per ordinare in base alla seconda colonna dell'intervallo dati, l'indice di ordinamento sarebbe 2;
  • [ordine_ordinamento]: Il numero 1 (o omesso) indica di ordinare in ordine crescente; il numero -1, ordina in ordine decrescente;
  • [per_col]: La direzione di ordinamento. VERO, ordina per colonne, FALSO o omesso, ordina per righe.

Nella formula, utilizziamo la funzione ORDINA in questo modo:

ORDINA(A2:B20;2;-1): Significa ordinare l'intervallo di celle A2:A20 sulla seconda colonna in ordine decrescente.

Funzione SEQUENZA:

=SEQUENZA(righe; [colonne]; [inizio]; [passo])

  • righe: Il numero di righe da restituire,
  • [colonne]: Il numero di colonne da restituire. Se omesso, restituirà una singola colonna.
  • [inizio]: Il primo numero nella sequenza. Se omesso, inizierà da 1.
  • [passo]: L'incremento tra ogni numero. Se escluso, ogni incremento sarà di 1.

In questa formula, utilizziamo SEQUENZA(10) per creare una lista da 1 a 10.

Infine, inserisci entrambe le funzioni ORDINA e SEQUENZA nella funzione INDICE: =INDICE(ORDINA(A2:B20;2;-1);SEQUENZA(10);{1;2}), ciò restituirà i primi 10 record dall'intervallo dati e restituirà le colonne 1 e 2.

Formula per creare una lista dinamica dei primi 10 elementi con criteri

Per visualizzare la lista dei primi 10 elementi con criteri, devi incorporare la funzione FILTRO nella funzione ORDINA in questo modo:

=INDICE(ORDINA(FILTRO(A2:C25;B2:B25=F2);3;-1);SEQUENZA(10);{1;3})

E premi semplicemente il tasto Invio, tutti i dati della lista dei primi 10 elementi basati sui criteri forniti verranno visualizzati immediatamente, vedi screenshot:

another formula to create a dynamic top 10 list with criteria in office 365

Suggerimenti:

Funzione FILTRO:

=FILTRO(matrice; include; [se_vuoto])

  • matrice: L'intervallo di celle da filtrare.
  • include: La condizione che utilizzi per filtrare l'array per ottenere un array di risultati VERO o FALSO, in modo che i valori VERO vengano mantenuti nel filtro.
  • [se_vuoto]: Il valore da visualizzare se non vengono restituiti risultati corrispondenti.

In questa formula: =FILTRO(A2:C25;B2:B25=F2) viene utilizzato per filtrare nell'intervallo A2:C25, dove i valori da B2:B25 sono uguali alla cella specifica F2.

I migliori strumenti per la produttività in Office

🤖 Kutools AI Aide: Rivoluziona l'analisi dei dati grazie a: Esecuzione Intelligente | Genera Codice | Crea Formule Personalizzate | Analizza Dati e Genera Grafici | Richiama Funzioni avanzate di Kutools…
Funzionalità popolari: Trova, evidenzia o contrassegna duplicati | Elimina righe vuote | Unisci colonne o celle senza perdere dati | Arrotonda...
Super RICERCA.VERT: Ricerca VERT con criteri multipli | Ricerca VERT con valori multipli | Ricerca su più fogli | Corrispondenza approssimativa...
Elenco a discesa avanzato: Crea rapidamente un elenco a discesa | Elenco a discesa dipendente | Elenco a discesa multi-selezione...
Gestione Colonne: Aggiungi un numero specifico di colonne | Sposta colonne | Attiva/disattiva la visibilità delle colonne nascoste | Confronta intervalli e colonne...
Funzionalità in evidenza: Attenzione della griglia | Visualizzazione di progettazione | Barra delle formule avanzata | Gestione Cartella di lavoro e Foglio di lavoro | Libreria AutoText | Selettore di data | Unisci dati | Crittografa/Decrittografa celle | Invia Email tramite elenco | Super Filtri | Filtro speciale (filtra grassetto/corsivo/barrato...) ...
Top15 set di strumenti:12 strumenti di testo (Aggiungi testo, Elimina Caratteri Specifici, ...) | Oltre50 tipi di grafici (Diagramma di Gantt, ...) | Oltre40 formule pratiche (Calcola l'età in base alla data di nascita, ...) |19 strumenti di inserimento (Inserisci codice QR, Inserisci Immagine da percorso, ...) |12 strumenti di conversione (Converti in parole, Conversione valuta, ...) |7 strumenti di unione e divisione (Unione avanzata righe, Dividi celle, ...) | ... e molto altro

Potenzia le tue competenze in Excel con Kutools per Excel e sperimenta un'efficienza mai vista prima. Kutools per Excel offre oltre300 funzionalità avanzate per aumentare la produttività e risparmiare tempo. Clicca qui per ottenere la funzione di cui hai più bisogno...

Office Tab porta l'interfaccia a schede in Office e rende il tuo lavoro molto più semplice

  • Abilita la modifica e la lettura a schede in Word, Excel, PowerPoint, Publisher, Access, Visio e Project.
  • Apri e crea più documenti in nuove schede della stessa finestra, invece che in nuove finestre.
  • Aumenta la tua produttività del50% e riduce centinaia di clic del mouse ogni giorno!