Come cercare e sostituire l'oggetto degli appuntamenti nel calendario di Outlook?

La funzione Trova e sostituisci per gli oggetti degli appuntamenti nel calendario di Outlook è ideale quando devi aggiornare in blocco il testo dell’oggetto di più appuntamenti con lo stesso contenuto. È particolarmente utile, ad esempio, per sostituire la parola «Copia» nel campo Oggetto dopo aver importato dati in Outlook. Questo articolo include un codice VBA che ti permette di cercare e sostituire automaticamente il testo negli oggetti di più appuntamenti. Scopri i dettagli qui di seguito.

Cerca e sostituisci l'oggetto degli appuntamenti con codice VBA

---

Cerca e sostituisci l'oggetto degli appuntamenti con codice VBA

In questa sezione puoi cercare e sostituire l'oggetto degli appuntamenti utilizzando il seguente codice VBA.

1. Innanzitutto, imposta il livello di sicurezza delle macro su «Basso» in Outlook.

1) In Outlook 2010 e 2013, fai clic su «File» > «Opzioni». Nella finestra di dialogo «Opzioni di Outlook», seleziona «Centro protezione» nel riquadro sinistro, quindi fai clic sul pulsante «Impostazioni Centro protezione».

Nella finestra di dialogo «Centro protezione», fai clic su «Impostazioni macro» nel riquadro sinistro, seleziona l’opzione «Abilita tutte le macro» nella sezione «Impostazioni macro» e infine conferma con il pulsante «OK». Vedi screenshot:

2) In Outlook 2007, fai clic su «Strumenti» > «Centro protezione». Nella finestra di dialogo «Centro protezione», seleziona «Impostazioni macro» nel riquadro sinistro, scegli l’opzione «Nessun controllo di sicurezza per le macro» e conferma con «OK».

2. Premi i tasti «Alt» + «F11» per aprire la finestra di Microsoft Visual Basic, Applications.

3. Nella finestra «Microsoft Visual Basic, Applications», fai doppio clic per espandere «Progetto1» > «Oggetti Microsoft Outlook» > «ThisOutlookSession» e aprire l’editor VBA. Vedi screenshot:

4. Copia e incolla il seguente codice VBA nell'editor VBA, quindi premi «F5» per eseguirlo.

VBA: Trova e sostituisci oggetto appuntamento

Sub FindReplaceAppointment()
    Dim oApp As Outlook.Application
    Dim oCalFolder As Outlook.MAPIFolder
    Dim oAppt As Outlook.AppointmentItem
    Dim sOldText As String
    Dim sNewText As String
    Dim iCalChangedCount As Integer
    Set oApp = Outlook.Application
    MsgBox ("This script will perform a find/replace in the subject line of all appointments in a specified calendar.")
    sOldText = InputBox("What is the text string that you would like to replace?")
    sNewText = InputBox("With what would you like to replace it?")
    ' Check to be sure a Calendar folder was selected
    Do
    If Not (oCalFolder Is Nothing) Then
        If (oCalFolder.DefaultItemType = olAppointmentItem) Then Exit Do
    End If
    MsgBox ("Please select a calendar folder from the following list.")
    Set oCalFolder = Application.Session.PickFolder
    On Error GoTo ErrHandler:
    Loop Until oCalFolder.DefaultItemType = olAppointmentItem
    ' Loop through appointments in calendar, change text where necessary, keep count
    iCalChangedCount = 0
    For Each oAppt In oCalFolder.Items
        If InStr(oAppt.Subject, sOldText) <> 0 Then
            Debug.Print "Changed: " & oAppt.Subject & " - " & oAppt.Start
            oAppt.Subject = Replace(oAppt.Subject, sOldText, sNewText)
            oAppt.Save
            iCalChangedCount = iCalChangedCount + 1
        End If
    Next
    ' Display results and clear table
    MsgBox (iCalChangedCount & " appointments had text in their subjects changed from '" & sOldText & "' to '" & sNewText & "'.")
    Set oAppt = Nothing
    Set oCalFolder = Nothing
Exit Sub
ErrHandler:
    MsgBox ("Macro terminated.")
End Sub

5. Dopo aver eseguito il codice, viene visualizzata la finestra di dialogo «Microsoft Outlook»: fai clic su «OK».

6. Nella seconda finestra di dialogo «Microsoft Outlook», inserisci il testo che vuoi sostituire e fai clic su «OK».

7. Nella terza finestra di dialogo «Microsoft Outlook», inserisci il testo da utilizzare come sostituto e fai clic su «OK».

Nota: se vuoi semplicemente eliminare tutte le occorrenze della parola «Copia» dall'oggetto degli eventi nel calendario specificato, lascia questa casella vuota.

8. Fai clic sul pulsante «OK» nella finestra di dialogo visualizzata.

9. Nella finestra di dialogo «Seleziona cartella», scegli il tuo calendario sotto l’account di posta indicato, quindi fai clic su «OK». Vedi screenshot:

10. Verrà quindi visualizzata una finestra di dialogo che ti conferma il completamento corretto della sostituzione. Fai clic su «OK».

11. A questo punto, tutti i testi negli oggetti del calendario selezionato sono stati sostituiti con il nuovo contenuto.