Formula Excel: Estrai testo da destra fino al carattere

In questo tutorial viene fornita una formula per estrarre il testo dalla parte destra del testo dato fino a quando non incontra un carattere specificato, spiegando anche gli argomenti di ogni formula.

Formula generica:

SE.ERRORE(DESTRA(txt;LUNGHEZZA(txt)-RICERCA("$";SOSTITUISCI(txt;" char";"$";LUNGHEZZA(txt)-LUNGHEZZA(SOSTITUISCI(txt;"char";""))))); txt)

Argomenti

Txt: il riferimento della cella o la stringa di testo che utilizzi.

Char: il carattere fino al quale vuoi estrarre il testo da destra.

Nota

Se la formula non trova il carattere specificato, restituisce i dati originali.

Come funziona questa formula

Ad esempio, se devi estrarre il testo dalla parte destra della stringa di testo nella cella B3 fino allo spazio, utilizza la seguente formula:

=SE.ERRORE(DESTRA(B3;LUNGHEZZA(B3)-RICERCA("$";SOSTITUISCI(B3;" ";"$";LUNGHEZZA(B3)-LUNGHEZZA(SOSTITUISCI(B3;" ";""))))); B3)

Premi Invio per estrarre il testo.

Spiegazione

SOSTITUISCI funzione viene utilizzata per sostituire un testo o un carattere con uno nuovo. Qui la formula SOSTITUISCI(B3;" ";"") nella formula lunga sostituisce lo spazio con nulla e restituisce “Gotolastcell”.

LUNGHEZZA funzione conta il numero di caratteri nel testo dato. Ora LUNGHEZZA(SOSTITUISCI(B3;" ";"")) può essere visto come LUNGHEZZA(“Gotolastcell”) che restituisce 12.

Quindi la formula LUNGHEZZA(B3)-LUNGHEZZA(SOSTITUISCI(B3;" ";"")) restituisce 3. Quindi la formula SOSTITUISCI(B3;" ";"$";LUNGHEZZA(B3)-LUNGHEZZA(SOSTITUISCI(B3;" ";""))) può essere vista come SOSTITUISCI(B3;" ";"$";3), che restituisce “Go to last$cell”.

RICERCA funzione trova la posizione del testo in un dato testo. La formula RICERCA("$";SOSTITUISCI(B3;" ";"$";LUNGHEZZA(B3)-LUNGHEZZA(SOSTITUISCI(B3;" ";""))))) può essere vista come RICERCA("$";"Go to last$cell") che restituisce 11.

Funzione DESTRA estrae il testo dal lato destro del testo. Qui DESTRA(B3;LUNGHEZZA(B3)-RICERCA("$";SOSTITUISCI(B3;" ";"$";LUNGHEZZA(B3)-LUNGHEZZA(SOSTITUISCI(B3;" ";""))))) può essere visto come
DESTRA(B3;LUNGHEZZA(B3)-11)
=DESTRA(B3;3)
=”cell”

Funzione SE.ERRORE viene utilizzata per intercettare e gestire gli errori. Qui, se la formula non trova il carattere “ “, restituisce i dati originali.

File di esempio

Clicca per scaricare il file di esempio

---

Formule relative

• Prima lettera minuscola
  Qui viene introdotta la formula per aggiungere nuovo testo in una certa posizione della stringa di testo.
• Riduci il testo a N parole
  Qui viene introdotta la formula per estrarre n parole dal lato sinistro di una stringa di testo.
• Aggiungi zeri iniziali per fissare la lunghezza
  Questo tutorial fornisce formule per aggiungere zeri iniziali per rendere il testo della stessa lunghezza.
• Aggiungi trattini al numero di telefono
  Per aggiungere trattini al numero di telefono, puoi usare una formula per risolverlo in Excel.

---

Funzioni relative

• Funzione DESTRA
  Estrai testo dal lato destro.
• Funzione SOSTITUISCI
  Sostituisci il vecchio testo con uno nuovo.
• Funzione LUNGHEZZA
  Ottieni il numero di caratteri nel testo.
• Funzione RICERCA
  Trova la posizione di un carattere o sottostringa specifica dalla stringa di testo data.
• Funzione TROVA
  Trova una stringa all'interno di un'altra stringa