Outlook: come inviare automaticamente nuovamente un'email se non si riceve risposta

Quando invii un'email a un collega, a un partner commerciale o a qualcun altro e hai bisogno di una risposta con urgenza, puoi impostare un'opzione per l'invio automatico dell'email nel caso in cui la risposta non arrivi entro un determinato periodo.

Utilizzo di Promemoria e VBA per impostare l'invio automatico in assenza di risposta

---

Utilizzo di Promemoria e VBA per impostare l'invio automatico in assenza di risposta

Parte 1: imposta un promemoria per essere avvisato entro un orario specifico

1. Fai clic con il tasto destro su un'email nella cartella **Elementi inviati** che desideri reinviare in caso di mancata risposta, quindi seleziona **Segui** > **Aggiungi promemoria** dal menu contestuale.

2. Nella finestra di dialogo «Personalizza» visualizzata, assicurati che la casella di controllo «Promemoria» sia selezionata, quindi imposta la data e l’orario entro i quali desideri ricevere la risposta utilizzando i menu a discesa sottostanti oppure digitandoli direttamente nelle apposite caselle. Fai clic su «OK».

Parte 2: inserisci una macro VBA per reinviare le email se non si riceve risposta entro il tempo specificato

3. Premi i tasti «Alt» + «F11» per aprire la finestra di Microsoft Visual Basic for Applications.

4. Fai doppio clic su «ThisOutlookSession» nel riquadro «Progetto – Project1» per aprire uno script vuoto, quindi copia e incolla il codice VBA riportato di seguito al suo interno.

VBA: reinviare un'email se non si riceve risposta

Public WithEvents GInboxItems As Outlook.Items
'UpdatebyExtendoffice20220413
Private Sub Application_Startup()
  Dim xInboxFld As Folder
  Set xInboxFld = Application.Session.GetDefaultFolder(olFolderInbox)
  Set GInboxItems = xInboxFld.Items
End Sub

'Judge
Private Sub GInboxItems_ItemAdd(ByVal Item As Object)
  Dim xSentItems As Outlook.Items
  Dim xMail As MailItem
  Dim i As Long
  Dim xSubject As String
  Dim xItemSubject As String
  Dim xSendTime As String
  On Error Resume Next
  Set xSentItems = Application.Session.GetDefaultFolder(olFolderSentMail).Items
  If Item.Class <> olMail Then Exit Sub
  For i = xSentItems.Count To 1 Step -1
    If xSentItems.Item(i).Class = olMail Then
      Set xMail = xSentItems.Item(i)
      xSubject = LCase(xMail.Subject)
      xSendTime = xMail.SentOn
      xItemSubject = LCase(Item.Subject)
      If (xItemSubject = "re: " & xSubject) Or (InStr(xItemSubject, xSubject) > 0) Then
        If Item.SentOn > xSendTime Then
           With xMail
             .ClearTaskFlag
             .ReminderSet = False
             .Save
           End With
        End If
      End If
    End If
  Next i
End Sub

'Reminder
Private Sub Application_Reminder(ByVal Item As Object)
  Dim xPrompt As String
  Dim xResponse As Integer
  Dim xFollowUpMail As Outlook.MailItem
  Dim xRcp As Recipient
  On Error Resume Next
  'Resend
  If (Item.Class <> olMail) Then Exit Sub
  xPrompt = "You haven't yet received the reply of " & Chr(34) & Item.Subject & Chr(34) & " within your expected time. Do you want to send a follow-up notification email?"
  xResponse = MsgBox(xPrompt, vbYesNo + vbQuestion, "Kutools for Outlook")
  If xResponse = vbNo Then Exit Sub
  Set xFollowUpMail = Application.CreateItem(olMailItem)
  With xFollowUpMail
    For Each xRcp In Item.Recipients
      .Recipients.Add (xRcp.Address)
    Next
    .Recipients.ResolveAll
    .Subject = "Follow Up: " & Chr(34) & Item.Subject & Chr(34)
    .Body = "Please respond to my email " & Chr(34) & Item.Subject & Chr(34) & " as soon as possible"
    .Attachments.Add Item
    .Display
  End With
End Sub

5. Salva il codice, quindi torna all’interfaccia principale. Fai clic su «File» > «Opzioni»; nella finestra «Opzioni di Outlook», seleziona «Centro protezione» nel riquadro sinistro e poi fai clic su «Impostazioni Centro protezione» per aprire la relativa finestra. Scegli «Impostazioni macro» e assicurati che, nella sezione di destra, sia selezionata l’opzione «Abilita tutte le macro (non consigliato; è possibile eseguire codice potenzialmente pericoloso)». Conferma facendo clic su «OK» > «OK».

6. Ora, se un'email inviata e contrassegnata con un promemoria non riceve alcuna risposta al raggiungimento dell’orario specificato, verrà visualizzata una finestra di dialogo per chiederti se desideri reinviarla come sollecito.

7. Fai clic su «Sì»: si aprirà una finestra di messaggio con l’email precedente allegata; potrai modificare il corpo del messaggio e inviarla nuovamente facendo clic su «Invia».

8. Fai clic su «No»: il promemoria verrà eliminato.

Nota: se l’email viene risposta prima dell’orario specificato, il promemoria verrà automaticamente rimosso dalla macro VBA.