Come si fa a eliminare tutte le categorie da Outlook?

Supponiamo che numerosi elementi in Outlook siano associati a categorie colorate. Se devi rimuovere tutte queste categorie dagli elementi, come puoi farlo in modo rapido e semplice in Outlook?

Elimina tutte le categorie da una cartella specifica con la funzione Elimina tutte le categorie

Elimina tutte le categorie da un account specifico con codice VBA

---

Elimina tutte le categorie da una cartella specifica con la funzione Elimina tutte le categorie

Se devi semplicemente eliminare le categorie da una cartella specifica, procedi nel seguente modo:

1. Fai clic sulla cartella da cui desideri rimuovere le categorie colore, quindi premi Ctrl + A per selezionare tutti gli elementi.

2. Fai quindi clic con il pulsante destro del mouse e scegli Categorizza > Elimina tutte le categorie dal menu contestuale, vedi screenshot:

3.In questo modo, tutte le categorie colore presenti in questa cartella specifica sono state eliminate contemporaneamente.

---

Elimina tutte le categorie da un account specifico con codice VBA

Per eliminare tutte le categorie da tutti gli elementi – ad esempio messaggi di posta elettronica, attività, contatti, note e così via – di un account, il codice VBA seguente ti sarà di aiuto:

1. Fai clic su un messaggio dell’account da cui desideri rimuovere tutte le categorie, quindi premi e tieni premuti i tasti ALT + F11 per aprire la finestra di Microsoft Visual Basic for Applications.

2. Fai clic su Inserisci > Modulo, quindi incolla la macro seguente nella finestra del Modulo.

Codice VBA: Elimina tutte le categorie da un account specifico:

Sub BatchClearAllCategories_AllOutlookItems()
    Dim xCurrentFolder As Outlook.Folder
    Dim xFolder As Folder, xCurFolder As Folder
    Dim xPos As Integer
    Dim xRootFldName As String
    Set xCurFolder = Outlook.ActiveExplorer.CurrentFolder
    xPos = InStr(3, xCurFolder.FolderPath, "\")
    If xPos > 0 Then
        xRootFldName = Mid(xCurFolder.FolderPath, 3, xPos - 3)
    Else
        xRootFldName = Mid(xCurFolder.FolderPath, 3, Len(xCurFolder.FolderPath) - 2)
    End If
    Set xCurrentFolder = Outlook.Application.Session.Folders(xRootFldName)
    For Each xFolder In xCurrentFolder.Folders
        Call ProcessFolders(xFolder)
    Next
    MsgBox "Clear completed!", vbInformation + vbOKOnly, "Kutools for Outlook"
End Sub
Sub ProcessFolders(ByVal CurFld As Outlook.Folder)
    Dim xItem As Object
    Dim i As Integer
    Dim xSubfolder As Outlook.Folder
    If CurFld.Items.Count > 0 Then
        For i = CurFld.Items.Count To 1 Step -1
            Set xItem = CurFld.Items.Item(i)
            xItem.Categories = ""
            xItem.Save
        Next
    End If
    If CurFld.Folders.Count = 0 Then Exit Sub
    For Each xSubfolder In CurFld.Folders
        Call ProcessFolders(xSubfolder)
    Next
End Sub

3. Premi quindi il tasto F5 per eseguirlo; verrà visualizzata una finestra di avviso che ti informa che tutte le categorie dell’account selezionato sono state eliminate, vedi screenshot: