Come fare per espandere automaticamente tutte le cartelle all’avvio di Outlook?

In genere, quando si espande o si comprime una cartella nella Navigazione di Outlook e si chiude il programma, lo stato (espanso o compresso) viene mantenuto al successivo riavvio. Ma cosa fare se si desidera che tutte le cartelle vengano automaticamente espanse ogni volta che si avvia Outlook? Questo articolo presenta una soluzione basata su VBA per ottenere esattamente questo risultato.

Espandere automaticamente Espandi tutte le cartelle all’avvio di Outlook mediante VBA

---

Espandere automaticamente Espandi tutte le cartelle all’avvio di Outlook mediante VBA

Questa guida spiega come utilizzare uno script VBA per espandere automaticamente tutte le cartelle nella riquadro di navigazione ogni volta che si avvia Outlook. Segui questi semplici passaggi per implementare lo script VBA:

1. Premere contemporaneamente i tasti Alt + F11 per aprire la finestra di Microsoft Visual Basic, Applications Edition.
2. Espandere il progetto Progetto 1e Oggetti Microsoft Outlooknel riquadro Progetto, fare doppio clic per aprire la finestra ThisOutlookSessione incollare il codice VBA riportato di seguito.

   

   VBA: Espandi automaticamente Espandi tutte le cartelle in Outlook

   Public WithEvents GEx As Explorer
   Public GFlag As Boolean
   Private Sub Application_Startup()
     'Update by ExtendOffice 2023/12/08
     Set GEx = Application.ActiveExplorer
     GFlag = False
   End Sub
   
   Private Sub GEx_SelectionChange()
     If GFlag = False Then
       ExpandAllFolders
     End If
     GFlag = True
   End Sub
   
   Public Sub ExpandAllFolders()
     Dim xNameSpace As Outlook.NameSpace
     Dim xFlds As Outlook.Folders
     Dim xCurrFld As Outlook.MAPIFolder
     Dim xFld As Outlook.MAPIFolder
     Dim xExpandDefaultStoreOnly As Boolean
     Dim xModule As NavigationModule
     On Error Resume Next
     xExpandDefaultStoreOnly = False
     Set xNameSpace = Application.Session
     Set xModule = Application.ActiveExplorer.NavigationPane.CurrentModule
     Set xCurrFld = Application.ActiveExplorer.CurrentFolder
     If xExpandDefaultStoreOnly = True Then
       Set xFld = xNameSpace.GetDefaultFolder(olFolderInbox)
       Set xFld = xFld.Parent
       Set xFlds = xFld.Folders
       LoopFolders xFlds, True
     Else
       LoopFolders xNameSpace.Folders, True
       LoopFolders xNameSpace.Folders, False
     End If
     DoEvents
     Set Application.ActiveExplorer.NavigationPane.CurrentModule = xModule
     Set Application.ActiveExplorer.CurrentFolder = xCurrFld
     Set xNameSpace = Nothing
     Set xModule = Nothing
     Set xCurrFld = Nothing
   End Sub
   
   Private Sub LoopFolders(Flds As Outlook.Folders, ByVal All As Boolean)
     Dim xFld As Outlook.MAPIFolder
     On Error Resume Next
     For Each xFld In Flds
       Select Case All
         Case True
           If xFld.DefaultItemType = olMailItem Then
             Set Application.ActiveExplorer.CurrentFolder = xFld
             DoEvents
             If xFld.Folders.Count > 0 Then
               LoopFolders xFld.Folders, All
             End If
           End If
         Case False
           Set Application.ActiveExplorer.CurrentFolder = xFld
           DoEvents
           If xFld.Folders.Count > 0 Then
             LoopFolders xFld.Folders, All
           End If
       End Select
     Next
   End Sub

3. Salva il codice e chiudi la finestra di Microsoft Visual Basic, Applications Edition.

D’ora in poi, al riavvio di Outlook, tutte le cartelle si espanderanno automaticamente.

---

Articoli correlati