Come trovare una cartella (con nome completo e percorso del file) in Outlook in base al solo nome della cartella?

Segui i passaggi indicati di seguito per cercare cartelle in base al nome della cartella utilizzando VBA in Outlook.

1. Premere contemporaneamente i tasti «Alt» + "F11" per aprire la finestra di Microsoft Visual Basic, Applications.

2. Fare clic su «Inserisci» > «Modulo» e incollare il seguente codice VBA nella nuova finestra del modulo.

VBA: Cerca e Apri cartella in base a Nome cartella in Outlook

Private m_Folder As MAPIFolder
Private m_Find As String
Private m_Wildcard As Boolean

Private Const SpeedUp As Boolean = True
Private Const StopAtFirstMatch As Boolean = True

Public Sub FindFolder()
Dim sName As String
Dim oFolders As Folders

  Set m_Folder = Nothing
m_Find = ""
m_Wildcard = False

  sName = InputBox("Find:", "Search folder")
If Len(Trim(sName)) = 0 Then Exit Sub
m_Find = sName

  m_Find = LCase(m_Find)
m_Find = Replace(m_Find, "%", "*")
m_Wildcard = (InStr(m_Find, "*"))

  Set oFolders = Application.Session.Folders
LoopFolders oFolders

  If Not m_Folder Is Nothing Then
If MsgBox("Activate folder: " & vbCrLf & m_Folder.FolderPath, vbQuestion Or vbYesNo) = vbYes Then
Set Application.ActiveExplorer.CurrentFolder = m_Folder
End If
Else
MsgBox "Not found", vbInformation
End If
End Sub

Private Sub LoopFolders(Folders As Outlook.Folders)
Dim oFolder As MAPIFolder
Dim bFound As Boolean

If SpeedUp = False Then DoEvents

  For Each oFolder In Folders
If m_Wildcard Then
bFound = (LCase(oFolder.Name) Like m_Find)
Else
bFound = (LCase(oFolder.Name) = m_Find)
End If

    If bFound Then
If StopAtFirstMatch = False Then
If MsgBox("Found: " & vbCrLf & oFolder.FolderPath & vbCrLf & vbCrLf & "Continue?", vbQuestion Or vbYesNo) = vbYes Then
bFound = False
End If
End If
End If
If bFound Then
Set m_Folder = oFolder
Exit For
Else
LoopFolders oFolder.Folders
If Not m_Folder Is Nothing Then Exit For
End If
Next
End Sub

3. Premere il tasto "F5" o fare clic sul pulsante «Esegui» per avviare questa macro VBA.

4. Nella finestra di dialogo «Cerca cartella» che compare, digita il nome specifico della cartella in base al quale desideri effettuare la ricerca e fai clic sul pulsante «OK».

Nota: questa macro VBA supporta il carattere jolly asterisco (*). Ad esempio, puoi digitare tes* per trovare tutte le cartelle il cui nome inizia con «tes».

5. A questo punto viene visualizzata una finestra di dialogo con il percorso del file della cartella trovata. Per aprire la cartella individuata, fare clic sul pulsante «Sì».

La cartella trovata viene ora aperta nel Navigazione, come mostrato nell’immagine seguente:

Nota: se sono presenti più cartelle con lo stesso nome specificato, questa macro VBA ne individua e apre soltanto una.

Se avete installato «Kutools per Outlook», potete usare la funzione «Vai a» per individuare rapidamente tutte le cartelle con un determinato nome e aprire in modo semplice quella desiderata.

1. Fare clic su «KUTOOLS PLUS» > «Vai a» per attivare questa funzione.

2. Nella finestra di dialogo «Vai a», digita il nome specifico della cartella nella casella «Cerca», seleziona «Seleziona una cartella» tra i risultati della ricerca e fai clic sul pulsante «OK».

La cartella specificata con il nome indicato viene ora individuata e aperta immediatamente.