Come esportare e stampare l’elenco di tutte le cartelle e sottocartelle in Outlook?

In genere, puoi premere i tasti **Ctrl + 6** per visualizzare l’elenco di tutte le cartelle nel riquadro di navigazione di Outlook. Tuttavia, non è possibile stampare direttamente tale elenco. Questo articolo ti propone due script VBA per esportare e stampare l’elenco completo delle cartelle e delle relative sottocartelle in Outlook.

• Esporta e stampa l'elenco di tutte le cartelle di Outlook e delle relative sottocartelle in Nuova Email
• Esporta e stampa l'elenco di tutte le cartelle di Outlook e delle relative sottocartelle in Blocco note

---

Esporta e stampa l'elenco di tutte le cartelle di Outlook e delle relative sottocartelle in Nuova Email

Questo metodo presenta uno script VBA che esporta l’elenco di tutte le cartelle e delle relative sottocartelle di un account email specifico direttamente in un nuovo messaggio di posta in Outlook, consentendo di stampare facilmente l’elenco delle cartelle.

1. Premere «Alt» + "F11" per aprire la finestra di Microsoft Visual Basic, Applications Edition.

2. Fare clic su «Inserisci» > «Modulo» e incollare il seguente codice VBA nella nuova finestra del modulo.

VBA: Esporta l'elenco delle cartelle e sottocartelle in un Nuova Email in Outlook

Public gFolders As String

Public Sub GetFolderNames()
Dim oSession As Outlook.NameSpace
Dim oFolder As Outlook.MAPIFolder
Dim oNewMail As Outlook.MailItem

Set oSession = Outlook.Application.GetNamespace("MAPI")
Set oFolder = oSession.PickFolder

If (oFolder Is Nothing) Then Exit Sub

ProcessFolder oFolder

Set oNewMail = Application.CreateItem(olMailItem)
oNewMail.Body = gFolders
oNewMail.Display

gFolders = ""
End Sub

Sub ProcessFolder(CurrentFolder As Outlook.MAPIFolder)
Dim i As Long
Dim oSubFolder As Outlook.MAPIFolder
Dim oFolder As Outlook.MAPIFolder
Dim sFolderPaths As String

For i = CurrentFolder.Folders.Count To 1 Step -1
    Set oFolder = CurrentFolder.Folders(i)
    sFolderPaths = oFolder.FolderPath
    gFolders = gFolders & vbCrLf & sFolderPaths & " " & oFolder.Items.Count
Next

For Each oSubFolder In CurrentFolder.Folders
    If oSubFolder.Name <> "Deleted Items" Then
        ProcessFolder oSubFolder
    End If
Next
End Sub

3. Premere "F5" per eseguire il codice VBA.

4. Nella finestra di dialogo «Seleziona cartella» che si apre, scegli l'account email il cui elenco di cartelle desideri stampare, quindi fai clic su «OK».

5. L'elenco delle cartelle dell'account selezionato verrà copiato in un nuovo messaggio di posta, come illustrato di seguito. Per stampare l'elenco delle cartelle, fai clic su «File» > «Stampa».

6. Dopo aver stampato, chiudere la finestra Nuova Email senza salvare.

---

Esporta e stampa l'elenco di tutte le cartelle di Outlook e delle relative sottocartelle in Blocco note

Questo metodo presenta uno script VBA per esportare in Blocco note l’elenco completo delle cartelle e relative sottocartelle di un account email specifico da Outlook, consentendoti di stamparlo facilmente.

1. Premere «Alt» + "F11" per aprire la finestra di Microsoft Visual Basic, Applications Edition.

2. Fare clic su «Inserisci» > «Modulo», quindi incollare il seguente codice VBA nella nuova finestra del modulo.

VBA: Esporta l'elenco di tutte le cartelle e sottocartelle di Outlook da Outlook a Blocco note

Dim gFileName, gCreateTree, gBase

Public Sub ExportFolderTree()
Dim objOutlook
Dim F, Folders
Dim Result

Set objOutlook = CreateObject("Outlook.Application")
Set F = objOutlook.Session.PickFolder

If Not F Is Nothing Then
    Set Folders = F.Folders
    Result = MsgBox("Do you want to create tree?", vbYesNo + vbDefaultButton2 + vbApplicationModal, "Output Folder Tree")
    If Result = 6 Then
        gCreateTree = True
    Else
        gCreateTree = False
    End If

    gFileName = GetDesktopFolder() & "\Outlook-Folders.txt"
    gBase = Len(F.FolderPath) - Len(Replace(F.FolderPath, "\", "")) + 1

    WriteToATextFile (CreateFolderTree(F.FolderPath, F.Name))
    LoopFolders Folders

    Set F = Nothing
    Set Folders = Nothing
    Set objOutlook = Nothing
End If
End Sub

Private Function GetDesktopFolder()
Dim objShell
Set objShell = CreateObject("WScript.Shell")
GetDesktopFolder = objShell.SpecialFolders("Desktop")
Set objShell = Nothing
End Function

Private Sub LoopFolders(Folders)
Dim F
For Each F In Folders
    WriteToATextFile (CreateFolderTree(F.FolderPath, F.Name))
    LoopFolders F.Folders
Next
End Sub

Private Sub WriteToATextFile(OLKfoldername)
Dim objFSO, objTextFile
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objTextFile = objFSO.OpenTextFile(gFileName, 8, True)
objTextFile.WriteLine (OLKfoldername)
objTextFile.Close
Set objFSO = Nothing
Set objTextFile = Nothing
End Sub

Private Function CreateFolderTree(OLKfolderpath, OLKfoldername)
If gCreateTree = False Then
    CreateFolderTree = Mid(OLKfolderpath, 3)
Else
    Dim i, x, OLKprefix
    i = Len(OLKfolderpath) - Len(Replace(OLKfolderpath, "\", ""))
    For x = gBase To i
        OLKprefix = OLKprefix & "-"
    Next
    CreateFolderTree = OLKprefix & OLKfoldername
End If
End Function

3. Premere "F5" per eseguire il codice VBA. Nella finestra di dialogo «Seleziona cartella» che si apre, scegliere l’account email il cui elenco di cartelle si desidera esportare e stampare, quindi fare clic su «OK».

4. Verrà visualizzata la finestra di dialogo «Struttura ad albero delle cartelle di output». Fare clic su «Sì» o «No» a seconda che si desideri includere la struttura ad albero con rientro.

Ora, un File di Testo denominato «Outlook-Folders» viene creato e salvato sul desktop, come mostrato di seguito:

5. Fare doppio clic per aprire il nuovo file di testo, quindi selezionare «File» > «Stampa» per stampare l'elenco esportato delle cartelle di Outlook.

Articoli correlati

Mostra o nascondi la visualizzazione dell'elenco cartelle in Outlook