Come esportare la struttura delle cartelle da Outlook a Excel?

In questo articolo ti mostrerò come esportare la struttura delle cartelle di un account da Outlook a un file Excel. Segui attentamente le istruzioni riportate di seguito.

Esportare Struttura cartella di un account da Outlook a Excel utilizzando codice VBA

---

Esportare Struttura cartella di un account da Outlook a Excel utilizzando codice VBA

Il seguente codice VBA potrebbe esserle utile; proceda seguendo i passaggi indicati di seguito:

1. Avvia Excel e tieni premuti i tasti ALT + F11 per aprire la finestra di Microsoft Visual Basic for Applications.

2. Fai clic su Inserisci > Modulo e incolla il codice seguente nella finestra del Modulo.

Codice VBA: Esportare Struttura cartella di un account da Outlook a Excel:

Dim xExcelApp As Excel.Application
Dim xWb As Excel.Workbook
Dim xWs As Excel.Worksheet
Dim xMainFolderCount As Long
Sub OutlookExportFolderStructureToExcel()
    Dim xFolder As Folder
    Dim xExcelFile As String
    Dim xFileDialog As FileDialog
    On Error Resume Next
    Set xFolder = Outlook.Application.Session.PickFolder
    If xFolder Is Nothing Then Exit Sub
    Set xExcelApp = New Excel.Application
    Set xWb = xExcelApp.Workbooks.Add
    Set xWs = xWb.Sheets(1)
    With xWs.Range("A1", "A1")
         .Value = "Folder Structure"
         .Font.Size = 14
         .Font.Bold = True
    End With
    xMainFolderCount = Len(xFolder.FolderPath) - Len(Replace(xFolder.FolderPath, "\", "")) + 1
    Call ExportToExcel(xFolder.FolderPath, xFolder.Name)
    Call ProcessFolders(xFolder.Folders)
    xWs.Columns("A").AutoFit
    Set xFileDialog = xExcelApp.FileDialog(msoFileDialogSaveAs)
    With xFileDialog
        .AllowMultiSelect = False
        .FilterIndex = 1
        If .Show = 0 Then
            xWb.Close False
            xExcelApp.Quit
            Set xExcelApp = Nothing
            Exit Sub
        End If
        xExcelFile = .SelectedItems.Item(1)
    End With
    xWb.Close True, xExcelFile
    MsgBox "Export complete!", vbExclamation, "Kutools for Outlook"
End Sub

Sub ProcessFolders(ByVal xFlds As Folders)
    Dim xSubFolder As Folder
    For Each xSubFolder In xFlds
        If xSubFolder.Name <> "Conversation Action Settings" And xSubFolder.Name <> "Quick Step Settings" Then
           Call ExportToExcel(xSubFolder.FolderPath, xSubFolder.Name)
           Call ProcessFolders(xSubFolder.Folders)
        End If
    Next
End Sub

Sub ExportToExcel(ByRef xFolderPath As String, xFolderName As String)
    Dim i, n As Long
    Dim xPrefix As String
    Dim xLastRow As Integer
    i = Len(xFolderPath) - Len(Replace(xFolderPath, "\", "")) - xMainFolderCount
    For n = 0 To i
        xPrefix = xPrefix & "-"
    Next
    xFolderName = xPrefix & xFolderName
    xLastRow = xWs.UsedRange.Rows.Count + 1
    xWs.Range("A" & xLastRow) = xFolderName
End Sub

3.Sempre nella finestra di Microsoft Visual Basic for Applications, faccia clic su Strumenti>Riferimentiper aprire la finestra di dialogo Riferimenti - Progetto1e selezioni l'opzione Microsoft Excel Object Librarydall'elenco dei Riferimenti disponibili, come mostrato nello screenshot:

4. Quindi, faccia clic sul pulsante OK e prema il tasto F5 per eseguire il codice. Si aprirà una finestra di dialogo Seleziona cartella; selezioni l’account di posta elettronica di cui desidera esportare la struttura delle cartelle, come mostrato nello screenshot:

5. Successivamente, faccia clic sul pulsante OK e si aprirà la finestra Salva file; specifichi quindi una posizione e un nome per il file esportato, come mostrato nello screenshot:

6. Infine, faccia clic sul pulsante Salva e potrà recarsi nella cartella di lavoro Excel specificata per visualizzare la struttura della cartella esportata, come mostrato nello screenshot: