Skip to main content

Somma i valori per numero di settimana o giorno della settimana in Excel

Author: Siluvia Last Modified: 2025-08-06

Questa guida illustra passo dopo passo le formule per aiutarti a sommare i valori in un determinato intervallo in base al numero di settimana o al giorno della settimana specificato in Excel.

Come sommare i valori per numero di settimana in Excel?
Come sommare i valori per giorno della settimana in Excel?

Come sommare i valori per numero di settimana in Excel?

Come mostrato nello screenshot sottostante, per sommare i valori nella colonna Importo in base alle date in cui cade un determinato numero di settimana, forniamo due formule.

doc-sum-by-week-number-weekday-1

Formule generiche

=SOMMA.PIÙ.SE(intervallo_valori, intervallo_colonna_aiuto, numero_settimana)

=MATR.SOMMA.PRODOTTO(--(NUM.SETTIMANA(intervallo_date+0,1)=numero_settimana),intervallo_valori)

Argomenti

Intervallo_valori: L'intervallo di valori che desideri sommare in base al numero di settimana;
Intervallo_colonna_aiuto: L'intervallo di numeri di settimana estratti dalla data;
Numero_settimana: Il numero di settimana utilizzato come criterio per la somma dei valori.

Come utilizzare questa formula?

Utilizzando la formula SOMMA.PIÙ.SE e una colonna di supporto

Per utilizzare la formula SOMMA.PIÙ.SE, prima devi applicare la funzione NUM.SETTIMANA per creare una colonna di supporto che calcoli i numeri di settimana corrispondenti per le date nella colonna Data.

=NUM.SETTIMANA(num_seriale, [tipo_ritorno])

La funzione NUM.SETTIMANA restituisce il numero di settimana della data specificata in un anno.

1. In questo caso, seleziono una cella (F5) accanto al primo valore nella colonna Importo.

2. Inserisci la seguente formula al suo interno e premi il tasto Invio per ottenere il numero di settimana della prima data. Seleziona la cella del risultato e trascina il quadratino di riempimento automatico verso il basso per ottenere gli altri numeri di settimana. Vedi screenshot:

=NUM.SETTIMANA(C5)

doc-sum-by-week-number-weekday-2

3. Seleziona una cella per visualizzare l'importo totale, inserisci la seguente formula al suo interno e premi il tasto Invio. Seleziona questa cella del risultato, trascina il quadratino di riempimento automatico verso il basso per ottenere gli altri risultati.

=SOMMA.PIÙ.SE($E$5:$E$14, $F$5:$F$14, H6)

doc-sum-by-week-number-weekday-3

Utilizzando la formula MATR.SOMMA.PRODOTTO

Non è necessario creare una colonna di supporto quando si utilizza la formula MATR.SOMMA.PRODOTTO per risolvere questo problema.

1. Seleziona una cella vuota, inserisci la seguente formula al suo interno e premi il tasto Invio.

=MATR.SOMMA.PRODOTTO(--(NUM.SETTIMANA($C$5:$C$14+0,1)=G6),$E$5:$E$14)

2. Seleziona la cella del risultato, trascina il quadratino di riempimento automatico verso il basso per ottenere gli altri risultati secondo necessità.

doc-sum-by-week-number-weekday-4

Spiegazione della formula

=SOMMA.PIÙ.SE($E$5:$E$14, $F$5:$F$14, H6)

Dopo aver calcolato i numeri di settimana con la funzione NUM.SETTIMANA, la funzione SOMMA.PIÙ.SE somma i valori nell'intervallo E5:E14 se i numeri di settimana nella colonna di supporto F5:F14 corrispondono alla settimana specificata in H6.

=MATR.SOMMA.PRODOTTO(--(NUM.SETTIMANA($C$5:$C$14+0,1)=G6),$E$5:$E$14)

NUM.SETTIMANA($C$5:$C$14+0,1): La funzione NUM.SETTIMANA calcola ogni numero di settimana delle date nell'intervallo C5:C14 e restituisce un array simile a questo: {1;1;5;6;6;9;11;11;13;14};
{1;1;5;6;6;9;11;11;13;14}=G6: Qui si confronta ogni numero di settimana nell'array con il numero di settimana specificato in G6 e si restituisce un nuovo array: {VERO;VERO;FALSO;FALSO;FALSO;FALSO;FALSO;FALSO;FALSO;FALSO};
--{VERO;VERO;FALSO;FALSO;FALSO;FALSO;FALSO;FALSO;FALSO;FALSO}: Questi due segni meno convertono “VERO” e “FALSO” in 1 e 0. Qui otterrai un nuovo array come {1;1;0;0;0;0;0;0;0;0};
{1;1;0;0;0;0;0;0;0;0},{1428;2010;2288;1831;2069;1728;1325;1469;1023;1100}: Ogni coppia di voci negli array viene moltiplicata insieme e restituisce {1428;2010;0;0;0;0;0;0;0;0};
MATR.SOMMA.PRODOTTO({1428;2010;0;0;0;0;0;0;0;0}): La funzione MATR.SOMMA.PRODOTTO somma tutti i numeri nell'array e restituisce il risultato finale 1428+2010=3438.

Come sommare i valori per giorno della settimana in Excel?

Come mostrato nello screenshot sottostante, per sommare i valori nella colonna Importo in base a un certo giorno della settimana in Excel, puoi applicare la funzione MATR.SOMMA.PRODOTTO insieme alla funzione GIORNO.SETTIMANA per farlo.

In questo caso, poiché dobbiamo sommare l'importo totale per ciascun giorno della settimana, prima di applicare la formula, creiamo una colonna di supporto con numeri da 1 a 7 per indicare separatamente lunedì a domenica.

doc-sum-by-week-number-weekday-6

Formula generica

=MATR.SOMMA.PRODOTTO((GIORNO.SETTIMANA(intervallo_date,2)=numero_giorno_settimana)*intervallo_valori)

Argomenti

Intervallo_date: L'intervallo di date in cui desideri valutare i giorni della settimana specificati;
Intervallo_valori: L'intervallo di valori che desideri sommare in base al giorno della settimana;
2: Il numero 2 rappresenta i numeri da 1 (lunedì) a 7 (domenica);
Numero_giorno_settimana: Il numero del giorno della settimana utilizzato come criterio per la somma dei valori. Può essere un riferimento di cella o un numero da 1 a 7.

Come utilizzare questa formula?

1. Seleziona una cella accanto alla cella con il numero 1. Qui seleziono I6.

2. Copia o inserisci la seguente formula al suo interno e premi il tasto Invio. Seleziona la cella del risultato e trascina il quadratino di riempimento automatico verso il basso per ottenere i risultati per gli altri giorni della settimana.

=MATR.SOMMA.PRODOTTO((GIORNO.SETTIMANA($C$5:$C$14,2)=H6)*$E$5:$E$14)

doc-sum-by-week-number-weekday-7

Nota: Se hai bisogno solo di sommare i valori in base a un determinato giorno della settimana, ad esempio venerdì, puoi inserire direttamente il numero 5 nella formula come segue.

=MATR.SOMMA.PRODOTTO((GIORNO.SETTIMANA($C$5:$C$14,2)=5)*$E$5:$E$14)

Spiegazione della formula

=MATR.SOMMA.PRODOTTO((GIORNO.SETTIMANA($C$5:$C$14,2)=H6)*$E$5:$E$14)

GIORNO.SETTIMANA($C$5:$C$14,2): La funzione GIORNO.SETTIMANA restituisce numeri interi da 1 a 7 per rappresentare il giorno della settimana da lunedì a domenica nell'intervallo C5:C14: {5;7;1;3;6;7;1;5;5;6};
{5;7;1;3;6;7;1;5;5;6}=H6: Qui si confronta ogni giorno della settimana nell'array con il numero del giorno della settimana specificato in H6 e si restituisce un nuovo array: {FALSO;FALSO;VERO;FALSO;FALSO;FALSO;VERO;FALSO;FALSO;FALSO};
{FALSO;FALSO;VERO;FALSO;FALSO;FALSO;VERO;FALSO;FALSO;FALSO}*$E$5:$E$14: Qui i VERO e FALSO vengono convertiti in 1 e 0, e poi moltiplicati con i valori in E5:E14 per restituire l'array: {0;0;2288;0;0;0;1325;0;0;0};
MATR.SOMMA.PRODOTTO{0;0;2288;0;0;0;1325;0;0;0}: La funzione MATR.SOMMA.PRODOTTO somma tutti i numeri nell'array e restituisce il risultato finale 2288+1325=3613.

Funzioni correlate

Funzione NUM.SETTIMANA di Excel
La funzione SOMMA.PIÙ.SE di Excel restituisce il numero di settimana della data specificata in un anno, che inizia a contare le settimane dal 1° gennaio.

Funzione MATR.SOMMA.PRODOTTO di Excel
La funzione MATR.SOMMA.PRODOTTO di Excel può essere utilizzata per moltiplicare due o più colonne o array insieme e quindi ottenere la somma dei prodotti.

Funzione GIORNO.SETTIMANA di Excel
La funzione FINE.MESE di Excel restituisce un numero intero compreso tra 1 e 7 per rappresentare il giorno della settimana per una data specificata in Excel.

Formule correlate

Somma i valori per mese (con o senza anno)
Questa guida illustra dettagliatamente due formule per aiutare a sommare i valori per un determinato mese e anno o sommare i valori per un determinato mese ignorando l'anno in Excel.

Somma i valori per la settimana di una data specificata
Questa guida parla di come sommare i valori per la settimana in cui cade una data specificata.

Somma ogni n righe o colonne in un intervallo
Questa guida spiega due formule basate sulle funzioni SOMMA e SCARTO per sommare ogni n righe o colonne in un intervallo specificato in Excel.

Somma ogni ennesima riga o colonna in un intervallo
Questa guida ti mostrerà come creare una formula basata sulle funzioni MATR.SOMMA.PRODOTTO, RESTO e COLONNA per sommare ogni ennesima riga o colonna in un intervallo in Excel.

I migliori strumenti per la produttività di Office

Kutools per Excel - Ti aiuta a distinguerti dalla massa

🤖 Assistente AI di KUTOOLS: Rivoluziona l'analisi dei dati basata su: Esecuzione Intelligente   |  Genera Codice  |  Crea Formule Personalizzate  |  Analizza Dati e Genera Grafici  |  Invoca Funzioni di Kutools…
Funzionalità popolari: Trova, Evidenzia o Identifica Duplicati  |  Elimina Righe Vuote  |  Combina Colonne o Celle senza Perdere Dati  |  Arrotonda senza Formula ...
Super VLookup: Criteri Multipli  |  Valori Multipli  |  Tra Fogli Multipli  |  Corrispondenza Approssimativa...
Elenco a Discesa Avanzato: Elenco a Discesa Semplice  |  Elenco a Discesa Dipendente  |  Elenco a Discesa con Selezione Multipla...
Gestione Colonne: Aggiungi un Numero Specifico di Colonne  |  Sposta Colonne  |  Attiva/Disattiva Visibilità delle Colonne Nascoste  |  Confronta Colonne per Selezionare Celle Uguali e Diverse ...
Funzionalità Principali: Attenzione della Griglia  |  Visualizzazione di Progettazione  |  Barra delle Formule Avanzata  |  Gestore Cartella di Lavoro e Foglio | Libreria Risorse (AutoTesto)  |  Selettore di Data  |  Unisci Fogli di Lavoro  |  Crittografa/Decrittografa Celle  |  Invia Email da Lista  |  Super Filtri  |  Filtro Speciale (filtra grassetto/corsivo/barrato...) ...
Top 15 Set di Strumenti:  12 Strumenti Testo (Aggiungi Testo, Elimina Caratteri ...)  |  50+ Tipi di Grafico (Diagramma di Gantt ...)  |  40+ Formule Pratiche (Calcola età in base alla data di nascita ...)  |  19 Strumenti Inserimento (Inserisci codice QR, Inserisci Immagine dal Percorso ...)  |  12 Strumenti Conversione (Converti in parole, Conversione valuta ...)  |  7 Strumenti Unisci & Dividi (Unione avanzata righe, Dividi celle Excel ...)  |  ... e altro
Usa Kutools nella tua lingua preferita – supporta Inglese, Spagnolo, Tedesco, Francese, Cinese e oltre 40 altre lingue!

Kutools per Excel vanta oltre 300 funzionalità, garantendo che ciò di cui hai bisogno sia a portata di clic...

Office Tab - Abilita la visualizzazione e la modifica a schede in Microsoft Office (include Excel)

  • Un secondo per passare tra decine di documenti aperti!
  • Riduce centinaia di clic del mouse ogni giorno, dì addio alla mano del mouse.
  • Aumenta la tua produttività del 50% quando visualizzi e modifichi più documenti.
  • Porta le schede efficienti in Office (include Excel), proprio come Chrome, Edge e Firefox.