Come si fa a importare i compleanni da Excel nel calendario di Outlook?

Se si ha un lungo elenco di compleanni in un foglio di lavoro e si desidera importarli nel calendario di Outlook come eventi, quali sono i metodi più rapidi per farlo?

---

Importa i compleanni da Excel nel calendario di Outlook con codice VBA

Di norma, non esiste un metodo diretto per importare i compleanni nel calendario di Outlook. Per risolvere questo problema, ho creato un codice VBA: procedi come segue.

1. Apri il foglio di lavoro contenente i compleanni da importare in Outlook, quindi premi contemporaneamente i tasti ALT + F11 per aprire la finestra di Microsoft Visual Basic for Applications.

2. Fare clic su Inserisci > Modulo, quindi incollare il codice seguente nella finestra del modulo.

Codice VBA: Importa i compleanni nel calendario di Outlook

Sub ImportBirthdaysToCalendar()
'Updateby ExtendOffice
Dim xWs As Excel.Worksheet
Dim xRng As Range
Dim xOlApp As Outlook.Application
Dim xCalendarFld As Outlook.Folder
Dim xAppointmentItem As Outlook.AppointmentItem
Dim xRecurrencePattern As Outlook.RecurrencePattern
Dim xRow As Integer
On Error Resume Next
Set xWs = ThisWorkbook.ActiveSheet
Set xRng = Application.InputBox("Please select the data range (only two columns):", "Kutools for Excel", , , , , , 8)
If xRng Is Nothing Then Exit Sub
If xRng.Columns.Count <> 2 Then
  MsgBox "You can only select two columns", vbOKOnly + vbCritical, "Kutools for Excel"
  Exit Sub
End If
Set xOlApp = CreateObject("Outlook.Application")
Set xCalendarFld = xOlApp.Session.GetDefaultFolder(olFolderCalendar)
For xRow = 1 To xRng.Rows.Count
  Set xAppointmentItem = xCalendarFld.Items.Add("IPM.Appointment")
  With xAppointmentItem
    .Subject = xRng.Cells(xRow, 1) & Chr(39) & "s Birthday"
    .AllDayEvent = True
    .Start = xRng.Cells(xRow, 2)
    Set xRecurrencePattern = .GetRecurrencePattern
    xRecurrencePattern.RecurrenceType = olRecursYearly
    .Save
  End With
Next
Set xWs = Nothing
Set xCalendarFld = Nothing
Set xOlApp = Nothing
End Sub

3. Sempre nella finestra di Microsoft Visual Basic for Applications, fai clic su Strumenti > Riferimenti. Nella finestra di dialogo Riferimenti – VBAProject visualizzata, seleziona l’opzione Microsoft Outlook 16,0 Object Library dall’elenco dei Riferimenti disponibili, come mostrato nello screenshot:

4. Fare quindi clic su OK per chiudere la finestra di dialogo. Ora premere il tasto F5 per eseguire il codice; verrà visualizzata una finestra di richiesta in cui selezionare le colonne relative a nome e data di nascita, come mostrato nello screenshot:

5. Fare quindi clic sul pulsante OK; i compleanni verranno immediatamente importati nel calendario di Outlook. Avvia Outlook per visualizzare il risultato, come mostrato nello screenshot: