Estrai il nome del file da un percorso in Excel
Questo tutorial spiega come applicare le formule per estrarre il nome del file con o senza estensione da un percorso di file in una cella specifica in Excel.
Estrai il nome del file con estensione da un percorso
Estrai il nome del file senza estensione da un percorso
Estrai il nome del file con estensione da un percorso
Come mostrato nell'immagine sottostante, c'è un elenco contenente diversi percorsi di file e da essi si desidera estrarre solo i nomi di file con estensioni, la seguente formula ti aiuterà a risolvere il problema.
Formula generica
=MID(A1,FIND("*",SUBSTITUTE(A1,"\","*",LEN(A1)-LEN(SUBSTITUTE(A1,"\",""))))+1,LEN(A1))
argomenti
A1: Rappresenta la cella contenente il percorso del file da cui estrarrai il nome del file.
Come utilizzare questa formula?
1. Selezionare una cella vuota per visualizzare il nome del file. In questo caso seleziono la cella D3.
2. Immettere la formula sottostante e premere il tasto entrare chiave. Seleziona la cella del risultato, quindi trascina la sua maniglia di riempimento fino in fondo per applicarla ad altre celle.
=MID(B3,FIND("*",SUBSTITUTE(B3,"\","*",LEN(B3)-LEN(SUBSTITUTE(B3,"\",""))))+1,LEN(B3))
Ora tutti i nomi di file con estensioni in percorsi di file specifici vengono estratti come mostrato nell'immagine sopra.
Note:
- In questa formula, B3 è la cella contenente il percorso del file. Si prega di cambiarlo quando necessario.
- Se il nome del file non supera i 99 caratteri, è possibile utilizzare anche la formula più breve di seguito per risolvere il problema. Vedi lo screenshot qui sotto mostrato.
=TRIM(RIGHT(SUBSTITUTE(A2,"\",REPT(" ",100)),99))
Come funziona questa formula?
=MID(B3,FIND("*",SUBSTITUTE(B3,"\","*",LEN(B3)-LEN(SUBSTITUTE(B3,"\",""))))+1,LEN(B3))
1. FIND("*",SUBSTITUTE(B3,"\","*",LEN(B3)-LEN(SUBSTITUTE(B3,"\",""))))
- LEN(B3): La funzione LEN calcola la lunghezza totale in "D: \\ files \ work \ Q1 \ Jan \ text.txt" e restituisce il risultato come 30;
- LEN(SUBSTITUTE(B3,"\","")): La funzione SOSTITUISCI sostituisce il carattere "\" con niente. Il risultato è "D: filesworkQ1Jantext.txt". Quindi la funzione LEN calcola la lunghezza totale di "D: filesworkQ1Jantext.txt" e ottiene il risultato 24;
- SUBSTITUTE(B3,"\","*",30-24): La funzione SOSTITUISCI sostituisce il terzo carattere (30-24 = 6) "\" in "D: \\ files \ work \ Q1 \ Jan \ text.txt" con un singolo carattere "*". Qui il risultato è "D: \\ files \ work \ Q1 \ Jan * text.txt";
- FIND("*","D:\\files\work\Q1\Jan*text.txt"): La funzione TROVA individua la posizione del carattere "*" in "D: \\ files \ work \ Q1 \ Jan * text.txt" e infine restituisce 22. Qui significa che il carattere "*" è nella 22a posizione in " D: \\ files \ work \ Q1 \ Jan * text.txt ".
2. =MID(B3,22+1,LEN(B3))
- Come mostrato nella spiegazione sopra, LEN (B3) restituisce il risultato come 30, qui la funzione MID può essere mostrata come = MID ("D: \\ files \ work \ Q1 \ Jan \ text.txt", 23,30). Significa che la funzione MID estrae 30 caratteri dalla stringa "D: \\ files \ work \ Q1 \ Jan \ text.txt", a partire dal 23 ° carattere. Qui il risultato è text.txt.
Estrai il nome del file senza estensione da un percorso
Un'altra circostanza, potrebbe essere necessario estrarre il nome del file senza estensione da un percorso come mostrato nell'immagine sottostante. Questa sezione fornirà una lunga formula per aiutarti a rimuoverla.
Formula generica
=IFERROR(MID(A1,FIND(CHAR(1),SUBSTITUTE(A1,"\",CHAR(1),LEN(A1)-LEN(SUBSTITUTE(A1,"\",""))))+1,FIND(CHAR(1),SUBSTITUTE(A1,".",CHAR(1),LEN(A1)-LEN(SUBSTITUTE(A1,".",""))))-FIND(CHAR(1),SUBSTITUTE(A1,"\",CHAR(1),LEN(A1)-LEN(SUBSTITUTE(A1,"\",""))))-1),"")
argomenti
A1: Rappresenta la cella contenente il percorso del file da cui estrarrai il nome del file.
CHAR (1): Il CHAR (1) qui può essere sostituito con qualsiasi numero CHAR di cui hai bisogno. Oppure può essere sostituito con un simbolo specifico racchiuso tra virgolette come "*".
Come utilizzare questa formula?
1. Selezionare una cella vuota per visualizzare il nome del file senza l'estensione.
2. Immettere la formula sottostante e premere il tasto entrare chiave. Seleziona la cella del risultato, quindi trascina la sua maniglia di riempimento fino in fondo per applicarla ad altre celle.
=IFERROR(MID(B4,FIND(CHAR(1),SUBSTITUTE(B4,"\",CHAR(1),LEN(B4)-LEN(SUBSTITUTE(B4,"\",""))))+1,FIND(CHAR(1),SUBSTITUTE(B4,".",CHAR(1),LEN(B4)-LEN(SUBSTITUTE(B4,".",""))))-FIND(CHAR(1),SUBSTITUTE(B4,"\",CHAR(1),LEN(B4)-LEN(SUBSTITUTE(B4,"\",""))))-1),"")
Note:: In questa formula, B3 è la cella contenente il percorso del file. Si prega di cambiarlo quando necessario.
Funzioni correlate
Funzione Excel MID
La funzione Excel MID viene utilizzata per trovare e restituire un numero specifico di caratteri dalla metà di una determinata stringa di testo.
Funzione TROVA di Excel
La funzione TROVA di Excel viene utilizzata per trovare una stringa all'interno di un'altra stringa e restituisce la posizione iniziale della stringa all'interno di un'altra.
Funzione SOSTITUZIONE di Excel
La funzione SOSTITUZIONE di Excel sostituisce il testo oi caratteri all'interno di una stringa di testo con un altro testo o caratteri.
Funzione Excel LEN
La funzione LEN di Excel restituisce il numero di caratteri in una stringa di testo.
Funzione Excel SE.ERRORE
La funzione SE.ERRORE viene utilizzata per restituire un risultato personalizzato quando una formula valuta un errore e restituisce un risultato normale quando non si verifica alcun errore.
Formule correlate
Estrai più linee da una cella
Se si dispone di un elenco di stringhe di testo separate da interruzioni di riga (che si verifica premendo Alt + Invio durante l'immissione del testo) e si desidera estrarre queste righe di testo in più celle, la formula in questo tutorial ti farà un favore.
Estrai l'ultima riga di testo da una cella multilinea
Per estrarre l'ultima riga di testo da una stringa di testo separata da interruzioni di riga, una formula in questo tutorial può aiutarti a gestire questa attività in Excel.
Estrai l'ennesima parola dalla stringa di testo in Excel
Questo articolo spiega come utilizzare una formula per estrarre l'ennesima parola specifica da una stringa di testo in una cella in Excel.
Estrai le ultime due parole da una cella in Excel
Questo tutorial spiega come utilizzare la formula per estrarre le ultime due parole da una cella in Excel.
Estrai la parola che inizia con un carattere specifico in Excel
Questo tutorial fornisce una formula con passaggi dettagliati per aiutarti a estrarre la parola che inizia con un carattere specifico da una stringa di testo in una cella in Excel.
Estrai tutte le parole tranne la prima o l'ultima
In questo tutorial imparerai come utilizzare le formule per estrarre tutte le parole da una cella tranne la prima o l'ultima in Excel.
I migliori strumenti per la produttività in ufficio
Kutools per Excel: ti aiuta a distinguerti dalla folla
Kutools per Excel vanta oltre 300 funzionalità, Garantirti che ciò di cui hai bisogno sia a portata di clic...
Scheda Office: abilita la lettura e la modifica a schede in Microsoft Office (incluso Excel)
- Un secondo per passare da una dozzina di documenti aperti all'altra!
- Riduci ogni giorno centinaia di clic del mouse, dì addio alla mano del mouse.
- Aumenta la produttività del 50% durante la visualizzazione e la modifica di più documenti.
- Porta schede efficienti in Office (incluso Excel), proprio come Chrome, Edge e Firefox.