Note: The other languages of the website are Google-translated. Back to English
English English

Ottetti separati dell'indirizzo IP in Excel

Hai mai provato a dividere gli indirizzi IP in colonne separate nel foglio di lavoro di Excel? Forse la funzione Testo in colonna può aiutarti a risolvere rapidamente questo lavoro, ma, in questo articolo, parlerò di alcune formule per ottenere questa attività in Excel.


Dividi ottetti di indirizzi IP in colonne separate in Excel

Normalmente, in Excel, le funzioni LEFT, MID, LEN e FIND possono aiutarti a estrarre ogni ottetto dall'indirizzo IP in colonne diverse. Si prega di fare con i seguenti passaggi:

Dividi il primo ottetto degli indirizzi IP:

Per estrarre il primo ottetto dell'indirizzo IP, applica la formula seguente in una cella vuota:

=LEFT(A2,FIND(".",A2)-1)

Quindi, trascina il quadratino di riempimento verso il basso sulle celle a cui desideri applicare questa formula e tutti i primi ottetti degli indirizzi IP sono stati estratti, vedi screenshot:

Spiegazione della formula:

TROVA (".", A2) -1: Questa funzione TROVA restituisce la posizione del primo punto dalla cella A2, sottrae 1 significa escludere il punto stesso, otterrai il risultato 2.

LEFT(A2,FIND(".",A2)-1)=LEFT(A2, 2):La funzione LEFT viene utilizzata per estrarre 2 caratteri dal lato sinistro della stringa nella cella A2.


Dividi il secondo ottetto degli indirizzi IP:

Per ottenere il secondo ottetto degli indirizzi IP, copia o inserisci la seguente formula in una cella vuota:

=MID(A2,FIND(".",A2)+1,FIND(".",A2,FIND(".",A2)+1)-FIND(".",A2)-1)

Quindi, trascina il quadratino di riempimento sulle celle per riempire questa formula, e otterrai il risultato di cui hai bisogno, vedi screenshot:

Spiegazione della formula:

1. TROVA (".", A2) +1: Questa funzione TROVA restituisce la posizione del primo punto dalla cella A2, aggiunge 1 significa all'estrazione dal carattere successivo, otterrai il risultato il numero 4. Questa parte della formula è riconosciuta come argomento start_num della funzione MID.

2. FIND(".",A2,FIND(".",A2)+1)-FIND(".",A2)-1: Questa parte è riconosciuta come argomento num_chars all'interno della funzione MID.

  • TROVA (".", A2, TROVA (".", A2) +1) = TROVA (".", A2,4): Questa funzione TROVA restituirà la posizione del secondo punto. E otterrai il numero 6.
  • FIND(".",A2,FIND(".",A2)+1)-FIND(".",A2)-1=6-3-1: Sottrai la posizione del primo punto dalla posizione del secondo punto, quindi sottrai 1 dal risultato significa rimuovere un punto iniziale. E il risultato è 2.

3. MID(A2,FIND(".",A2)+1,FIND(".",A2,FIND(".",A2)+1)-FIND(".",A2)-1)=MID(A2, 4, 2): Infine, questa funzione MID viene utilizzata per estrarre 2 caratteri che iniziano con il quarto carattere dalla cella A2.


Dividi il terzo ottetto degli indirizzi IP:

Per estrarre il terzo ottetto degli indirizzi IP, anche le funzioni MID e FIND possono farti un favore, inserisci o copia la seguente formula in una cella vuota:

=MID(A2,FIND(".",A2,FIND(".",A2)+1)+1,FIND(".",A2,FIND(".",A2,FIND(".",A2)+1)+1)-(FIND(".",A2,FIND(".",A2)+1)+1))

Quindi, trascina il quadratino di riempimento verso il basso per ottenere i risultati di cui hai bisogno e solo il terzo ottetto degli indirizzi IP è stato diviso, vedi screenshot:

Spiegazione della formula:

1. FIND(".",A2,FIND(".",A2)+1)+1: Questa funzione TROVA nidificata viene utilizzata per ottenere la posizione del secondo punto nella cella A2, aggiungendo 1 significa all'estrazione dal carattere successivo e otterrai il numero 7. Questa parte è riconosciuta come argomento start_num della funzione MID.

2. FIND(".",A2,FIND(".",A2,FIND(".",A2)+1)+1)-(FIND(".",A2,FIND(".",A2)+1)+1): Questa parte della formula è riconosciuta come argomento num_chars della funzione MID.

  • FIND(".",A2,FIND(".",A2,FIND(".",A2)+1)+1)=FIND(".",A2, 7): Questa funzione TROVA nidificata viene utilizzata per ottenere la posizione del terzo punto nella cella A2, restituisce il numero 8.
  • FIND(".",A2,FIND(".",A2,FIND(".",A2)+1)+1)-(FIND(".",A2,FIND(".",A2)+1)+1)=8-7: Sottrai la posizione del secondo punto dalla posizione del terzo punto, e il risultato è 1.

3.MID(A2,FIND(".",A2,FIND(".",A2)+1)+1,FIND(".",A2,FIND(".",A2,FIND(".",A2)+1)+1)-(FIND(".",A2,FIND(".",A2)+1)+1))=MID(A2, 7, 1): Questa funzione MID otterrà 1 carattere che inizia con il settimo carattere dalla cella A2.


Dividi il quarto ottetto degli indirizzi IP:

La formula seguente può aiutare a estrarre l'ultimo ottetto dell'indirizzo IP, per favore copia o inserisci la formula in una cella vuota:

=MID(A2,FIND(".",A2,FIND(".",A2,FIND(".",A2)+1)+1)+1,LEN(A2)-FIND(".",A2,FIND(".",A2,FIND(".",A2)+1)+1))

Quindi, trascina il quadratino di riempimento per riempire questa formula in altre celle di cui hai bisogno, otterrai il risultato come mostrato nell'immagine sottostante:

Spiegazione della formula:

1. FIND(".",A2,FIND(".",A2,FIND(".",A2)+1)+1)+1: Questa funzione TROVA nidificata viene utilizzata per ottenere la posizione del terzo punto nella cella A2, aggiungendo 1 significa all'estrazione dal carattere successivo e otterrai il numero 9. Questa parte è riconosciuta come argomento start_num della funzione MID.

2. LEN(A2)-FIND(".",A2,FIND(".",A2,FIND(".",A2)+1)+1):

  • LEN (A2): La funzione LEN restituisce il numero totale di caratteri nella cella A2. Otterrà il numero 11.
  • LEN(A2)-FIND(".",A2,FIND(".",A2,FIND(".",A2)+1)+1)=11-8: La lunghezza totale della cella A2 sottrae la posizione del terzo punto per ottenere il numero del carattere rimanente. Questo otterrà il numero 3.

3. MID(A2,FIND(".",A2,FIND(".",A2,FIND(".",A2)+1)+1)+1,LEN(A2)-FIND(".",A2,FIND(".",A2,FIND(".",A2)+1)+1))=MID(A2, 9, 3): Alla fine, questa funzione MID otterrà 3 caratteri che iniziano con il nono carattere dalla cella A2.


Funzioni relative utilizzate:

  • LEFT:
  • La funzione LEFT estrae il numero di caratteri specificato dal lato sinistro di una stringa fornita.
  • MID:
  • La funzione MID viene utilizzata per trovare e restituire un numero specifico di caratteri dalla metà di una determinata stringa di testo.
  • FIND:
  • La funzione TROVA viene utilizzata per trovare una stringa all'interno di un'altra stringa e restituisce la posizione iniziale della stringa all'interno di un'altra.
  • LEN:
  • La funzione LEN restituisce il numero di caratteri in una stringa di testo.

Altri articoli:

  • Dividi testo e numeri in una cella in Excel
  • Supponendo che i dati di una cella siano mescolati con testo e numeri, come puoi dividerli in celle di colonna separate? Questo tutorial ti mostrerà i passaggi dettagliati per farlo con le formule.

I migliori strumenti per la produttività in ufficio

Kutools per Excel: ti aiuta a distinguerti dalla folla

Vorresti completare il tuo lavoro quotidiano in modo rapido e perfetto? Kutools per Excel offre 300 potenti funzionalità avanzate (Combina cartelle di lavoro, somma per colore, contenuto di celle divise, converti data e così via ...) e risparmia l'80% di tempo per te.

  • Progettato per 1500 scenari di lavoro, ti aiuta a risolvere l'80% dei problemi di Excel.
  • Riduci migliaia di clic della tastiera e del mouse ogni giorno, allevia i tuoi occhi e le tue mani stanche.
  • Diventa un esperto di Excel in 3 minuti. Non è più necessario ricordare formule dolorose e codici VBA.
  • Prova gratuita illimitata di 30 giorni. Garanzia di rimborso di 60 giorni. Aggiornamento gratuito e supporto per 2 anni.
Nastro di Excel (con Kutools per Excel installato)

Scheda Office: abilita la lettura e la modifica a schede in Microsoft Office (incluso Excel)

  • Un secondo per passare da una dozzina di documenti aperti all'altra!
  • Riduci ogni giorno centinaia di clic del mouse, dì addio alla mano del mouse.
  • Aumenta la produttività del 50% durante la visualizzazione e la modifica di più documenti.
  • Porta schede efficienti in Office (incluso Excel), proprio come Chrome, Firefox e il nuovo Internet Explorer.
Screenshot di Excel (con la scheda Office installata)
Commenti (1)
Rinomato 5 su 5 · Valutazioni 1
Questo commento è stato fatto dal moderatore sul sito
Questo ha funzionato magnificamente, grazie per queste informazioni!!
Rinomato 5 su 5
Non ci sono ancora commenti pubblicati qui
Lasciate i vostri commenti
Pubblicazione come ospite
×
Valuta questo post:
0   Personaggi
Posizioni suggerite