KutoolsforOffice — Un'unica soluzione, cinque potenti strumenti.Ottenere di più con meno sforzo.

Padroneggiare le istruzioni IF annidate in Excel – Guida passo passo

AutoreSiluvia Data di modifica

In Excel, sebbene la funzione SE sia fondamentale per eseguire test logici di base, le condizioni complesse richiedono spesso l’uso di istruzioni SE annidate per un’elaborazione dati più efficace. In questa guida completa esploreremo in dettaglio le basi del SE annidato: dalla sintassi alle applicazioni pratiche, incluse le combinazioni con le funzioni E e O. Scopriremo inoltre come migliorare la leggibilità delle formule con SE annidati, condivideremo suggerimenti utili e presenteremo alternative potenti come CERCA.VERT, PIÙ.SE e altre, per semplificare e rendere più efficienti anche le operazioni logiche più complesse.

Uno screenshot delle istruzioni SE annidate in Excel

Funzione SE di Excel vs. istruzioni SE annidate

La funzione SE e le istruzioni SE annidate in Excel condividono obiettivi simili, ma si differenziano notevolmente per complessità e ambito di applicazione.

IF Function: La funzione SE verifica una condizione e restituisce un valore se la condizione è vera e un altro valore se è falsa.
  • La sintassi è:
    =IF (logical_test, [value_if_true], [value_if_false])
  • Limitazione: Può gestire una sola condizione alla volta, risultando quindi poco adatto a scenari decisionali complessi che richiedono la valutazione di criteri multipli.
Istruzioni SE annidate: Le funzioni SE annidate, ovvero una funzione SE all’interno di un’altra, consentono di verificare più criteri e aumentano il numero di possibili risultati.
  • La sintassi è:
    =IF( condition1, value_if_true1, IF( condition2, value_if_true2, value_if_false2 ))
  • Complessità: Può gestire condizioni multiple, ma con troppi livelli di annidamento rischia di diventare complessa e difficile da leggere.

Utilizzo di IF annidati

Questa sezione illustra l’uso fondamentale delle istruzioni SE annidate in Excel, con sintassi chiara, esempi pratici e il loro abbinamento alle condizioni E e O.

Sintassi di IF annidati

Comprendere la sintassi di una funzione è essenziale per utilizzarla in modo corretto ed efficace in Excel. Iniziamo con la sintassi delle istruzioni SE annidate.

Sintassi:

=IF(condition1, result1, IF(condition2, result2, IF(condition3, result3, result4)))

Argomenti:

  • Condizione1, Condizione2, Condizione3: sono le condizioni che desideri verificare. Ogni condizione viene valutata in ordine, a partire da Condizione1.
  • Risultato1: è il valore restituito se Condizione1 è vera.
  • Risultato2: Questo valore viene restituito quando Condizione1 è FALSA e Condizione2 è VERA. È importante notare che Risultato2 viene valutato solo se Condizione1 è FALSA.
  • Risultato3: Questo valore viene restituito quando sia Condizione1 che Condizione2 sono FALSE e Condizione3 è VERA. In pratica, per valutare Risultato3, le condizioni precedenti (Condizione1 e Condizione2) devono essere entrambe FALSE.
  • Risultato4: Questo risultato viene restituito se tutte le condizioni (Condizione1, Condizione2 e Condizione3) sono FALSE.
    In sintesi, questa espressione può essere interpretata come segue:
    Test condition1, if TRUE, return result1, if FALSE,
    test condition2, if TRUE, return result2, if FALSE,
    test condition3, if TRUE, return result3, if FALSE,
    return result4

Ricorda che, in una struttura SE annidata, ogni condizione successiva viene valutata solo se tutte quelle precedenti risultano FALSE. Questo controllo sequenziale è essenziale per comprendere il funzionamento dei SE annidati.

Esempi pratici di IF annidati

Ora approfondiamo l’uso del SE annidato con due esempi pratici.

Esempio 1: sistema di valutazione

Come illustrato nell’immagine seguente, supponiamo di avere un elenco di punteggi degli studenti e di voler assegnare voti in base a tali punteggi. È possibile utilizzare la funzione SE annidata per svolgere questo compito.

Nota: I livelli di valutazione e i relativi intervalli di punteggio sono elencati nell’intervallo E2:F6.

Uno screenshot che mostra l'esempio del sistema di valutazione con istruzioni SE annidate in Excel

Seleziona una cella vuota (ad esempio C2), inserisci la formula seguente e premi Invio per ottenere il risultato. Trascina poi il quadratino di riempimento verso il basso per visualizzare tutti gli altri risultati.

=IF(B2>=90,$F$2,IF(B2>=80,$F$3,IF(B2>=70,$F$4,IF(B2>=60,$F$5,$F$6))))
Note:
  • È possibile specificare direttamente il livello di voto nella formula, quindi la formula può essere modificata in:
    =IF(A2>=90, "A", IF(A2>=80, "B", IF(A2>=70, "C", IF(A2>=60, "D", "F"))))
  • Questa formula assegna un voto (A, B, C, D o F) in base al punteggio presente nella cella A2, utilizzando le soglie standard di valutazione. È un caso d’uso classico per le istruzioni IF annidate nei sistemi di valutazione accademica.
  • Spiegazione della formula:
    1. A2>=90: Questa è la prima condizione valutata dalla formula. Se il punteggio nella cella A2 è maggiore o uguale a 90, la formula restituisce «A».
    2. A2>=80: Se la prima condizione è falsa (il punteggio è inferiore a 90), verifica se A2 è maggiore o uguale a 80. In tal caso, restituisce «B».
    3. A2>=70: Analogamente, se il punteggio è inferiore a 80, verifica se è maggiore o uguale a 70. In tal caso, restituisce «C».
    4. A2>=60: Se il punteggio è inferiore a 70, la formula controlla se è maggiore o uguale a 60. In tal caso, restituisce «D».
    5. "F«: Infine, se nessuna delle condizioni precedenti è soddisfatta (il punteggio è inferiore a 60), la formula restituisce »F".
Esempio 2: calcolo della commissione sulle vendite

Immagina uno scenario in cui i rappresentanti di vendita ricevono percentuali di commissione diverse a seconda dei risultati raggiunti. Come illustrato nell’immagine seguente, puoi calcolare la commissione di un venditore in base a diverse soglie di vendita: in casi come questo, le istruzioni SE annidate sono la soluzione ideale.

Nota: Le percentuali di commissione e i relativi intervalli di vendita sono elencati nell’intervallo E2:F4.
  • Livello 1 ($20,000+): 20 %
  • Livello 2 ($10,000-$19,999): 15 %
  • Livello 3 (<$10,000): 10 %

Uno screenshot che mostra l'esempio del calcolo della commissione sulle vendite con istruzioni SE annidate in Excel

Seleziona una cella vuota (ad esempio C2), inserisci la formula seguente e premi Invio per ottenere il risultato. Trascina poi il quadratino di riempimento verso il basso per visualizzare tutti gli altri risultati.

=B2*IF(B2>20000,$F$2,IF(B2>=10000,$F$3,$F$4))

Uno screenshot che visualizza i risultati del calcolo della commissione sulle vendite utilizzando formule SE annidate

Note:
  • È possibile specificare direttamente la percentuale di commissione nella formula, quindi la formula può essere modificata in:
    =B2*IF(B2>20000, 20%, IF(B2>=10000, 15%, 10%))
  • La formula fornita calcola la commissione di un venditore in base all’importo delle sue vendite, applicando percentuali differenziate a seconda delle soglie raggiunte.
  • Spiegazione della formula:
    1. B2: rappresenta l’importo delle vendite del venditore, utilizzato come base per il calcolo della commissione.
    2. IF(B2>20000, «20%», ...): Questa è la prima condizione valutata. Verifica se l’importo delle vendite in B2 supera i 20.000 €; in tal caso, la formula applica una commissione del 20 %.
    3. IF(B2>=10000, «15%», «10%»): Se la prima condizione non è soddisfatta (le vendite non superano i 20.000), la formula verifica se le vendite sono uguali o superiori a 10.000. In tal caso, applica un tasso di commissione del 15 %. Se invece l’importo delle vendite è inferiore a 10.000, la formula applica automaticamente un tasso di commissione del 10 %.

IF annidati con condizioni AND / OR

In questa sezione modificherò il primo esempio precedente, «il sistema di valutazione», per mostrare come combinare la funzione SE annidata con le condizioni E o O in Excel. Nella versione aggiornata dell’esempio, ho introdotto una condizione aggiuntiva basata sulla «percentuale di presenza».

Uno screenshot che illustra l'esempio di valutazione con criteri di presenza in Excel

Utilizzo del SE annidato con la condizione E

Se uno studente soddisfa entrambi i criteri – punteggio e presenza – riceverà un miglioramento del voto. Ad esempio, uno studente con un punteggio pari o superiore a 60 e una percentuale di presenza pari o superiore al 95 % vedrà il proprio voto aumentato di un livello (ad esempio da A ad A+, da B a B+ e così via). Tuttavia, se la percentuale di presenza è inferiore al 95 %, la valutazione seguirà i criteri originali basati esclusivamente sul punteggio. In questi casi, è necessario utilizzare un’istruzione SE annidata con una condizione E.

Seleziona una cella vuota (ad esempio D2), inserisci la formula seguente e premi Invio per ottenere il risultato. Trascina poi il quadratino di riempimento verso il basso per visualizzare tutti gli altri risultati.

=IF(AND(B2>=60, C2>=95%),IF(B2>=90, "A+", IF(B2>=80, "B+", IF(B2>=70, "C+", "D+"))),IF(B2>=90, "A", IF(B2>=80, "B", IF(B2>=70, "C", IF(B2>=60, "D", "F")))))

Uno screenshot che mostra il SE annidato con la condizione E per la valutazione in Excel

Note: Di seguito viene spiegato il funzionamento di questa formula:
  1. Controllo della condizione AND:
    AND(B2>=60, C2>=95 %): La condizione AND verifica innanzitutto che entrambe le condizioni siano soddisfatte — il punteggio dello studente è 60 o superiore e la sua percentuale di presenza è 95 % o superiore.
  2. New grade assignment:
    IF(B2>=[[PH_131]], «A+», IF(B2>=[[PH_130]], «B+», IF(B2>=[[PH_129]], «C+», «D+»))): Se entrambe le condizioni nell’istruzione AND sono vere, la formula verifica quindi il punteggio dello studente e ne aumenta il voto di un livello.
    • B2>=90: Se il punteggio è 90 o superiore, il voto assegnato è "A +". Nuova assegnazione del voto:
    • B2>=80: Se il punteggio è 80 o superiore (ma inferiore a 90), il voto è "B +".
    • B2>=70: Se il punteggio è 70 o superiore (ma inferiore a 80), il voto è «C+».
    • B2>=60: Se il punteggio è 60 o superiore (ma inferiore a 70), il voto assegnato è «D+».
  3. Regular Grade Assignment:
    IF(B2>=[[PH_146]], «A», IF(B2>=[[PH_145]], «B», IF(B2>=[[PH_144]], «C», IF(B2>=[[PH_143]], «D», «F»)))): Se la condizione AND non è soddisfatta (il punteggio è inferiore a 80 o la presenza è inferiore a 95 %), la formula assegna voti standard.
    • B2>=90: Un punteggio di 90 o superiore ottiene una «A».
    • B2>=80: Un punteggio pari o superiore a 80 (ma inferiore a 90) ottiene una «B».
    • B2>=70: Un punteggio pari o superiore a 70 (ma inferiore a 80) ottiene una «C».
    • B2>=60: Un punteggio pari o superiore a 60 (ma inferiore a 70) ottiene una «D».
    • I punteggi inferiori a 60 ricevono una «F».
Utilizzo del SE annidato con la condizione O

In questo caso, il voto di uno studente verrà aumentato di un livello se il suo punteggio è pari o superiore a 95 oppure se la sua percentuale di presenza raggiunge almeno il 95 %. Ecco come realizzarlo utilizzando una funzione SE annidata con la condizione O.

Seleziona una cella vuota (ad esempio D2), inserisci la formula seguente e premi Invio per ottenere il risultato. Trascina poi il quadratino di riempimento verso il basso per visualizzare tutti gli altri risultati.

=IF(OR(B2>=95, C2>=95%),IF(B2>=90, "A+", IF(B2>=80, "B+", IF(B2>=70, "C+", IF(B2>=60, "D+", "F+")))),IF(B2>=90, "A", IF(B2>=80, "B", IF(B2>=70, "C", IF(B2>=60, "D", "F")))))

Uno screenshot che mostra il SE annidato con la condizione O per la valutazione in Excel

Note: Di seguito viene illustrato il funzionamento della formula:
  1. Controllo della condizione OR:
    OR(B2>=95, C2>=95 %): La formula verifica innanzitutto se almeno una delle condizioni è vera — il punteggio dello studente è 95 o superiore oppure la sua percentuale di presenza è 95 % o superiore.
  2. Grade Assignment with Bonus:
    IF(B2>=[[PH_168]], «A+», IF(B2>=[[PH_167]], «B+», IF(B2>=[[PH_166]], «C+», IF(B2>=[[PH_165]], «D+», «F+»)))): Se almeno una delle condizioni nell’istruzione OR è vera, il voto dello studente verrà aumentato di un livello.
    • B2>=90: se il punteggio è 90 o superiore, il voto è «A+».
    • B2>=80: Se il punteggio è 80 o superiore (ma inferiore a 90), il voto è «B+».
    • B2>=70: Se il punteggio è 70 o superiore (ma inferiore a 80), il voto è «C+».
    • B2>=60: Se il punteggio è 60 o superiore (ma inferiore a 70), il voto è «D+».
    • In caso contrario, il voto è «F+».
  3. Regular Grade Assignment:
    IF(B2>=[[PH_182]], «B», IF(B2>=[[PH_181]], «C», IF(B2>=[[PH_180]], «D», «F»)))): Se nessuna delle condizioni OR è soddisfatta (il punteggio è inferiore a 95 e la presenza è inferiore a 95 %), la formula assegna voti standard.
    • B2>=90: Un punteggio di 90 o superiore ottiene una «A».
    • B2>=80: Un punteggio pari o superiore a 80 (ma inferiore a 90) ottiene una «B».
    • B2>=70: Un punteggio pari o superiore a 70 (ma inferiore a 80) ottiene una «C».
    • B2>=60: Uno score pari o superiore a 60 (ma inferiore a 70) riceve una valutazione «D».
    • I punteggi inferiori a 60 ricevono una «F».

Suggerimenti e trucchi per IF annidati

Questa sezione presenta quattro suggerimenti utili per il SE annidato.

Rendere gli IF annidati facili da leggere

Un’istruzione tipica di SE annidato può sembrare compatta, ma spesso risulta difficile da interpretare.

Nella formula seguente è difficile individuare rapidamente dove finisce una condizione e ne inizia un’altra, soprattutto man mano che la complessità aumenta.

=IF(A2>=90, "A", IF(A2>=80, "B", IF(A2>=70, "C", IF(A2>=60, "D", "F"))))
Soluzione: aggiungere interruzioni di riga e rientri

Per migliorare la leggibilità del SE annidato, puoi suddividere la formula su più righe, inserendo ogni funzione SE su una nuova riga. Nella barra della formula, posiziona semplicemente il cursore davanti alla funzione SE e premi Alt + Invio.

Dopo aver suddiviso la formula sopra indicata, verrà visualizzata come segue:

=IF(A2>=90, "A",
      IF(A2>=80, "B",
          IF(A2>=70, "C",
              IF(A2>=60, "D", "F")))
)

Questo formato rende più chiari i diversi criteri e i relativi risultati, migliorando notevolmente la leggibilità della formula.

Ordine delle funzioni IF annidate

L’ordine delle condizioni logiche in una formula SE annidata è fondamentale, poiché determina come Excel le valuta e influisce direttamente sul risultato finale della formula.

Formula corretta

Nell’esempio del sistema di valutazione, utilizziamo la seguente formula per assegnare i voti in base ai punteggi ottenuti.

=IF(B2>=90, "A", IF(B2>=80, "B", IF(B2>=70, "C", IF(B2>=60, "D", "F"))))

Uno screenshot che visualizza l'ordine corretto delle condizioni in una formula SE annidata per la valutazione

Excel valuta le condizioni in una formula SE annidata in sequenza, dalla prima all’ultima. La formula controlla innanzitutto la soglia di punteggio più alta (>=90 per un «A»), per poi passare progressivamente a quelle inferiori. Questo approccio assicura che ogni punteggio venga confrontato con il voto più alto per cui è idoneo. Se la prima condizione risulta vera (A2>=90), la formula restituisce immediatamente «A» senza valutare le condizioni successive.

Formula con ordine errato

Se l’ordine delle condizioni fosse invertito, partendo dalla soglia più bassa, si otterrebbero risultati errati.

=IF(B2>=60, "D", IF(B2>=70, "C", IF(B2>=80, "B", IF(B2>=90, "A", "F"))))

Uno screenshot che illustra un ordinamento errato in una formula SE annidata

In questa formula errata, un punteggio di 95 soddisferebbe immediatamente la prima condizione B2>=60 e verrebbe erroneamente assegnato il voto «D».

Numeri e testo devono essere trattati in modo diverso

Questa sezione illustra come numeri e testo vengano gestiti in modo diverso all’interno delle istruzioni SE annidate.

Numeri

I numeri servono per effettuare confronti aritmetici e calcoli. Nelle istruzioni SE annidate, puoi confrontare direttamente i numeri utilizzando operatori come >, = e <=.

Testo

Nelle istruzioni SE annidate, il testo deve essere racchiuso tra virgolette doppie. Si vedano A, B, C, D e F nella formula seguente:

=IF(A2>=90, "A", IF(A2>=80, "B", IF(A2>=70, "C", IF(A2>=60, "D", "F"))))

Limitazioni degli IF annidati

Questa sezione illustra alcune limitazioni e svantaggi del SE annidato.

Complessità e leggibilità:

Sebbene Excel consenta di annidare fino a 64 funzioni SE, non è affatto consigliabile farlo: più alto è il livello di annidamento, più complessa diventa la formula, risultando difficile da leggere, comprendere e mantenere.

Suscettibilità agli errori:

Inoltre, le istruzioni SE annidate complesse possono facilmente causare errori e risultare difficili da correggere o modificare.

Difficoltà di estensione o scalabilità:

Se la logica cambia o occorre aggiungere ulteriori condizioni, i SE annidati in profondità possono diventare difficili da modificare o estendere.

Comprendere queste limitazioni è essenziale per sfruttare al meglio le funzioni SE annidate in Excel. Spesso, combinarle con altre funzioni o adottare approcci alternativi consente di ottenere soluzioni più efficienti e semplici da gestire.

Alternative agli IF annidati

Questa sezione presenta diverse funzioni di Excel che offrono valide alternative alle istruzioni SE annidate.

Utilizzo di VLOOKUP

È possibile utilizzare la funzione CERCA.VERT al posto delle istruzioni SE annidate per realizzare i due esempi pratici illustrati sopra. Ecco come fare:

Esempio 1: sistema di valutazione con CERCA.VERT

Qui ti mostrerò come usare CERCA.VERT per assegnare voti in base ai punteggi.

Passaggio 1: crea una tabella di ricerca per i voti

Innanzitutto, devi creare una tabella di ricerca (ad esempio E1:F6 in questo caso) per gli intervalli di punteggio e i voti corrispondenti.Nota:I punteggi nella prima colonna della tabella devono essere ordinati in ordine crescente.

Uno screenshot che mostra una tabella di ricerca per i voti da utilizzare con CERCA.VERT in Excel

Passaggio 2: applica la funzione CERCA.VERT per assegnare i voti

Seleziona una cella vuota (C2 in questo caso), inserisci la seguente formula e premi Invio per ottenere il primo voto. Seleziona quindi la cella con la formula e trascina il quadratino di riempimento verso il basso per ottenere i voti restanti.

=VLOOKUP(B2,$E$2:$F$6,2,TRUE)

Uno screenshot che dimostra l'uso di CERCA.VERT per la valutazione in Excel

Note:
  • Il valore 95 nella cella B2 è quello che VLOOKUP cerca nella prima colonna della tabella di ricerca ($E$2:$F$6). Se lo trova, restituisce il voto corrispondente dalla seconda colonna della tabella, nella stessa riga del valore individuato.
  • Ricordati di rendere assoluto il riferimento alla tabella di ricerca aggiungendo il simbolo del dollaro ($) davanti ai riferimenti, in modo che non cambi quando la formula viene copiata in un’altra cella.
  • Per ulteriori informazioni sulla funzione VLOOKUP, visita questa pagina.
Esempio 2: calcolo della commissione sulle vendite con CERCA.VERT

Puoi anche usare CERCA.VERT per calcolare la commissione sulle vendite in Excel. Ecco come fare.

Passaggio 1: Creare una tabella di ricerca per i voti

Innanzitutto, devi creare una tabella di ricerca per le vendite e le relative percentuali di commissione, ad esempio E2:F4 in questo caso.Nota: Le vendite nella prima colonna della tabella devono essere ordinate in ordine crescente.

Uno screenshot che mostra una tabella di ricerca per le percentuali di commissione sulle vendite da utilizzare con CERCA.VERT in Excel

Passaggio 2: Applicare la funzione CERCA.VERT per assegnare i voti

Selezionare una cella vuota (C2 in questo caso), inserire la seguente formula e premere il tasto Invio per ottenere la prima commissione. Selezionare questa cella contenente la formula e trascinare il quadratino di riempimento verso il basso per ottenere i restanti risultati.

=B2*VLOOKUP(B2,$E$2:$F$4,2,TRUE)

Uno screenshot che dimostra l'uso di CERCA.VERT per il calcolo della commissione sulle vendite in Excel

Note:
  • In entrambi gli esempi, VLOOKUP cerca un valore in una tabella utilizzando un valore di ricerca (punteggio o importo delle vendite) e restituisce il valore corrispondente nella stessa riga da una colonna specificata (voto o percentuale di commissione). Il quarto parametro, impostato su TRUE, abilita la corrispondenza approssimativa, ideale per questi scenari in cui il valore esatto potrebbe non essere presente nella tabella.
  • Per ulteriori informazioni sulla funzione VLOOKUP, visita questa pagina.

Utilizzo di IFS

La funzione IFS semplifica il processo eliminando la necessità di annidamenti, rendendo le formule più chiare e facili da gestire. Migliora la leggibilità e facilita la gestione di controlli condizionali multipli. Per utilizzare la funzione IFS, assicurati di avere Excel 2019 o una versione successiva, oppure un abbonamento a Office 365. Vediamo ora come applicarla in esempi pratici.

Esempio 1: Sistema di valutazione con IFS

Supponendo gli stessi criteri di valutazione di prima, la funzione IFS può essere utilizzata come segue:

Seleziona una cella vuota, ad esempio C2, inserisci la seguente formula e premi Invio per ottenere il primo risultato. Seleziona quindi la cella con il risultato e trascina il quadratino di riempimento verso il basso per visualizzare tutti gli altri risultati.

=IFS(B2>=90,"A",B2>=80,"B",B2>=70,"C",B2>=60,"D",B2<60,"F")

Uno screenshot che mostra l'uso della funzione IFS per la valutazione in Excel

Note:
  • Ogni condizione viene valutata in ordine. Non appena una condizione è soddisfatta, viene restituito il risultato corrispondente e la formula smette di verificare ulteriori condizioni. In questo caso, la formula viene utilizzata per assegnare voti in base al punteggio presente in B2, seguendo una scala di valutazione tipica in cui un punteggio più alto corrisponde a un voto migliore.
  • Per ulteriori informazioni sulla funzione IFS, visita questa pagina.
Esempio 2: Calcolo della commissione sulle vendite con IFS

Nello scenario del calcolo della commissione sulle vendite, la funzione IFS viene applicata come segue:

Seleziona una cella vuota, ad esempio C2, inserisci la seguente formula e premi Invio per ottenere il primo risultato. Seleziona quindi la cella con il risultato e trascina il quadratino di riempimento verso il basso per ottenere tutti gli altri risultati.

=B2*IFS(B2>20000,20%,B2>=10000,15%,TRUE,10%)

Uno screenshot che mostra l'uso della funzione IFS per il calcolo della commissione sulle vendite in Excel

Utilizzo di CHOOSE e MATCH

L’approccio basato su CHOOSE e MATCH si rivela più efficiente e più semplice da gestire rispetto alle istruzioni IF annidate, semplificando la formula e rendendo aggiornamenti o modifiche immediati. Di seguito ti mostrerò come sfruttare al meglio la combinazione delle funzioni CHOOSE e MATCH per affrontare i due esempi pratici presentati in questo articolo.

Esempio 1: Sistema di valutazione con CHOOSE e MATCH

È possibile assegnare voti in base a punteggi diversi combinando le funzioni CHOOSE e MATCH.

Passaggio 1: Creare una matrice di ricerca con Valore di ricerca

Innanzitutto, è necessario creare un intervallo di celle contenente i valori soglia che la funzione MATCH cercherà, ad esempio $E$2:$E$6 in questo caso.Nota:I numeri in questo intervallo devono essere ordinati in ordine crescente affinché la funzione MATCH funzioni correttamente quando si utilizza una corrispondenza approssimativa.

Uno screenshot che mostra una matrice di ricerca per i voti utilizzando SCEGLI e CONFRONTA in Excel

Passaggio 2: Applicare CHOOSE e MATCH per assegnare i voti

Selezionare una cella vuota (C2 in questo caso), inserire la seguente formula e premere il tasto Invio per ottenere il primo voto. Selezionare questa cella contenente la formula e trascinare il quadratino di riempimento verso il basso per ottenere i restanti risultati.

=CHOOSE(MATCH(B2, $E$2:$E$6, 1), "F", "D", "C", "B", "A")

Uno screenshot che dimostra l'uso di SCEGLI e CONFRONTA per la valutazione in Excel

Note:
  • MATCH(B2, $E$2:$E$6, 1)Questa parte della formula cerca il punteggio (95) presente nella cella B2 all'interno dell'intervallo $E$2:$E$6. Il valore 1 indica che la funzione CONFRONTA deve trovare una corrispondenza approssimativa, ovvero il valore più grande nell'intervallo che sia minore o uguale a quello in B2.
  • CHOOSE(..., «F», «D», «C», «B», «A»)In base alla posizione restituita dalla funzione CONFRONTA, SCEGLI seleziona il voto corrispondente.
  • Per ulteriori informazioni sulla funzione MATCH, visita questa pagina.
  • Per ulteriori informazioni sulla funzione CHOOSE, visita questa pagina.
Esempio 2: Calcolo della commissione sulle vendite con IFS

Utilizzare la combinazione di CHOOSE e MATCH per calcolare la commissione sulle vendite può rivelarsi una soluzione efficace, soprattutto quando le percentuali di commissione dipendono da specifiche soglie di vendita. Ecco come procedere.

Passaggio 1: Creare una matrice di ricerca con Valore di ricerca

Innanzitutto, è necessario creare un intervallo di celle contenente i valori soglia che la funzione MATCH cercherà, ad esempio $E$2:$E$4 in questo caso.Nota:I numeri in questo intervallo devono essere ordinati in ordine crescente affinché la funzione MATCH funzioni correttamente quando si utilizza una corrispondenza approssimativa.

Uno screenshot che mostra una matrice di ricerca per le percentuali di commissione sulle vendite utilizzando SCEGLI e CONFRONTA in Excel

Passaggio 2: Applicare CHOOSE e MATCH per ottenere i risultati

Selezionare una cella vuota (C2 in questo caso), inserire la seguente formula e premere il tasto Invio per ottenere il primo voto. Selezionare questa cella contenente la formula e trascinare il quadratino di riempimento verso il basso per ottenere i restanti risultati.

=B2*CHOOSE(MATCH(B2, $E$2:$E$4, 1), 10%, 15%, 20%)

Uno screenshot che dimostra l'uso di SCEGLI e CONFRONTA per il calcolo della commissione sulle vendite in Excel

Note:

In conclusione, padroneggiare le istruzioni IF annidate in Excel è un’abilità preziosa che potenzia la tua capacità di gestire scenari logici complessi nei processi di analisi dei dati e di supporto alle decisioni. Sebbene gli IF annidati siano potenti per operazioni logiche articolate, è fondamentale tenere conto dei loro limiti. In molti casi, alternative più snelle come VLOOKUP, IFS o la combinazione CHOOSE con MATCH offrono soluzioni più efficienti e leggibili. Grazie a queste conoscenze, puoi ora applicare con sicurezza le tecniche di Excel più adatte alle tue attività di analisi dei dati, garantendo chiarezza, accuratezza ed efficienza nei tuoi fogli di calcolo. Vuoi approfondire ulteriormente le funzionalità di Excel? Il nostro sito web offre un’ampia raccolta di tutorial!Scopri altri suggerimenti e trucchi su Excel qui.

I migliori strumenti per la produttività in Office

🤖KUTOOLS AI Assistente: Rivoluziona Analisi dei dati basandoti su:Esecuzione Intelligente   |  Genera Codice|  Crea formule personalizzate  |  Analizza Dati e Genera Grafici|  Richiama Funzioni avanzate…
Funzionalità Popolari:Trova, Evidenzia o Contrassegna Duplicati   |  Elimina righe vuote   |  Combinare Colonne o Celle senza Perdere Dati   |   Arrotondamento senza usare la formula...
Super RICERCA.VERT:Ricerca VLookup con Criteri Multipli  |  Ricerca VLookup con Valori Multipli  |   VLookup tra Fogli Multipli   |   Corrispondenza approssimativa....
Elenco a discesa avanzato:Crea Rapidamente un Elenco a Discesa   |  Elenco a Discesa Dipendente   |  Elenco a Discesa con Selezione Multipla....
Gestione Colonne:Aggiungi un Numero Specifico di Colonne|Sposta Colonne|Attiva/Disattiva lo Stato di Visibilità delle Colonne Nascoste|Confronta Intervalli e Colonne...
Funzionalità in Evidenza:Attenzione della griglia   |  Visualizzazione Design   |Barra delle formule avanzata   | Gestione Cartella di Lavoro e Fogli   |  Biblioteca di risorse(Testo Automatico)|  Selettore di Date   |  Unisci fogli di lavoro  |  Crittografa/Decrittografa celle   | Invia Email da Elenco   |  Super Filtri   |   Filtro speciale(Filtra celle con testo in grassetto/corsivo/barrato...) ...
Principali Set di Strumenti 15:... e molto altro... e molto altro(,)Elimina Caratteri Specifici, ...)|   (, ...)|   (Calcola l'età in base alla data di nascita, ...)|   19 Strumenti per l'Inserimento(,Inserisci Immagine dal Percorso , ...)|   per la Conversione (Converti in parole,Conversione del tasso di cambio, ...)|per Unire e Dividere   (Unione avanzata righe,, ...)|, ...)   |
Usa Kutools nella tua lingua preferita – supporta inglese, spagnolo, tedesco, francese, cinese e 40+ altre lingue!

Potenzia le tue competenze Excel con Kutools per Excel e sperimenta un’efficienza mai vista prima.Kutools per Excel offre oltre 300 funzionalità avanzate per aumentare la produttività e Risparmia tempo.Clicca qui per ottenere la funzionalità di cui hai più bisogno...

Office Tab Porta l’interfaccia a schede in Office e rende il tuo lavoro molto più semplice

  • Abilita la modifica e la lettura a schede in Word, Excel, PowerPoint, Publisher, Access, Visio e Project.
  • Apri e crea più documenti in nuove schede della stessa finestra, anziché in nuove finestre.
  • Aumenta la tua produttività del 50 % e riduce centinaia di clic del mouse ogni giorno!

Tutti i componenti aggiuntivi Kutools. Un solo programma di installazione

Kutools for Office è la suite che include componenti aggiuntivi per Excel, Word, Outlook e PowerPoint, oltre a Office Tab Pro: la soluzione ideale per i team che lavorano su più app di Office.

ExcelWordOutlookTabsPowerPoint
  • Suite completa— componenti aggiuntivi per Excel, Word, Outlook e PowerPoint + Office Tab Pro
  • Un solo programma di installazione, una sola licenza— configurazione in pochi minuti (pronto per MSI)
  • Funzionano meglio insieme— produttività ottimizzata tra le applicazioni Office
  • Prova gratuita di 30 giorni con tutte le funzionalità— senza registrazione, senza carta di credito
  • Miglior rapporto qualità-prezzo— risparmia rispetto all’acquisto dei singoli componenti aggiuntivi