Come si ottiene l'elenco delle cartelle in Outlook?

A volte, la struttura ad albero completa di tutte le cartelle di posta — incluse quelle personali create dall’utente — nel riquadro di navigazione può rivelarsi estremamente utile durante il lavoro con Outlook. Per visualizzare rapidamente l’intera gerarchia delle cartelle, puoi ricorrere al codice VBA. In questo tutorial scoprirai come ottenere facilmente l’elenco delle cartelle utilizzando proprio il codice VBA.

Ottieni l'elenco delle cartelle in Outlook con il codice VBA

---

Ottieni l'elenco delle cartelle in Outlook con il codice VBA

Per ottenere l'elenco delle cartelle in Outlook tramite codice VBA, segui questi semplici passaggi.

1. Premi contemporaneamente i tasti «Alt» + "F11" sulla tastiera per aprire la finestra di Microsoft Visual Basic, Applications.

2. Dopodiché, fai doppio clic su "Project1" > «Oggetti Microsoft Outlook» > «ThisOutlookSession» per aprire la finestra «Project1 – ThisOutlookSession». Vedi screenshot:

3. Copia quindi e incolla il codice VBA riportato di seguito nella finestra «Project1 – ThisOutlookSession».

VBA: ottieni l'elenco delle cartelle in Outlook

Option Explicit
Sub GetFoldersList()
    On Error GoTo On_Error
    
    Dim Report As String
    Dim Folder As Outlook.Folder
       
    For Each Folder In Application.Session.Folders
        Report = Report & "---------------------------------------------------------------------------" & vbCrLf
        Call RecurseFolders(Folder, "", Report)
    Next
    Call CreateReportEmail("Outlook Folders List", Report)
    
Exiting:
    Exit Sub
On_Error:
    MsgBox "error=" & Err.Number & " " & Err.Description
End Sub
Sub RecurseFolders(CurrentFolder As Outlook.Folder, TabChars, ByRef Report As String)
    Dim SubFolder As Outlook.Folder
    Dim FolderName, StoreName As String
    
    FolderName = CurrentFolder.Name
    StoreName = CurrentFolder.Store.DisplayName
    
    Report = Report & TabChars & FolderName & " (Store: " & StoreName & ")" & vbCrLf
    
    For Each SubFolder In CurrentFolder.Folders
        Call RecurseFolders(SubFolder, TabChars & vbTab, Report)
    Next SubFolder
End Sub
Sub CreateReportEmail(Title As String, Report As String)
    Dim aMail As MailItem
    
    Set aMail = Application.CreateItem(olMailItem)
        
    aMail.Subject = Title
    aMail.Body = Report
    
    aMail.Display
End Sub

4. Premi il tasto "F5" sulla tastiera per eseguire il codice VBA.

5. Si apre ora la finestra di dialogo «Macro»; fai clic sul pulsante «Esegui».

6. Attendi il completamento dell'esecuzione della macro: l'elenco di tutte le tue cartelle di posta verrà visualizzato immediatamente in una nuova finestra di messaggio appena creata, pronta per essere stampata con facilità. Vedi screenshot:

Nota: questo codice VBA è compatibile con Outlook 2007, 2010 e 2013.