Come creare un appuntamento a partire dai dati di Excel?

Supponiamo che tu abbia una tabella di dati relativi ad appuntamenti in un foglio di lavoro Excel, come mostrato nello screenshot seguente. Come puoi importare rapidamente questi dati nel calendario di Outlook?

Crea appuntamenti dai dati di Excel con codice VBA

---

Crea appuntamenti dai dati di Excel con codice VBA

Per creare appuntamenti a partire dai dati di Excel, puoi utilizzare il seguente codice VBA. Segui questi passaggi:

1. Avvia Outlook e tieni premuti i tasti ALT + F11 per aprire la finestra di Microsoft Visual Basic for Applications.

2. Fai clic su Inserisci > Modulo e incolla il codice seguente nella finestra del Modulo.

Codice VBA: Importa dati da Excel negli appuntamenti:

Public Sub CreateOutlookApptz()
    Dim xAppointmentItem As Outlook.AppointmentItem
    Dim xNameSpace As Outlook.NameSpace
    Dim xCalendarFld As Outlook.MAPIFolder, xSubFolder As Outlook.MAPIFolder
    Dim xCalendarStr As String
    Dim I As Long
    Dim xFileDialog As FileDialog
    Dim xFilePath As String
    Dim xExcelApp As Excel.Application
    Dim xWb As Workbook
    Dim xWs As Worksheet
    On Error GoTo Err_Execute
    Set xExcelApp = New Excel.Application
    Set xFileDialog = xExcelApp.FileDialog(msoFileDialogFilePicker)
    With xFileDialog
        .Title = "Select a file"
        .Filters.Add "Microsoft Excel", "*.xlsx"
    End With
    If xFileDialog.Show = 0 Then Exit Sub
    xFilePath = xFileDialog.SelectedItems(1)
    Set xWb = xExcelApp.Workbooks.Open(xFilePath)
    Set xNameSpace = Outlook.Application.Session
    Set xCalendarFld = xNameSpace.GetDefaultFolder(olFolderCalendar)
    I = 2
    Set xWs = xWb.Worksheets.Item(1)
    xCalendarStr = xWb.Name
    If FolderExist(xCalendarFld, xCalendarStr) = False Then
        Set xSubFolder = xCalendarFld.Folders.Add(xCalendarStr, olFolderCalendar)
    Else
        Set xSubFolder = xCalendarFld.Folders(xCalendarStr)
    End If
    Do Until Trim(xWs.Cells(I, 1).Value) = ""
        Set xAppointmentItem = xSubFolder.Items.Add(olAppointmentItem)
        With xAppointmentItem
            .Start = xWs.Cells(I, 5) + xWs.Cells(I, 6)
            .End = xWs.Cells(I, 7) + xWs.Cells(I, 8)
            .Subject = xWs.Cells(I, 1)
            .Location = xWs.Cells(I, 2)
            .Body = xWs.Cells(I, 3)
            .BusyStatus = olBusy
            .ReminderMinutesBeforeStart = xWs.Cells(I, 9)
            .ReminderSet = True
            .Categories = xWs.Cells(I, 4)
            .Save
        End With
        I = I + 1
    Loop
    Set xAppointmentItem = Nothing
    Set olApp = Nothing
    xExcelApp.Quit
    Set xExcelApp = Nothing
    MsgBox "Import successfully!", vbInformation, "Kutools for Outlook"
    Exit Sub
Err_Execute:
    MsgBox "An error occurred - Exporting items to Calendar.", vbInformation, "Kutools for Outlook"
End Sub
Function FolderExist(CalFolder As Folder, FolderName As String) As Boolean
    Dim I As Integer
    Dim xSubFolder As Folder
    For I = 1 To CalFolder.Folders.Count
        Set xSubFolder = CalFolder.Folders.Item(I)
        If xSubFolder.Name = FolderName Then
            FolderExist = True
            Exit Function
        End If
    Next I
End Function

3. Sempre nella finestra di Microsoft Visual Basic for Applications, fai clic su Strumenti > Riferimenti per aprire la finestra di dialogo Riferimenti - Progetto1, quindi seleziona l'opzione Microsoft Excel Object Library dall'elenco dei Riferimenti disponibili, come illustrato nello screenshot:

4. Fai quindi clic sul pulsante OK, poi premi il tasto F5 per eseguire questo codice. Verrà visualizzata la finestra Seleziona un file, in cui dovrai selezionare il file Excel che desideri importare in Outlook, come mostrato nello screenshot:

5.Quindi fai clic su OK, verrà visualizzata una finestra di avviso come segue:

6. Fai quindi clic su OK: i dati di Excel sono stati importati nel calendario, come mostrato nello screenshot seguente: