Dividi le dimensioni in lunghezza, altezza e larghezza individuali
Questo articolo spiega come dividere le dimensioni in una cella in tre parti (dimensioni individuali che includono lunghezza, altezza e larghezza).
Come dividere le dimensioni in tre parti?
Per dividere le dimensioni in lunghezza, altezza e larghezza individuali, è necessario applicare tre diverse formule separatamente.
Formula generica per estrarre la prima dimensione
=LEFT(text,FIND("char",text)-1)
Formula generica per estrarre la seconda dimensione
=MID(text,FIND("char",text)+1,FIND("@",SUBSTITUTE(text,"char","@",2))-(FIND("char",text)+1))
Formula generica per estrarre la terza dimensione
=RIGHT(text,LEN(text)-FIND("@",SUBSTITUTE(text,"char","@",2)))
Argomenti delle formule precedenti
Testo: La stringa da cui estrarre il numero di caratteri specificato. Può essere:
- 1. Il testo racchiuso tra virgolette;
- 2. O un riferimento a una cella contenente il testo.
char: Il personaggio su cui dividerete le dimensioni in base.
Come utilizzare queste formule?
In primo luogo, dobbiamo ottenere la prima dimensione.
1. Selezionare una cella vuota per produrre la prima dimensione.
2. Immettere la formula sottostante e premere il tasto entrare chiave. Selezionare la cella del risultato e trascinare la maniglia di riempimento per applicare la formula ad altre celle di cui hai bisogno.
=LEFT(B5,FIND("x",B5)-1)
Quindi, suddivideremo la seconda dimensione come segue.
1. Selezionare una cella vuota per produrre la seconda dimensione.
2. Immettere la formula sottostante e premere il tasto entrare chiave. Selezionare la cella del risultato e trascinare la maniglia di riempimento per applicare la formula ad altre celle di cui hai bisogno.
=MID(B5,FIND("x",B5)+1,FIND("@",SUBSTITUTE(B5,"x","@",2))-(FIND("x",B5)+1))
Infine, ottieni l'ultima dimensione
1. Selezionare una cella vuota per produrre l'ultima dimensione.
2. Immettere la formula sottostante e premere il tasto entrare chiave. Selezionare la cella del risultato e trascinare la maniglia di riempimento per applicare la formula ad altre celle di cui hai bisogno.
=RIGHT(B5,LEN(B5)-FIND("@",SUBSTITUTE(B5,"x","@",2)))
Come funzionano queste formule?
=LEFT(B5,FIND("x",B5)-1)
1. FIND("x",B5)-1: La funzione TROVA ottiene la posizione della prima "x" in B5. Per ottenere la prima dimensione senza la prima "x", è necessario sottrarre 1. Quindi il risultato è 4-1 = 3.
2. LEFT(B5,3): La funzione LEFT estrae 3 caratteri partendo dal lato sinistro di B5 e restituisce il risultato come 100.
=MID(B5,FIND("x",B5)+1,FIND("@",SUBSTITUTE(B5,"x","@",2))-(FIND("x",B5)+1))
1. FIND("x",B5)+1: La funzione TROVA individua la prima "x" di B5. Poiché è necessario ottenere la seconda dimensione dopo la prima "x", qui è necessario aggiungere 1. Quindi il risultato è 4 + 1 = 5.
2. FIND("@",SUBSTITUTE(B5,"x","@",2)):
- SUBSTITUTE(B5,"x","@",2): La funzione SOSTITUISCI sostituisce la seconda "x" in B5 con "@" e restituisce il risultato come 100x50 @ 300;
- FIND("@",100x50@300): La funzione TROVA qui ottiene la posizione del carattere "@" nel testo 100x50 @ 300 e restituisce il risultato come 7.
3. (FIND("x",B5)+1): Come indicato nel passaggio 1 sopra, qui la funzione TROVA individua la prima "x" di B5 e aggiunge 1 per restituire il risultato come 5.
4. MID(B5,5,7-(5)): La funzione MID estrae due caratteri (7-5 = 2) a partire dal quinto carattere del testo in Si5. E restituisci il risultato finale come 50.
=RIGHT(B5,LEN(B5)-FIND("@",SUBSTITUTE(B5,"x","@",2)))
1. LEN(B5): La funzione LEN calcola la lunghezza totale della stringa in B5 e restituisce il risultato come 10;
2. FIND("@",SUBSTITUTE(B5,"x","@",2)):
- SUBSTITUTE(B5,"x","@",2): La funzione SOSTITUISCI sostituisce la seconda "x" in B5 con "@" e restituisce il risultato come 100x50 @ 300;
- FIND("@",100x50@300): La funzione TROVA qui individua la "@" nel testo 100x50 @ 300 e restituisce il risultato come 7.
3. LEN(B5)-FIND("@",SUBSTITUTE(B5,"x","@",2)): (10-7) La lunghezza totale della stringa di testo nella cella B5 sottrae i primi 7 caratteri e restituisce il risultato come 3.
4. RIGHT(B5,3): E poi la funzione RIGHT estrae 3 caratteri a partire dal lato destro di B5 e restituisce la terza dimensione come 300.
Funzioni correlate
Funzione Excel SINISTRA
La funzione LEFT estrae il numero di caratteri specificato dal lato sinistro di una stringa fornita.
Funzione Excel MID
La funzione MID viene utilizzata per trovare e restituire un numero specifico di caratteri dalla metà di una determinata stringa di testo.
Funzione Excel DESTRA
La funzione RIGHT estrae un numero specifico di caratteri dal lato destro della stringa di testo.
Funzione TROVA di Excel
La funzione TROVA viene utilizzata per trovare una stringa all'interno di un'altra stringa e restituisce la posizione iniziale della stringa all'interno di un'altra.
Funzione Excel LEN
La funzione LEN restituisce il numero di caratteri in una stringa di testo.
Funzione SOSTITUZIONE di Excel
La funzione SOSTITUZIONE di Microsoft Excel sostituisce il testo oi caratteri all'interno di una stringa di testo con un altro testo o caratteri.
Formule correlate
Dividi le dimensioni in due parti in Excel
Questo articolo spiega come utilizzare la formula per dividere le dimensioni in una cella in due parti senza unità (lunghezza e larghezza individuali).
Separare i numeri dalle unità di misura
Questo articolo spiega come utilizzare la formula per separare i numeri dalle unità di misura.
I migliori strumenti per la produttività in ufficio
Kutools per Excel: ti aiuta a distinguerti dalla folla
Kutools per Excel vanta oltre 300 funzionalità, Garantirti che ciò di cui hai bisogno sia a portata di clic...
Scheda Office: abilita la lettura e la modifica a schede in Microsoft Office (incluso Excel)
- Un secondo per passare da una dozzina di documenti aperti all'altra!
- Riduci ogni giorno centinaia di clic del mouse, dì addio alla mano del mouse.
- Aumenta la produttività del 50% durante la visualizzazione e la modifica di più documenti.
- Porta schede efficienti in Office (incluso Excel), proprio come Chrome, Edge e Firefox.
