Come nascondere il numero di fax nell’elenco “Seleziona nomi” in Outlook?

In Outlook potresti aver notato che, nell’elenco «Seleziona nomi» o nella Rubrica, la colonna Indirizzo email include non solo gli indirizzi email, ma anche i numeri di fax, il che può risultare fastidioso. In questo articolo ti mostriamo alcuni metodi efficaci per nascondere i numeri di fax.

Nascondi il numero di fax in Seleziona Elenco nomi con VBA

---

Nascondi il numero di fax in Seleziona Elenco nomi con VBA

Se desideri nascondere i numeri di fax già esistenti in Seleziona Elenco nomi, procedi come segue:

1. Premi i tasti Alt + F11 per aprire la finestra di Microsoft Visual Basic for Applications.

2. Fai clic su Inserisci > Modulo per inserire un nuovo modulo vuoto, quindi copia e incolla il codice seguente nello script.

VBA: Nascondi i numeri di fax esistenti in Seleziona nomi

Sub HideFaxNumbers_ExistingContacts()
'UpdatebyExtendoffice2018-5-23
Dim xStores As Outlook.Stores
Dim xStore As Outlook.Store
Dim xRootFolder As Outlook.Folder
Dim xFolder As Folder
On Error Resume Next
Set xStores = Outlook.Application.Session.Stores
For Each xStore In xStores
    Set xRootFolder = xStore.GetRootFolder
    For Each xFolder In xRootFolder.Folders
        Call ProcessFolders(xFolder)
    Next
Next
End Sub
Sub ProcessFolders(ByVal CurrentFolder As Outlook.Folder)
Dim xContactItem As Outlook.ContactItem
Dim xSubFolder As Outlook.Folder
Dim xFax As String
Dim I As Integer
On Error Resume Next
If CurrentFolder.DefaultItemType <> olContactItem Then Exit Sub
xFax = "Fax: "
For I = CurrentFolder.Items.Count To 1 Step -1
    Set xContactItem = CurrentFolder.Items.Item(I)
    With xContactItem
        If (Len(.BusinessFaxNumber) <> 0) And InStrRev(.BusinessFaxNumber, Trim(xFax)) = 0 Then
            .BusinessFaxNumber = xFax & .BusinessFaxNumber
        End If
        If (Len(.HomeFaxNumber) <> 0) And InStrRev(.HomeFaxNumber, Trim(xFax)) = 0 Then
            .HomeFaxNumber = xFax & .HomeFaxNumber
        End If
        If (Len(.OtherFaxNumber) <> 0) And InStrRev(.OtherFaxNumber, Trim(xFax)) = 0 Then
            .OtherFaxNumber = xFax & .OtherFaxNumber
        End If
        .Save
    End With
Next I
If CurrentFolder.Folders.Count <> 0 Then
    For I = CurrentFolder.Folders.Count To 1 Step -1
        Set xSubFolder = CurrentFolder.Folders.Item(I)
        Call ProcessFolders(xSubFolder)
    Next I
End If
End Sub

3. Premi il tasto F5 per eseguire il codice: da questo momento, i numeri di fax saranno nascosti.

Se invece desideri nascondere il numero di fax in Contatto, procedi come segue:

1. Premi Alt + F11 per aprire la finestra di Microsoft Visual Basic for Applications.

2. Fai doppio clic su ThisOutlookSession nel riquadro Progetto - 1, quindi copia e incolla il codice seguente nello script.

VBA: Nascondi il numero di fax nei nuovi Aggiungi contatto

Public WithEvents xInspectors As Outlook.Inspectors
Public WithEvents xContactItem As Outlook.ContactItem
Private Sub Application_Startup()
'UpdatebyExtendoffice2018-5-23
    Set xInspectors = Outlook.Application.Inspectors
End Sub
Private Sub xInspectors_NewInspector(ByVal Inspector As Inspector)
If TypeName(Inspector.CurrentItem) = "ContactItem" Then
    Set xContactItem = Inspector.CurrentItem
End If
End Sub
Private Sub xContactItem_PropertyChange(ByVal Name As String)
Dim xArr() As Variant
Dim xFax As String
On Error Resume Next
xArr = Array("BusinessFaxNumber", "HomeFaxNumber", "OtherFaxNumber")
xFax = "Fax: "
With xContactItem
    Select Case Name
        Case xArr(0)
            If InStrRev(.BusinessFaxNumber, Trim(xFax)) = 0 Then
                .BusinessFaxNumber = xFax & .BusinessFaxNumber
            End If
        Case xArr(1)
            If InStrRev(.HomeFaxNumber, Trim(xFax)) = 0 Then
                .HomeFaxNumber = xFax & .HomeFaxNumber
            End If
        Case xArr(2)
            If InStrRev(.OtherFaxNumber, Trim(xFax)) = 0 Then
                .OtherFaxNumber = xFax & .OtherFaxNumber
            End If
    End Select
End With
End Sub

3. Salva il codice e riavvia Outlook per attivare gli effetti.

D’ora in poi, tutti i numeri di fax dei nuovi contatti creati saranno nascosti nella finestra **Seleziona nomi: Contatti**.