Come modificare automaticamente la firma in base ai destinatari in Outlook?

Per impostazione predefinita, Outlook include una funzione integrata che cambia automaticamente la firma quando si inviano e-mail da account diversi. In aggiunta, di seguito viene illustrato un metodo per modificare automaticamente la firma in base ai destinatari presenti nel campo A:.

Modifica automatica della firma in base ai destinatari con codice VBA

---

Modifica automatica della firma in base ai destinatari con codice VBA

Segui i passaggi indicati di seguito per applicare firme diverse ai rispettivi destinatari quando invii e-mail in Outlook.

1. Innanzitutto, disattiva la funzione di allegazione automatica della firma in Outlook. Fai clic su File > Opzioni per aprire la finestra Opzioni di Outlook.

2. Nella finestra Opzioni di Outlook, seleziona Posta nel riquadro sinistro, quindi fai clic sul pulsante Firme nella sezione Componi messaggi. Vedere lo screenshot:

3. Nella finestra di dialogo Firme e carta intestata, passare alla sezione Scegli firma predefinita sotto la scheda Firma e-mail, selezionare un account di posta elettronica dall’elenco a discesa Account di posta elettronica e scegliere quindi (nessuna) nei menu a discesa Nuovi messaggi e Risposte/inoltri. Ripetere questi passaggi finché tutti gli account non saranno impostati su (nessuna). Fare infine clic sul pulsante OK.

Nota: In questa finestra di dialogo Firme e carta intestata puoi anche creare le firme che ti servono.

4. Fare clic sul pulsante OK per tornare alla finestra Opzioni di Outlook.

5. Premere i tasti Alt+F11 per aprire la finestra di Microsoft Visual Basic for Applications.

6. Nella finestra di Microsoft Visual Basic for Applications, fai doppio clic su ThisOutlookSession nel riquadro sinistro per aprire la finestra del codice e incollare il seguente codice VBA. Guarda lo screenshot:

Codice VBA: Modifica automatica della firma in base ai destinatari in Outlook

Private Sub Application_ItemSend(ByVal Item As Object, Cancel As Boolean)
'Updated by ExtendOffice 2022/08/01
Dim xMailItem As MailItem
Dim xRecipients As Recipients
Dim xRecipient As Recipient
Dim xRcpAddress As String
Dim xSignatureFile, xSignaturePath As String
Dim xFSO As Scripting.FileSystemObject
Dim xDoc As Document
Dim xFindStr As String
On Error Resume Next
Set xFSO = New Scripting.FileSystemObject
If Item.Class <> olMail Then Exit Sub
Set xMailItem = Item
Set xRecipients = xMailItem.Recipients
xSignaturePath = CreateObject("WScript.Shell").SpecialFolders(5) + "\Microsoft\Signatures\"
For Each xRecipient In xRecipients
    If xRecipient.AddressEntry.AddressEntryUserType = olExchangeUserAddressEntry Then
        xRcpAddress = xRecipient.AddressEntry.GetExchangeUser.PrimarySmtpAddress
    Else
        xRcpAddress = xRecipient.AddressEntry.Address
    End If
    Select Case xRcpAddress
        Case "Email Address 1"
            xSignatureFile = xSignaturePath & "aaa.htm"
            Exit For
        Case "Email Address 2", "Email Address 3"
            xSignatureFile = xSignaturePath & "bbb.htm"
            Exit For
        Case "Email Address 4"
            xSignatureFile = xSignaturePath & "ccc.htm"
            Exit For
    End Select
Next
VBA.DoEvents
Set xDoc = xMailItem.GetInspector.WordEditor
xFindStr = "From: " & xMailItem.Recipients.Item(1).Name & " <" & xRcpAddress & ">"
If VBA.InStr(1, xMailItem.Body, xFindStr) <> 0 Then
    xDoc.Application.Selection.HomeKey Unit:=wdStory, Extend:=wdMove
    With xDoc.Application.Selection.Find
        .ClearFormatting
        .Text = xFindStr
        .Execute Forward:=True
    End With
    With xDoc.Application.Selection
        .MoveLeft wdCharacter, 2
        .InsertParagraphAfter
        .MoveDown Unit:=wdLine, Count:=1
    End With
Else
    With xDoc.Application.Selection
        .EndKey Unit:=wdStory, Extend:=wdMove
        .InsertParagraphAfter
        .MoveDown Unit:=wdLine, Count:=1
    End With
End If
xDoc.Application.Selection.InsertFile FileName:=xSignatureFile, Link:=False, Attachment:=False
End Sub

Note:

• 1). Nel codice VBA, sostituisci "Indirizzo Email 1/2/3/4" con l’indirizzo email specifico dei destinatari.
• 2). "aaa.htm", "bbb.htm« e »ccc.htm" sono le firme personalizzate che invierete ai rispettivi destinatari.
• 3). In questo caso, la firma "aaa« verrà inviata a »Indirizzo Email 1«, la firma »bbb« verrà inviata a »Indirizzo Email 2« e a »Indirizzo Email 3", mentre "Indirizzo Email 4« riceverà l'e-mail con la firma »ccc" incorporata. Personalizzale in base alle tue esigenze.
• 4). Se un’e-mail contiene più destinatari, il codice considera soltanto il primo; di conseguenza, tutti gli altri destinatari riceveranno l’e-mail con la stessa firma del primo.

7. Fare quindi clic su Strumenti > Riferimenti per aprire la finestra di dialogo Riferimenti - Progetto. Nella finestra di dialogo, selezionare sia la libreria Microsoft Word Object Library sia l’opzione Microsoft Scripting Runtime, quindi fare clic sul pulsante OK. Vedere lo screenshot:

8. Premere i tasti Alt + Q per chiudere la finestra di Microsoft Visual Basic for Applications.

D’ora in poi, dopo aver composto un’e-mail e aver premuto il pulsante Invia, la firma corrispondente verrà inserita automaticamente alla fine del messaggio in base all’indirizzo e-mail del destinatario nel campo A:.

---