KutoolsforOffice — Un'unica soluzione, cinque potenti strumenti.Ottenere di più con meno sforzo.

Contare facilmente valori univoci e distinti – 7 esempi

AutoreXiaoyang Data di modifica

Normalmente, in Excel, i valori univoci sono quelli che compaiono una sola volta nell’elenco senza duplicati, mentre i valori distinti comprendono tutti i Valore diverso (valori univoci + prime occorrenze duplicate). Quando si lavora con un ampio set di dati, potrebbe essere necessario contare il numero di valori univoci e distinti tra i duplicati in un elenco di celle, come mostrato nell’immagine seguente. Questo tutorial illustra alcuni metodi rapidi per contare valori univoci e distinti in Excel.

Conta i valori univoci o distinti in un elenco

Conta il numero di valori univoci in un intervallo in Excel

Conteggio univoco valori (univoci e prime occorrenze duplicate) in Excel

Scarica il file di esempio

Conta i valori univoci e distinti

Conta il numero di valori univoci in un intervallo in Excel

Questa sezione presenta alcuni esempi di formule per contare i valori univoci, inclusi testo e numeri in un elenco.

Conta il numero di valori univoci in un intervallo con formule

Supponiamo di avere un elenco nomi contenente alcuni duplicati. Ora è necessario ottenere solo il numero di nomi univoci (evidenziati in giallo), come mostrato nell’immagine seguente:

dati di esempio

Per risolvere questo problema, la seguente formula di matrice può esserti d’aiuto:

Passaggio 1: Inserire la formula

Immettere o copiare la formula seguente in una cella vuota in cui si desidera visualizzare il risultato:

=SUM(IF(COUNTIF(A2:A12,A2:A12)=1,1,0))
Nota: Nella formula precedente, «A2:A12» è l’elenco di dati di cui si desidera contare i valori univoci.

Passaggio 2: Premere i tasti Ctrl + Maiusc + Invio per ottenere il risultato corretto:

Conta i valori univoci con formula

Note:

  1. Se l’elenco di celle contiene altri tipi di dati, ad esempio numeri, valori booleani, errori, ecc., applicando la formula sopra indicata si otterrà il numero di valori univoci indipendentemente dal tipo di dato.
  2. Quando l’elenco di dati contiene celle vuote, questa formula le esclude automaticamente.
  3. Per contare soltanto i valori testuali univoci in presenza di altri tipi di dati, applicare la seguente formula matriciale e premere i tasti «Ctrl» + «Maiusc» + «Invio» per ottenere il risultato:
    =SUM(IF(ISTEXT(A2:A12)*COUNTIF(A2:A12,A2:A12)=1,1,0))
  4. Per contare soltanto i numeri univoci da un elenco di celle contenente qualsiasi tipo di dato, utilizzare la seguente formula matriciale e premere i tasti «Ctrl» + «Maiusc» + «Invio» per ottenere il risultato:
    =SUM(IF(ISNUMBER(A2:A12)*COUNTIF(A2:A12,A2:A12)=1,1,0))

Conta il numero di valori univoci in un intervallo con pochi clic tramite Kutools per Excel

Ricordare le formule può diventare difficile quando devi riutilizzarle in futuro. Tuttavia, con «Kutools per Excel», grazie all’opzione «Conta il numero di valori univoci in un intervallo» presente in  «Assistente formula», puoi ottenere il risultato in pochi clic. Guarda la demo seguente:

  1. Fare clic su una cella per visualizzare il risultato;
  2. Abilitare questa funzione facendo clic su «Kutools» > «Assistente formula» > «Assistente formula» > «Statistica» > «Conta il numero di valori univoci in un intervallo»;
  3. Seleziona l’elenco di dati e clicca su «OK».
    Conta i valori univoci con Kutools
Suggerimenti:
  1. Per utilizzare questa funzionalità, devi scaricare e installare Kutools per Excel.
  2. La funzionalità «Assistente formula» raccoglie oltre 40 formule tra le più utilizzate, come «Estrai valori univoci», «Estrai le celle con valori univoci da un intervallo (inclusi i primi duplicati)», «Conta il numero di valori separati da virgola in una cella», «Somma in base allo stesso testo» e molte altre...

Conta il numero di valori univoci in un intervallo in Excel 365/2021 con formule

Se utilizzi Excel 365 o Excel 2021, puoi sfruttare la nuova funzione UNICI per creare formule più semplici e contare il numero di valori univoci in un intervallo all’interno di un set di dati.

Ad esempio, per contare il numero di nomi univoci nell’intervallo A2:A12, immettere la seguente formula：

Passaggio 1: Copiare o immettere la formula seguente

=IFERROR(ROWS(UNIQUE(A2:A12,,TRUE)), 0)
Nota: In questa formula, «A2:A12» è l’elenco di dati di cui si desidera Conta il numero di valori univoci in un intervallo.

Passaggio 2: Premere il tasto Invio per ottenere il risultato:

Conta i valori univoci in Excel 365/2021 con formula

Suggerimenti:

  1. Se l’elenco di dati contiene diversi tipi di dati, come testo, numeri, valori booleani, errori e così via, questa formula restituisce il numero di valori univoci, indipendentemente dal tipo.
  2. La formula indicata sopra conta il numero di valori univoci in un intervallo, incluse le celle vuote. Per escludere le celle vuote, applica la seguente formula e premi semplicemente Invio:
    =SUM(IF(COUNTIF(A2:A12,A2:A12)=1,1,0))

Conteggio univoco valori (univoci e prime occorrenze duplicate) in Excel

Per contare i valori diversi (valori univoci e prime occorrenze di duplicati) in un elenco di celle, di seguito sono illustrate ulteriori formule per completare questa operazione.

Conteggio univoco valori con formule

In Excel puoi applicare una qualsiasi delle seguenti formule per ottenere il numero di valori distinti.

Passaggio 1: Immettere una delle formule seguenti

Formula 1: dopo aver inserito la formula, premere il tasto «Invio».

=SUMPRODUCT(1/COUNTIF(A2:A12,A2:A12))

Formula 2: dopo aver inserito la formula, premere contemporaneamente i tasti «Ctrl» + «Maiusc» + «Invio».

=SUM(1/COUNTIF(A2:A12,A2:A12))
Nota: In queste formule, «A2:A12» è l’elenco di dati di cui si desidera contare Valore diverso.

Risultato:

Conta i valori distinti con formula

Suggerimenti:

  1. Se l’elenco di dati contiene altri tipi di dati, come numeri, valori booleani, errori e così via, questa formula restituisce comunque tutti i valori distinti, indipendentemente dal loro tipo.
  2. Quando si utilizza la formula sopra indicata, si otterrà il valore di errore #DIV/0 se l’elenco di dati contiene celle vuote. Per correggere il problema ed ignorare le celle vuote, applicare una delle seguenti formule:
    Formula 1: dopo aver inserito la formula, premere il tasto «Invio».
    =SUMPRODUCT((A2:A12<>"")/COUNTIF(A2:A12,A2:A12&""))
    Formula 2: dopo aver inserito la formula, premere i tasti «Ctrl» + «Maiusc» + «Invio».
    =SUM(IF(A2:A12<>"",1/COUNTIF(A2:A12, A2:A12), 0))

    Conta i valori distinti escludendo le celle vuote con formula

  3. Per ottenere soltanto il numero di valori testuali distinti all’interno di un elenco di dati, applicare la seguente formula matriciale e premere i tasti «Ctrl» + «Maiusc» + «Invio» per ottenere il risultato:
    =SUM(IF(ISTEXT(A2:A12),1/COUNTIF(A2:A12, A2:A12),""))
  4. Per contare soltanto i valori numerici distinti, utilizzare la seguente formula matriciale e premere i tasti «Ctrl» + «Maiusc» + «Invio» per ottenere il risultato:
    =SUM(IF(ISNUMBER(A2:A12),1/COUNTIF(A2:A12, A2:A12),""))

Conteggio univoco valori con pochi clic tramite Kutools per Excel

Se applichi spesso formule nella cartella di lavoro, ricordarle tutte potrebbe rivelarsi complicato. Tuttavia, con «Kutools per Excel» puoi ottenere il risultato in pochi clic grazie all’opzione «Conta celle con valori univoci (includi la prima occorrenza duplicata)» presente in «Assistente formula». Guarda la demo seguente:

  1. Fare clic su una cella per visualizzare il risultato;
  2. Abilitare questa funzione facendo clic su «Kutools» > «Assistente formula» > «Statistica» > «Conta celle con valori univoci (includi la prima occorrenza duplicata)»;
  3. Selezionare l’elenco di dati e fare clic su «OK».
    Conta i valori distinti con Kutools
Suggerimenti:
  1. Per utilizzare questa funzionalità, devi prima scaricare e installare Kutools per Excel.
  2. La funzionalità «Assistente formula» raccoglie oltre 40 formule tra le più utilizzate, come «Estrai valori univoci», «Estrai le celle con valori univoci da un intervallo (inclusi i primi duplicati)», «Conta il numero di valori separati da virgola in una cella», «Somma in base allo stesso testo» e molte altre!

Conteggio univoco valori con tabella pivot

In Excel, anche la tabella pivot può aiutarti a ottenere il numero di valori distinti da un elenco di dati. Procedi come segue:

Passaggio 1: Creare una Tabella pivot

  1. Selezionare l’elenco di dati, quindi fare clic su «Inserisci» > «Tabella pivot» dalla Barra multifunzione, vedi immagine:
    crea una tabella pivot per i dati selezionati
  2. Nella finestra di dialogo «Tabella pivot da tabella o intervallo» visualizzata:
    (1). Scegli se inserire la tabella pivot in un nuovo foglio di lavoro o in un foglio di lavoro esistente;
    (2). Seleziona quindi la casella «Aggiungi questi dati al modello dati»;
    (3). Fai infine clic sul pulsante «OK».
    imposta le opzioni nella finestra di dialogo Tabella pivot da tabella o intervallo

Passaggio 2: Organizzare il campo e selezionare l’opzione Conteggio distinto

  1. Viene visualizzato il riquadro «Campi tabella pivot». Trascina il campo «Nomi» nell’area «Valori»; vedi la demo seguente:
    Organizza il campo per la tabella pivot
  2. Quindi fare clic sulla freccia a discesa accanto a «Conteggio di Nomi» e scegliere «Impostazioni campo valore», vedi immagine:
    fai clic sull'opzione Impostazioni campo valori
  3. Si aprirà quindi la finestra di dialogo «Impostazioni campo valore». Nella scheda «Riepiloga valori per», selezionare «Conteggio distinto» dall’elenco e fare clic su «OK» (vedi immagine).
    seleziona l'opzione Conteggio valori distinti

Risultato:

Ora la Tabella pivot creata visualizzerà il conteggio distinto dell’elenco di dati, come mostrato nell’immagine seguente:

Risultato della tabella pivot per contare i valori distinti

Suggerimenti:

  1. Se si aggiornano i dati di origine, per ottenere il conteggio aggiornato basta fare clic con il tasto destro sulla tabella pivot e selezionare l’opzione «Aggiorna».
  2. L’opzione «Conteggio Distinto» è disponibile esclusivamente in Excel 2013 e versioni successive.

Conteggio univoco valori in Excel 365/2021 con formule

In Excel 365 o Excel 2021, puoi sfruttare la nuova funzione UNICI insieme alla classica funzione CONTA.VALORI per creare una formula semplice ed efficace.

Copi o inserisca la formula seguente in una cella vuota e premere il tasto «Invio» per ottenere il risultato:

=COUNTA(UNIQUE(A2:A12))
Nota: In questa formula, «A2:A12» è l’elenco di dati di cui si desidera Conteggio univoco valori.

Conta i valori distinti in Excel 365/2021 con formula

Suggerimenti:

  1. Se l’elenco di dati include altri tipi di dati, come testo, numeri, valori booleani, errori e così via, questa formula conta il numero di valori distinti indipendentemente dal tipo di dato.
  2. La formula indicata sopra conta in modo univoco tutti i valori, incluse le celle vuote. Per escludere le celle vuote, applicare la seguente formula e premere il tasto «Invio» per ottenere il risultato:
    =COUNTA(UNIQUE(FILTER(A2:A12, A2:A12<>"")))

    Conta i valori distinti in Excel 365/2021 con formula escludendo le celle vuote

Articoli correlati:

  • Conta il numero di valori univoci in un intervallo in Tabella pivot
  • Per impostazione predefinita, quando si crea una Tabella pivot basata su un intervallo di dati contenente valori duplicati, tutti i record vengono conteggiati. Tuttavia, in alcuni casi è necessario contare solo i valori univoci di una specifica colonna per ottenere risultati accurati. In questo articolo scopriremo come contare i valori univoci in una Tabella pivot.
  • Conta il numero di valori univoci in un intervallo con criteri multipli
  • Di seguito è riportato un intervallo di dati contenente diversi nomi, progetti e località. L’obiettivo è individuare i nomi che soddisfano i criteri elencati e contare ciascun nome corrispondente una sola volta, come mostrato nell’immagine seguente. Conoscete qualche trucco per portare a termine questo compito in modo rapido ed efficace? In questo articolo vi illustrerò alcuni metodi pratici e collaudati.
  • Concatena valori univoci
  • Se ho un lungo elenco di valori con alcuni duplicati e voglio estrarre solo i valori univoci per concatenarli in un’unica cella, come posso risolvere questo problema in modo rapido e semplice in Excel?