Come stampare le attività per categoria in Outlook?

Si supponga di avere diverse categorie colore assegnate alle attività in Outlook e di voler stampare gli elenchi delle attività, suddivisi per categoria, su pagine separate. In che modo è possibile eseguire questa operazione in Outlook?

Stampa delle attività in base alle categorie su pagine diverse manualmente, una alla volta

Stampa delle attività in base alle categorie su pagine diverse con codice VBA

---

Stampa delle attività in base alle categorie su pagine diverse manualmente, una alla volta

In Outlook è possibile stampare manualmente le attività suddivise per categoria, con ciascuna categoria su una pagina separata. Procedere come segue:

1. Avvia Outlook, passa al riquadro Attività, seleziona la cartella delle attività da stampare, quindi premi Ctrl + E per attivare la casella Cerca. Nella scheda Cerca, fai clic sull’icona Per categoria e scegli la categoria colorata da stampare, come illustrato nello screenshot:

2. A questo punto, tutte le attività appartenenti alla categoria colorata selezionata verranno visualizzate immediatamente, come illustrato nello screenshot:

3. Fare quindi clic su File > Stampa per stampare questo elenco di attività, come illustrato nello screenshot seguente:

4. Ripeti i passaggi precedenti per stampare manualmente, uno alla volta, gli elenchi delle attività appartenenti alle altre categorie colore.

---

Stampa delle attività in base alle categorie su pagine diverse con codice VBA

Di seguito trovi un codice VBA che ti permette di stampare in un’unica operazione le attività raggruppate per categoria, ciascuna su una pagina dedicata. Segui questi passaggi:

1. Passa al riquadro Attività e seleziona la cartella delle attività da stampare.

2. Tenere premuti i tasti ALT + F11 per aprire la finestra di Microsoft Visual Basic, Applications.

3. Fare quindi clic su Inserisci > Modulo, quindi copiare e incollare il codice seguente nel modulo vuoto aperto:

Codice VBA: stampa delle attività in base alle categorie su pagine diverse:

Sub PrintTaskList_SpecificColorCategory()
    Dim xTaskItems As Outlook.Items
    Dim xTask As Outlook.TaskItem
    Dim xDictionary As Scripting.Dictionary
    Dim xCategoryArr As Variant, xCategory As Variant
    Dim xExcelApp As Excel.Application
    Dim xExcelWorkbook As Excel.Workbook
    Dim xExcelWorksheet As Excel.Worksheet
    Dim xSheet As Excel.Worksheet
    Dim xKey As Variant
    Dim xKeyStr As String
    Dim i As Long, xLastRow As Integer
    On Error Resume Next
    If Application.ActiveExplorer.CurrentFolder.DefaultItemType <> olTaskItem Then Exit Sub
    Set xTaskItems = Application.ActiveExplorer.CurrentFolder.Items
    Set xDictionary = New Scripting.Dictionary
    For Each xTask In xTaskItems
        xCategoryArr = Split(xTask.Categories, ",")
        For Each xCategory In xCategoryArr
            If xDictionary.Exists(Trim(xCategory)) = False Then
               xDictionary.Add Trim(xCategory), 0
            End If
        Next
    Next
    If xDictionary.Count = 0 Then
        MsgBox "The current Task doesn’t have any category", vbOKOnly + vbInformation, "Kutools for Outlook"
        Exit Sub
    End If
    Set xExcelApp = New Excel.Application
    Set xExcelWorkbook = xExcelApp.Workbooks.Add
    xExcelApp.Visible = True
    i = 0
    If xDictionary.Count > xExcelWorkbook.Sheets.Count Then
        xExcelWorkbook.Sheets.Add Count:=xDictionary.Count - xExcelWorkbook.Sheets.Count
    End If
    For Each xKey In xDictionary.Keys
        xKeyStr = CStr(xKey)
        i = i + 1
        Set xExcelWorksheet = xExcelWorkbook.Sheets(i)
        xExcelWorksheet.Name = xKeyStr
        With xExcelWorksheet
             .Range("A1") = xKeyStr
             .Range("A1").Font.Bold = True
             .Range("A1").Font.Size = 18
             .Range("A1", "C1").HorizontalAlignment = xlCenter
             .Range("A1", "C1").VerticalAlignment = xlCenter
             .Range("A1", "C1").Merge
             .Range("A2") = "Subject"
             .Range("A2").Font.Bold = True
             .Range("B2") = "Start Date"
             .Range("B2").Font.Bold = True
             .Range("C2") = "Due Date"
             .Range("C2").Font.Bold = True
        End With
        For Each xTask In xTaskItems
            If InStr(xTask.Categories, xKeyStr) > 0 Then
               xLastRow = xExcelWorksheet.UsedRange.Rows.Count + 1
               With xExcelWorksheet
                    .Range("A" & xLastRow) = xTask.Subject
                    .Range("B" & xLastRow) = xTask.StartDate
                    .Range("C" & xLastRow) = xTask.DueDate
               End With
            End If
        Next
        xExcelWorksheet.Columns("A:C").AutoFit
    Next
    For Each xSheet In xExcelWorkbook.Sheets
        xSheet.PrintOut
    Next
    xExcelWorkbook.Close False
    xExcelApp.Quit
End Sub

4. Fare quindi clic su Strumenti > Riferimenti nella finestra di Microsoft Visual Basic, Applications. Nella finestra di dialogo Riferimenti - Progetto1 visualizzata, selezionare le opzioni Microsoft Excel Object Library e Microsoft Scripting Runtime dall’elenco Riferimenti disponibili, come mostrato nello screenshot:

5. Fare quindi clic sul pulsante OK, quindi premere il tasto F5 per eseguire il codice. Al termine dell’esecuzione, gli elenchi delle attività suddivisi per categoria verranno stampati su pagine distinte.