Come mantenere la categoria quando si risponde o si inoltra un'email in Outlook?

Di norma, quando si risponde o si inoltra un'email categorizzata, la categoria viene automaticamente rimossa dal messaggio inviato. Se desideri mantenere la categoria nei messaggi in uscita durante la risposta o l’inoltro, questo articolo ti illustra un metodo efficace per risolvere il problema.

Mantieni la categoria durante la risposta o l'inoltro di un'email con codice VBA

---

Mantieni la categoria durante la risposta o l'inoltro di un'email con codice VBA

1. Tieni premuti i tasti ALT + F11 per aprire la finestra di Microsoft Visual Basic for Applications.

2. Nella finestra di Microsoft Visual Basic for Applications, fai doppio clic su ThisOutlookSession nel riquadro Project1 (VbaProject.OTM) per aprire il modulo, quindi copia e incolla il codice seguente nel modulo vuoto.

Codice VBA: Mantieni la categoria durante la risposta o l'inoltro di un'email:

Private WithEvents GExplorer As Outlook.Explorer
Private WithEvents GInspectors As Outlook.Inspectors
Private WithEvents GMailItem As Outlook.MailItem
Private GCategories As String
Private Sub Application_Startup()
    Dim xApp As Outlook.Application
    Set xApp = Outlook.Application
    Set GExplorer = xApp.ActiveExplorer
    Set GInspectors = xApp.Inspectors
End Sub
Private Sub GExplorer_SelectionChange()
    On Error Resume Next
    If TypeName(GExplorer.Selection.Item(1)) <> "MailItem" Then Exit Sub
    Set GMailItem = GExplorer.Selection.Item(1)
    GCategories = GMailItem.Categories
End Sub
Private Sub GInspectors_NewInspector(ByVal Inspector As Inspector)
    On Error Resume Next
    If TypeName(Inspector.CurrentItem) <> "MailItem" Then Exit Sub
   Set GMailItem = Inspector.CurrentItem
    GCategories = GMailItem.Categories
End Sub
Private Sub GMailItem_Forward(ByVal Forward As Object, Cancel As Boolean)
    Call GetCategories(Forward)
End Sub
Private Sub GMailItem_Reply(ByVal Response As Object, Cancel As Boolean)
    Call GetCategories(Response)
End Sub
Private Sub GMailItem_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Call GetCategories(Response)
End Sub
Private Sub GetCategories(ByVal NewMail As Object)
    If NewMail.Class <> olMail Then Exit Sub
    NewMail.Categories = GCategories
End Sub

3. Salva e chiudi questa finestra del codice, quindi chiudi e riavvia Outlook. D'ora in poi, quando risponderai o inoltrerai un'email con una categoria assegnata, la categoria verrà mantenuta nel messaggio in uscita nella cartella Elementi inviati; vedi lo screenshot: