Come rispondere normalmente dalla cartella Elementi inviati di Outlook?

Di norma, quando si fa clic su **Rispondi** nella cartella **Elementi inviati** per inviare un nuovo messaggio ai destinatari dell’email originale, il proprio indirizzo email appare nel campo **A**, come illustrato nello screenshot seguente. Questo può risultare fastidioso, poiché richiede di correggere manualmente il destinatario ogni volta. Come si può fare in modo che Outlook utilizzi l’indirizzo del destinatario originale anziché il proprio?

Rispondere normalmente nella cartella Elementi inviati da Outlook con la funzione Rispondi a tutti

Rispondere normalmente nella cartella Elementi inviati da Outlook con codice VBA

---

Rispondere normalmente nella cartella Elementi inviati da Outlook con la funzione Rispondi a tutti

In Outlook, la funzione Rispondi a tuttipuò aiutarti a risolvere questo problema; procedi come segue:

Quando devi rispondere a un'email inviata per reinviarla mantenendo l'indirizzo del destinatario originale, fai clic sul pulsante Rispondi a tutti, e l'indirizzo del destinatario originale apparirà nel campo A, come illustrato nello screenshot seguente:

---

Rispondere normalmente nella cartella Elementi inviati da Outlook con codice VBA

A volte potresti dimenticare di usare la funzione Rispondi a tutti quando rispondi a un messaggio inviato. Il codice VBA riportato di seguito ti consente di rispondere normalmente nella cartella Elementi inviati utilizzando semplicemente il pulsante Rispondi. Ecco come fare:

1. Tieni premuti i tasti ALT + F11 per aprire la finestra di Microsoft Visual Basic for Applications.

2. Nella finestra di Microsoft Visual Basic for Applications, fai doppio clic su ThisOutlookSession nel riquadro Project1 (VbaProject.OTM) per aprire il modulo, quindi copia e incolla il codice seguente nel modulo vuoto.

Codice VBA: Rispondere normalmente nella cartella Elementi inviati da Outlook:

Option Explicit
Private WithEvents GExplorer As Explorer
Private WithEvents GMailItem As MailItem
Private Sub Application_Startup()
    Set GExplorer = Application.ActiveExplorer
End Sub
Private Sub GExplorer_SelectionChange()
   On Error Resume Next
   Set GMailItem = GExplorer.Selection.Item(1)
End Sub
Private Sub GMailItem_Reply(ByVal Response As Object, Cancel As Boolean)
Dim xResponse As MailItem
Dim xRecipients As Outlook.Recipients
Dim xRecipient As Outlook.Recipient
Dim i As Integer
Dim xTo As String, xCC As String, xBCC As String, xName As String
On Error Resume Next
If Application.ActiveExplorer.CurrentFolder <> Session.GetDefaultFolder(olFolderSentMail) Then
    Exit Sub
End If
Cancel = True
Set xResponse = GMailItem.Reply
Set xRecipients = GMailItem.Recipients
For i = xRecipients.Count To 1 Step -1
    Set xRecipient = xRecipients.Item(i)
    xName = xRecipient.Name
    If Left(xName, 1) = "'" Then
        xName = Mid(xName, 2, Len(xRecipient.Name) - 2)
    End If
    Select Case xRecipient.Type
        Case olTo
            xTo = xName & ";" & xTo
        Case olCC
            xCC = xName & ";" & xCC
        Case olBCC
            xBCC = xName & ";" & xBCC
    End Select
Next
With xResponse
    .To = xTo
    .CC = xCC
    .BCC = xBCC
End With
xResponse.Recipients.ResolveAll
xResponse.Display
End Sub

3. Salva quindi il codice e riavvia Outlook affinché le modifiche abbiano effetto. Ora, quando fai clic su Rispondi per reinviare un'email nella cartella Elementi inviati, l'indirizzo del destinatario originale verrà visualizzato nel campo A, proprio come desideri.