Come copiare la struttura delle cartelle di Outlook sul desktop (in Esplora file di Windows)?

Come saprai, è possibile utilizzare la funzione Archivia per copiare la struttura delle cartelle in un altro profilo di Outlook, ma sai come esportare la struttura delle cartelle di Outlook direttamente in una specifica cartella di Windows, ad esempio sul desktop? Questo articolo presenta una macro VBA che ti permette di copiare facilmente la struttura delle cartelle di Outlook in Esplora file di Windows.

Copiare le Struttura cartella di Outlook sul desktop (Esplora file di Windows)

---

Copiare le Struttura cartella di Outlook sul desktop (Esplora file di Windows)

Segui i passaggi seguenti per copiare la struttura delle cartelle di Outlook sul desktop o in Esplora file di Windows.

1. Nella Navigazione, fai clic per selezionare la cartella specifica di cui desideri copiare la struttura, quindi premi i tasti «Alt» + "F11" per aprire la finestra di Microsoft Visual Basic, Applications Edition.

2. Fai clic su «Strumenti» > «Riferimenti» per aprire la finestra di dialogo Riferimenti. Seleziona l'opzione «Microsoft Scripting Runtime», quindi conferma con il pulsante «OK». Vedi screenshot:

3. Fai clic su «Inserisci» > «Modulo» e copia e incolla il seguente codice VBA nella nuova finestra del modulo.

VBA: Copiare le Struttura cartella di Outlook in Esplora file di Windows

Dim xFSO As Scripting.FileSystemObject
Sub CopyOutlookFldStructureToWinExplorer()
    ExportAction "Copy"
End Sub
  
Sub ExportAction(xAction As String)
Dim xFolder As Outlook.Folder
Dim xFldPath As String
xFldPath = SelectAFolder()
If xFldPath = "" Then
    MsgBox "You did not select a folder. Export cancelled.", vbInformation + vbOKOnly, "Kutools for Outlook"
Else
    Set xFSO = New Scripting.FileSystemObject
    Set xFolder = Outlook.Application.ActiveExplorer.CurrentFolder
    ExportOutlookFolder xFolder, xFldPath
End If
Set xFolder = Nothing
Set xFSO = Nothing
End Sub

Sub ExportOutlookFolder(ByVal OutlookFolder As Outlook.Folder, xFldPath As String)
Dim xSubFld As Outlook.Folder
Dim xItem As Object
Dim xPath As String
Dim xFilePath As String
Dim xSubject As String
Dim xCount As Integer
Dim xFilename As String
On Error Resume Next
xPath = xFldPath & "\" & OutlookFolder.Name
'?????????,??????
If Dir(xPath, 16) = Empty Then MkDir xPath
For Each xItem In OutlookFolder.Items
    xSubject = ReplaceInvalidCharacters(xItem.Subject)
    xFilename = xSubject & ".msg"
    xCount = 0
    xFilePath = xPath & "\" & xFilename
    If xFSO.FileExists(xFilePath) Then
        xCount = xCount + 1
        xFilename = xSubject & " (" & xCount & ").msg"
        xFilePath = xPath & "\" & xFilename
    End If
    xItem.SaveAs xFilePath, olMSG
Next
For Each xSubFld In OutlookFolder.Folders
    ExportOutlookFolder xSubFld, xPath
Next
Set OutlookFolder = Nothing
Set xItem = Nothing
End Sub

Function SelectAFolder() As String
Dim xSelFolder As Object
Dim xShell As Object
On Error Resume Next
Set xShell = CreateObject("Shell.Application")
Set xSelFolder = xShell.BrowseForFolder(0, "Select a folder", 0, 0)
If Not TypeName(xSelFolder) = "Nothing" Then
    SelectAFolder = xSelFolder.self.Path
End If
Set xSelFolder = Nothing
Set xShell = Nothing
End Function
  
Function ReplaceInvalidCharacters(Str As String) As String
Dim xRegEx
Set xRegEx = CreateObject("vbscript.regexp")
xRegEx.Global = True
xRegEx.IgnoreCase = False
xRegEx.Pattern = "\||\/|\<|\>|""|:|\*|\\|\?"
ReplaceInvalidCharacters = xRegEx.Replace(Str, "")
End Function

4. Premi il tasto "F5" o fai clic sul pulsante «Esegui» per avviare la macro VBA.

5. Nella finestra di dialogo «Sfoglia cartelle» che si apre, seleziona la cartella specifica in cui desideri salvare la struttura delle cartelle copiate, quindi fai clic sul pulsante «OK». Vedi screenshot:

Ora vai nella cartella specificata: noterai che la struttura delle cartelle è stata copiata sul disco rigido indicato. Vedi screenshot:

Nota: anche gli elementi della cartella, come messaggi di posta elettronica, appuntamenti, attività e così via, vengono copiati nelle rispettive cartelle del disco rigido.

---

Articoli correlati

Come copiare la struttura di una cartella in un nuovo file di dati PST in Outlook?