Skip to main content

Rimuovi il testo prima o dopo il primo o l'ultimo carattere specifico dalle stringhe di testo

Author: Xiaoyang Last Modified: 2025-08-06

Questa guida spiegherà come rimuovere il testo prima o dopo il primo o l'ultimo carattere specifico, come uno spazio o una virgola, da una lista di stringhe di testo in Excel.

doc-remove-after-first-space-01

Rimuovi il testo prima o dopo il primo carattere specifico dalle stringhe di testo

Rimuovi il testo prima del primo carattere specifico (come uno spazio, una virgola)

Per rimuovere il testo prima del primo carattere specifico dalle stringhe di testo, le funzioni DESTRA, LUNGHEZZA e TROVA possono aiutarti. La sintassi generica è:

=DESTRA(cella; LUNGHEZZA(cella)-TROVA("carattere"; cella))
  • cella: Il riferimento alla cella o la stringa di testo dalla quale vuoi rimuovere il testo.
  • carattere: Il separatore specifico in base al quale vuoi rimuovere il testo.

Inserisci o copia la seguente formula in una cella vuota dove desideri ottenere il risultato:

=DESTRA(A2;LUNGHEZZA(A2)-TROVA(" ";A2))

Quindi, trascina la maniglia di riempimento verso il basso fino alle celle in cui vuoi applicare questa formula, e tutto il testo prima del primo spazio verrà rimosso dalle stringhe di testo, come mostrato nello screenshot:

doc-remove-after-first-space-02

Spiegazione della formula:

1.LUNGHEZZA(A2)-TROVA(" ";A2): Questa parte della formula viene riconosciuta come num_caratteri all'interno della funzione DESTRA.

  • TROVA(" ";A2): La funzione TROVA viene utilizzata per ottenere la posizione del primo spazio, restituisce il numero 11.
  • LUNGHEZZA(A2): Questa funzione LUNGHEZZA restituirà il numero totale di caratteri nella cella A2. Otterrà il numero 27.
  • LUNGHEZZA(A2)-TROVA(" ";A2)=27-11: Sottraendo la posizione del primo spazio dalla lunghezza totale della cella A2 si ottiene il numero di caratteri che si trovano dopo il primo spazio.

2. DESTRA(A2;LUNGHEZZA(A2)-TROVA(" ";A2))=DESTRA(A2; 16): Infine, questa funzione DESTRA estrarrà 16 caratteri dal lato destro della stringa di testo nella cella A2.

Rimuovi il testo dopo il primo carattere specifico (come uno spazio, una virgola)

In Excel, combinando le funzioni SINISTRA e TROVA, puoi rimuovere rapidamente il testo dopo il primo carattere specifico. La sintassi generica è:

=SINISTRA(cella;TROVA("carattere";cella)-1)
  • cella: Il riferimento alla cella o la stringa di testo dalla quale vuoi rimuovere il testo.
  • carattere: Il separatore specifico in base al quale vuoi rimuovere il testo.

Applica la seguente formula in una cella vuota:

=SINISTRA(A2;TROVA(" ";A2)-1)

Quindi, trascina la maniglia di riempimento verso il basso fino alle celle in cui vuoi applicare questa formula, e tutto il testo dopo il primo spazio verrà rimosso immediatamente, come mostrato nello screenshot:

doc-remove-after-first-space-03

Spiegazione della formula:

1.TROVA(" ";A2)-1: Questa funzione TROVA otterrà la posizione del primo spazio nella cella A2, sottraendo 1 significa escludere il carattere spazio. Otterrà il risultato 10. È riconosciuto come num_caratteri all'interno della funzione SINISTRA.

2. SINISTRA(A2;TROVA(" ";A2)-1)=SINISTRA(A2; 10): Questa funzione SINISTRA estrarrà 10 caratteri dal lato sinistro della stringa di testo nella cella A2.

Rimuovi il testo prima o dopo l'ultimo carattere specifico dalle stringhe di testo

Rimuovi il testo prima dell'ultimo carattere specifico (come uno spazio, una virgola)

Se hai bisogno di rimuovere tutto il testo prima dell'ultimo carattere specifico e lasciare solo le sottostringhe dopo l'ultimo carattere specifico, le funzioni DESTRA, LUNGHEZZA, RICERCA e SOSTITUISCI possono esserti d'aiuto. La sintassi generica è:

=DESTRA(cella;LUNGHEZZA(cella)-RICERCA("#";SOSTITUISCI(cella;"carattere";"#";LUNGHEZZA(cella)-LUNGHEZZA(SOSTITUISCI(cella;"carattere";"")))))
  • cella: Il riferimento alla cella o la stringa di testo dalla quale vuoi rimuovere il testo.
  • carattere: Il separatore specifico in base al quale vuoi rimuovere il testo.

Per risolvere questo compito, copia o inserisci la seguente formula in una cella vuota:

=DESTRA(A2;LUNGHEZZA(A2)-RICERCA("#";SOSTITUISCI(A2;" ";"#";LUNGHEZZA(A2)-LUNGHEZZA(SOSTITUISCI(A2;" ";"")))))

Quindi, trascina la maniglia di riempimento per applicare questa formula ad altre celle necessarie, e ora tutto il testo prima dell'ultimo spazio sarà stato eliminato, lasciando solo il testo dopo l'ultimo spazio, come mostrato nello screenshot:

doc-remove-after-first-space-04

Spiegazione della formula:

1. LUNGHEZZA(A2)-RICERCA("#";SOSTITUISCI(A2;" ";"#";LUNGHEZZA(A2)-LUNGHEZZA(SOSTITUISCI(A2;" ";"")))):

  • SOSTITUISCI(A2;" ";""): Questa funzione SOSTITUISCI viene utilizzata per sostituire tutti i caratteri spazio con nulla nella cella A2, e otterrai il risultato come questo: “Tom-Grade1HoustonTexasUS”.
  • LUNGHEZZA(SOSTITUISCI(A2;" ";""): Questa funzione LUNGHEZZA restituisce il numero di caratteri della stringa di testo restituita dalla funzione SOSTITUISCI senza spazi. Otterrà il numero 24.
  • LUNGHEZZA(A2)-LUNGHEZZA(SOSTITUISCI(A2;" ";"")=27-24: Sottraendo il numero di caratteri senza spazio dalla lunghezza totale della cella A2 si otterrà il numero degli spazi tra la stringa di testo. Questo darà il numero 3.
  • SOSTITUISCI(A2;" ";"#";LUNGHEZZA(A2)-LUNGHEZZA(SOSTITUISCI(A2;" ";"")))= SOSTITUISCI(A2;" ";"#"; 3): Questa funzione SOSTITUISCI viene utilizzata per sostituire l'ultimo carattere spazio con un carattere # specifico, il risultato è: “Tom-Grade1 Houston Texas#US”.
  • RICERCA("#";SOSTITUISCI(A2;" ";"#";LUNGHEZZA(A2)-LUNGHEZZA(SOSTITUISCI(A2;" ";""))))= RICERCA("#"; "Tom-Grade1 Houston Texas#US") : Questa funzione RICERCA troverà la posizione del carattere # specifico all'interno della stringa di testo restituita dalla funzione SOSTITUISCI. Otterrà il numero 25.
  • LUNGHEZZA(A2)-RICERCA("#";SOSTITUISCI(A2;" ";"#";LUNGHEZZA(A2)-LUNGHEZZA(SOSTITUISCI(A2;" ";""))))=27-25: La lunghezza totale del testo nella cella A2 sottrae la posizione dell'ultimo spazio, otterrà il numero dei caratteri che si trovano dopo l'ultimo spazio. E questo darà il numero 2.

2. DESTRA(A2;LUNGHEZZA(A2)-RICERCA("#";SOSTITUISCI(A2;" ";"#";LUNGHEZZA(A2)-LUNGHEZZA(SOSTITUISCI(A2;" ";"")))))=DESTRA(A2; 2): Infine, questa funzione DESTRA estrarrà 2 caratteri dal lato destro della stringa di testo nella cella A2.

Rimuovi il testo dopo l'ultimo carattere specifico (come uno spazio, una virgola)

Per rimuovere il testo dopo l'ultimo carattere specifico, le funzioni SINISTRA, TROVA, SOSTITUISCI e LUNGHEZZA possono aiutarti. La sintassi generica è:

=SINISTRA(cella;TROVA("#";SOSTITUISCI(cella;"carattere";"#";LUNGHEZZA(cella)-LUNGHEZZA(SOSTITUISCI(cella;"carattere";""))))-1)
  • cella: Il riferimento alla cella o la stringa di testo dalla quale vuoi rimuovere il testo.
  • carattere: Il separatore specifico in base al quale vuoi rimuovere il testo.

Inserisci o copia la seguente formula in una cella vuota:

=SINISTRA(A2;TROVA("#";SOSTITUISCI(A2;" ";"#";LUNGHEZZA(A2)-LUNGHEZZA(SOSTITUISCI(A2;" ";""))))-1)

Quindi, trascina la maniglia di riempimento verso il basso fino alle celle in cui vuoi applicare questa formula, e otterrai il risultato come mostrato nello screenshot qui sotto:

doc-remove-after-first-space-05

Spiegazione della formula:

1. TROVA("#";SOSTITUISCI(A2;" ";"#";LUNGHEZZA(A2)-LUNGHEZZA(SOSTITUISCI(A2;" ";""))))-1:

  • SOSTITUISCI(A2;" ";""): Questa funzione SOSTITUISCI viene utilizzata per sostituire tutti i caratteri spazio con nulla nella cella A2, e otterrai il risultato come questo: “Tom-Grade1HoustonTexasUS”.
  • LUNGHEZZA(SOSTITUISCI(A2;" ";""): Questa funzione LUNGHEZZA restituisce il numero di caratteri della stringa di testo restituita dalla funzione SOSTITUISCI senza spazi. Otterrà il numero 24.
  • LUNGHEZZA(A2)-LUNGHEZZA(SOSTITUISCI(A2;" ";""))=27-24: Sottraendo il numero di caratteri senza spazio dalla lunghezza totale della cella A2 si otterrà il numero degli spazi tra la stringa di testo. Questo darà il numero 3.
  • SOSTITUISCI(A2;" ";"#";LUNGHEZZA(A2)-LUNGHEZZA(SOSTITUISCI(A2;" ";"")))= SOSTITUISCI(A2;" ";"#"; 3): Questa funzione SOSTITUISCI viene utilizzata per sostituire l'ultimo carattere spazio con un carattere # specifico, il risultato è: “Tom-Grade1 Houston Texas#US”.
  • TROVA("#";SOSTITUISCI(A2;" ";"#";LUNGHEZZA(A2)-LUNGHEZZA(SOSTITUISCI(A2;" ";""))))-1=TROVA("#"; "Tom-Grade1 Houston Texas#US ")-1=25-1: Questa funzione TROVA restituirà la posizione del carattere # specifico nella stringa di testo restituita dalla funzione SOSTITUISCI, sottraendo 1 significa escludere il carattere spazio. E questo darà il numero 24.

2. SINISTRA(A2;TROVA("#";SOSTITUISCI(A2;" ";"#";LUNGHEZZA(A2)-LUNGHEZZA(SOSTITUISCI(A2;" ";""))))-1)=SINISTRA(A2; 24): Infine, questa funzione SINISTRA viene utilizzata per estrarre 24 caratteri dal lato sinistro della stringa di testo della cella A2.

Funzioni correlate utilizzate:

  • SINISTRA:
  • La funzione SINISTRA estrae il numero dato di caratteri dal lato sinistro di una stringa fornita.
  • DESTRA:
  • La funzione DESTRA viene utilizzata per estrarre un numero specifico di caratteri dal lato destro della stringa di testo.
  • TROVA:
  • La funzione TROVA viene utilizzata per trovare una stringa all'interno di un'altra stringa e restituisce la posizione iniziale della stringa all'interno di un'altra.
  • RICERCA:
  • La funzione RICERCA può aiutarti a trovare la posizione di un carattere o sottostringa specifica da una stringa di testo data.
  • SOSTITUISCI:
  • La funzione SOSTITUISCI di Excel sostituisce il testo o i caratteri all'interno di una stringa di testo con un altro testo o caratteri.
  • LUNGHEZZA:
  • La funzione LUNGHEZZA restituisce il numero di caratteri in una stringa di testo.

Altri articoli:

I migliori strumenti per la produttività di Office

Kutools per Excel - Ti aiuta a distinguerti dalla massa

🤖 Assistente AI di KUTOOLS: Rivoluziona l'analisi dei dati basata su: Esecuzione Intelligente   |  Genera Codice  |  Crea Formule Personalizzate  |  Analizza Dati e Genera Grafici  |  Invoca Funzioni di Kutools…
Funzionalità popolari: Trova, Evidenzia o Identifica Duplicati  |  Elimina Righe Vuote  |  Combina Colonne o Celle senza Perdere Dati  |  Arrotonda senza Formula ...
Super VLookup: Criteri Multipli  |  Valori Multipli  |  Tra Fogli Multipli  |  Corrispondenza Approssimativa...
Elenco a Discesa Avanzato: Elenco a Discesa Semplice  |  Elenco a Discesa Dipendente  |  Elenco a Discesa con Selezione Multipla...
Gestione Colonne: Aggiungi un Numero Specifico di Colonne  |  Sposta Colonne  |  Attiva/Disattiva Visibilità delle Colonne Nascoste  |  Confronta Colonne per Selezionare Celle Uguali e Diverse ...
Funzionalità Principali: Attenzione della Griglia  |  Visualizzazione di Progettazione  |  Barra delle Formule Avanzata  |  Gestore Cartella di Lavoro e Foglio | Libreria Risorse (AutoTesto)  |  Selettore di Data  |  Unisci Fogli di Lavoro  |  Crittografa/Decrittografa Celle  |  Invia Email da Lista  |  Super Filtri  |  Filtro Speciale (filtra grassetto/corsivo/barrato...) ...
Top 15 Set di Strumenti:  12 Strumenti Testo (Aggiungi Testo, Elimina Caratteri ...)  |  50+ Tipi di Grafico (Diagramma di Gantt ...)  |  40+ Formule Pratiche (Calcola età in base alla data di nascita ...)  |  19 Strumenti Inserimento (Inserisci codice QR, Inserisci Immagine dal Percorso ...)  |  12 Strumenti Conversione (Converti in parole, Conversione valuta ...)  |  7 Strumenti Unisci & Dividi (Unione avanzata righe, Dividi celle Excel ...)  |  ... e altro
Usa Kutools nella tua lingua preferita – supporta Inglese, Spagnolo, Tedesco, Francese, Cinese e oltre 40 altre lingue!

Kutools per Excel vanta oltre 300 funzionalità, garantendo che ciò di cui hai bisogno sia a portata di clic...

Office Tab - Abilita la visualizzazione e la modifica a schede in Microsoft Office (include Excel)

  • Un secondo per passare tra decine di documenti aperti!
  • Riduce centinaia di clic del mouse ogni giorno, dì addio alla mano del mouse.
  • Aumenta la tua produttività del 50% quando visualizzi e modifichi più documenti.
  • Porta le schede efficienti in Office (include Excel), proprio come Chrome, Edge e Firefox.