Come impostare firme diverse per risposte e inoltri in Outlook?

Normalmente puoi impostare firme diverse per i vari account in Outlook, ma hai mai provato a utilizzare firme distinte per le risposte e per gli inoltri? In altre parole, quando rispondi a un messaggio viene inserita la firma1, mentre quando inoltri un messaggio viene applicata la firma2. Come puoi soddisfare questa esigenza in Outlook?

Imposta firme diverse per risposte e inoltri con codice VBA

---

Imposta firme diverse per risposte e inoltri con codice VBA

Il seguente codice VBA ti permette di impostare firme diverse per le risposte e gli inoltri. Segui attentamente i passaggi indicati di seguito:

1. Tieni premuti i tasti ALT + F11 per aprire la finestra di Microsoft Visual Basic for Applications.

2. Fai quindi clic su Inserisci > Modulo, copia e incolla il codice seguente nel modulo vuoto appena aperto; vedi screenshot:

Codice VBA: Imposta firme diverse per risposte e inoltri:

Public WithEvents GExplorer As Outlook.Explorer
Public WithEvents GMail As Outlook.MailItem
Public GFSO As Scripting.FileSystemObject
Public GTextStream As Scripting.TextStream
Public GText As String
Private Sub Application_Startup()
    Set GExplorer = Outlook.Application.ActiveExplorer
    Set GFSO = New Scripting.FileSystemObject
End Sub
Private Sub GExplorer_SelectionChange()
    Dim xItem As Object
    On Error Resume Next
    Set xItem = GExplorer.Selection.Item(1)
    If xItem.Class <> olMail Then Exit Sub
    Set GMail = xItem
End Sub
Private Sub GMail_Reply(ByVal Response As Object, Cancel As Boolean)
    InsertSignature Response, "Signature1.htm"   'change this signature name for replies
End Sub
Private Sub GMail_Forward(ByVal Forward As Object, Cancel As Boolean)
    InsertSignature Forward, " Signature2.htm"    'change this signature name for forwards
End Sub
Private Sub InsertSignature(Item As Object, SignName As String)
    Dim xSignatureFile As String
    Dim xMailItem As Outlook.MailItem
    xSignatureFile = CreateObject("WScript.Shell").SpecialFolders(5)
    xSignatureFile = xSignatureFile & "\Microsoft\Signatures\" & SignName
    Set GTextStream = GFSO.OpenTextFile(xSignatureFile)
    GText = ""
    GText = GTextStream.ReadAll
    If Item.Class <> olMail Then Exit Sub
    Set xMailItem = Item
    With xMailItem
        .Display
        .HTMLBody = .HTMLBody & "<br><br>" & GText
    End With
End Sub

Nota: nel codice riportato sopra, Signature1 e Signature2 sono i nomi delle due firme che desideri utilizzare rispettivamente per le risposte e gli inoltri. Modificali in base alle tue esigenze.

3. Sempre nella finestra di Microsoft Visual Basic for Applications, fai clic su Strumenti > Riferimenti per aprire la finestra di dialogo Riferimenti - Progetto1, quindi seleziona l’opzione Microsoft Scripting Runtime dall’elenco dei Riferimenti disponibili; vedi screenshot:

4. Fai quindi clic su OK per chiudere la finestra di dialogo. Da questo momento, ogni volta che risponderai a un messaggio, verrà inserita automaticamente Signature1; vedi screenshot:

E quando inoltrerai un messaggio, verrà inserita Signature2, come mostrato nello screenshot seguente: