Come trovare e sostituire il testo dell'oggetto all'interno di messaggi o attività in Outlook?

In Outlook, se sono presenti più messaggi o attività da sostituire con un testo specifico, è possibile modificarli uno per uno, ma esiste un metodo rapido per completare questa operazione in un colpo solo?

Trova e sostituisci il testo dell'oggetto all'interno di più messaggi utilizzando codice VBA

Trova e sostituisci il testo dell'oggetto all'interno di più attività utilizzando codice VBA

---

Trova e sostituisci il testo dell'oggetto all'interno di più messaggi utilizzando codice VBA

Per individuare un testo specifico e sostituirlo con un altro in più oggetti messaggio, il seguente codice VBA ti sarà di grande aiuto. Segui attentamente le istruzioni riportate di seguito:

1. Seleziona i messaggi di posta elettronica per cui desideri applicare Trova e sostituisci al testo dell’oggetto, quindi tieni premuti i tasti «ALT + F11» per aprire la finestra «Microsoft Visual Basic for Applications».

2. Clicca su «Inserisci» > «Modulo», copia e incolla il codice seguente nel modulo vuoto appena aperto, come mostrato nello screenshot:

Codice VBA: Trova e sostituisci il testo dell’oggetto all’interno di più messaggi:

Option Explicit
Sub FindAndReplaceInSubject()
Dim xItem As Object
Dim xNewSubject As String
Dim xMailItem As MailItem
Dim xExplorer As Explorer
Dim i As Integer
On Error Resume Next
Set xExplorer = Outlook.Application.ActiveExplorer
For i = xExplorer.Selection.Count To 1 Step -1
    Set xItem = xExplorer.Selection.Item(i)
    If xItem.Class = olMail Then
        Set xMailItem = xItem
        With xMailItem
            xNewSubject = Replace(.Subject, "kte", "Kutools for Excel")
            .Subject = xNewSubject
            .Save
        End With
    End If
Next
End Sub

Nota: Nel codice riportato sopra, `xNewSubject = Replace(.Subject, «kte», «[[PH_8]]»)`, il termine `«kte»` rappresenta il Testo Vecchio che desideri cercare, mentre `«Kutools per Excel»` è il Testo Nuovo con cui intendi sostituirlo. Personalizzali in base alle tue esigenze.

3. Premi il tasto «F5» per eseguire questo codice: il testo specifico negli oggetti dei messaggi verrà sostituito con il Testo Nuovo richiesto (vedi screenshot).

---

Trova e sostituisci il testo dell’oggetto all’interno di più attività utilizzando codice VBA

Se devi trovare e sostituire il testo dell’oggetto nelle attività, anche il seguente codice VBA potrà esserti d’aiuto.

1. Tieni premuti i tasti «ALT + F11» per aprire la finestra di «Microsoft Visual Basic for Applications».

2. Clicca su «Inserisci» > «Modulo», copia e incolla il codice seguente nel modulo vuoto appena aperto, come mostrato nello screenshot:

Codice VBA: Trova e sostituisci il testo dell’oggetto all’interno di tutte le attività:

Option Explicit
Sub FindReplaceTextsInAllTaskSubjects()
Dim xPane As NavigationPane
Dim xModule As TasksModule
Dim xGroup As NavigationGroup
Dim xNavFolder As NavigationFolder
Dim xTaskItem As Outlook.TaskItem
Dim i, k As Integer
Dim xFindStr, xReplaceStr As String
Dim xTotalCount As Long
On Error Resume Next
xFindStr = InputBox("Type the words to find:", "Kutools for Outlook", xFindStr)
If Len(Trim(xFindStr)) = 0 Then Exit Sub
xReplaceStr = InputBox("Type the words to replace:", "Kutools for Outlook", xReplaceStr)
If Len(Trim(xReplaceStr)) = 0 Then Exit Sub
xTotalCount = 0
Set xPane = Outlook.Application.ActiveExplorer.NavigationPane
Set xModule = xPane.Modules.GetNavigationModule(olModuleTasks)
Set xGroup = xModule.NavigationGroups.Item(1)
For i = xGroup.NavigationFolders.Count To 1 Step -1
    Set xNavFolder = xGroup.NavigationFolders.Item(i)
    For k = xNavFolder.Folder.Items.Count To 1 Step -1
        Set xTaskItem = xNavFolder.Folder.Items(k)
        If InStr(xTaskItem.Subject, xFindStr) > 0 Then
            xTaskItem.Subject = Replace(xTaskItem.Subject, xFindStr, xReplaceStr)
            xTaskItem.Save
            xTotalCount = xTotalCount + 1
        End If
    Next
Next
MsgBox xTotalCount & " task subjects have been changed!", vbInformation + vbOKOnly, "Kutools for Outlook"
End Sub

3. Premi il tasto «F5» per eseguire il codice: apparirà una finestra di dialogo in cui inserire il testo da cercare negli oggetti delle attività (vedi screenshot).

4. Clicca su «OK» e apparirà un’altra finestra di dialogo in cui inserire il testo nuovo con cui desideri sostituire quello trovato, come mostrato nello screenshot:

5. Clicca quindi su «OK»: verrà visualizzata una finestra di dialogo con il numero di righe oggetto modificate, come mostrato nello screenshot:

6. Clicca su «OK» e il Testo Vecchio negli oggetti delle attività verrà sostituito con quello nuovo, come mostrato nello screenshot: