Come contrassegnare automaticamente le email in base a un allegato specifico in Outlook?

Quando ricevi email con un allegato specifico e importante, potrebbe essere utile contrassegnarle per ritrovarle rapidamente e facilmente in seguito. In questo articolo ti mostrerò un metodo semplice per contrassegnare automaticamente le email i cui allegati hanno nomi specifici.

Contrassegna automaticamente le email in base a un allegato specifico con codice VBA

---

Contrassegna automaticamente le email in base a un allegato specifico con codice VBA

Per contrassegnare automaticamente le email che contengono un allegato specifico, applica il seguente codice VBA:

1. Avvia Outlook, quindi tieni premuti i tasti «ALT + F11» per aprire la finestra di Microsoft Visual Basic for Applications.

2. Nella finestra di «Microsoft Visual Basic for Applications», fai doppio clic su «ThisOutlookSession» nel riquadro "Project1 (VbaProject.OTM)" per aprire un nuovo modulo, quindi copia e incolla il codice seguente nel modulo vuoto.

Codice VBA: Contrassegna automaticamente le email in base a un allegato specifico:

Public WithEvents GMailItems As Outlook.Items
Private Sub Application_Startup()
    Set GMailItems = Outlook.Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub

Private Sub GMailItems_ItemAdd(ByVal Item As Object)
    If Item.Class <> olMail Then Exit Sub
    FlagEmail_SpecificAttachments Item
End Sub

Sub FlagEmail_SpecificAttachments(Mail As Outlook.MailItem)
    Dim xAttachment As Outlook.Attachment
    Dim xExt As String
    Dim xFileName As String
    If Mail.Attachments.Count = 0 Then Exit Sub
    For Each xAttachment In Mail.Attachments
        xExt = SplitPath(xAttachment.FileName, 2)
        xFileName = SplitPath(xAttachment.FileName, 1)
        Select Case xExt
            Case "txt", "xlsx", "docx", "pdf"
                If InStr(LCase(xFileName), LCase("KTO")) > 0 Then
                    With Mail
                        .ReminderSet = True
                        .ReminderTime = Now + 1
                        .MarkAsTask olMarkTomorrow
                        .Save
                    End With
                End If
        End Select
    Next
End Sub

Public Function SplitPath(FullPath As String, ResultFlag As Integer) As String
Dim xSplitPos As Integer, xDotPos As Integer
xSplitPos = InStrRev(FullPath, "/")
xDotPos = InStrRev(FullPath, ".")
Select Case ResultFlag
    Case 0
        SplitPath = Left(FullPath, xSplitPos - 1)
    Case 1
        If xDotPos = 0 Then xDotPos = Len(FullPath) + 1
        SplitPath = Mid(FullPath, xSplitPos + 1, xDotPos - xSplitPos - 1)
    Case 2
        If xDotPos = 0 Then xDotPos = Len(FullPath)
        SplitPath = Mid(FullPath, xDotPos + 1)
    Case Else
    Err.Raise vbObjectError + 1, "SplitPath Function", "Invalid Parameter!"
End Select
End Function

Nota: Nel codice riportato sopra, puoi personalizzare l’estensione del file e il nome dell’allegato in base alle tue esigenze.

3. Salva quindi il codice e riavvia Outlook per attivarne gli effetti. D’ora in poi, ogni volta che riceverai email con allegati il cui nome contiene il testo specificato, Outlook le contrassegnerà automaticamente per il follow-up; vedi screenshot: