Come spostare automaticamente i diversi tipi di elementi eliminati in cartelle specifiche in Outlook?

In Outlook, tutti i tipi di elementi eliminati (messaggi, attività, contatti, ecc.) finiscono nella cartella Elementi eliminati. Se si vuole organizzarli automaticamente in sottocartelle distinte in base al tipo di elemento, come illustrato nell’immagine seguente, come si può configurare questa impostazione in Outlook?

---

Sposta automaticamente diversi tipi di Elementi eliminati in cartelle diverse con codice VBA

Il codice VBA seguente consente di spostare automaticamente i Elementi eliminati in cartelle diverse; procedere come segue:

1. Avvia Outlook, quindi tieni premuti i tasti ALT + F11 per aprire la finestra di Microsoft Visual Basic for Applications.

2. Dopodiché, fai doppio clic su ThisOutlookSession nel riquadro Progetto - Progetto1, quindi copia e incolla il codice seguente nella finestra vuota del codice:

Codice VBA: Sposta automaticamente diversi tipi di Elementi eliminati in cartelle diverse

Public WithEvents GDeletedFolder As Outlook.Folder
Public WithEvents GDeletedItems As Outlook.Items
Private Sub Application_Startup()
  Set GDeletedFolder = Application.Session.GetDefaultFolder(olFolderDeletedItems)
  Set GDeletedItems = GDeletedFolder.Items
End Sub
Private Sub GDeletedItems_ItemAdd(ByVal Item As Object)
'Updateby ExtendOffice
Dim xTargetFolder As Outlook.Folder
On Error Resume Next
Select Case TypeName(Item)
  Case "MailItem", "PostItem", "ReportItem", "MeetingItem"
    Set xTargetFolder = GDeletedFolder.Folders("Deleted Mails")
    If xTargetFolder Is Nothing Then
      Set xTargetFolder = GDeletedFolder.Folders.Add("Deleted Mails", olFolderInbox)
    End If
  Case "AppointmentItem"
    Set xTargetFolder = GDeletedFolder.Folders("Deleted Appointments")
    If xTargetFolder Is Nothing Then
      Set xTargetFolder = GDeletedFolder.Folders.Add("Deleted Appointments", olFolderCalendar)
    End If
  Case "ContactItem", "DistListItem"
    Set xTargetFolder = GDeletedFolder.Folders("Deleted Contacts")
    If xTargetFolder Is Nothing Then
      Set xTargetFolder = GDeletedFolder.Folders.Add("Deleted Contacts", olFolderContacts)
    End If
  Case "TaskItem"
    Set xTargetFolder = GDeletedFolder.Folders("Deleted Tasks")
    If xTargetFolder Is Nothing Then
      Set xTargetFolder = GDeletedFolder.Folders.Add("Deleted Tasks", olFolderTasks)
    End If
  Case "JournalItem"
    Set xTargetFolder = GDeletedFolder.Folders("Deleted Journals")
    If xTargetFolder Is Nothing Then
      Set xTargetFolder = GDeletedFolder.Folders.Add("Deleted Journals", olFolderJournal)
    End If
  Case "NoteItem"
    Set xTargetFolder = GDeletedFolder.Folders("Deleted Notess")
    If xTargetFolder Is Nothing Then
      Set xTargetFolder = GDeletedFolder.Folders.Add("Deleted Notess", olFolderNotes)
    End If
End Select
If xTargetFolder Is Nothing Then Exit Sub
Item.Move xTargetFolder
Set xTargetFolder = Nothing
End Sub

3. Salva quindi questo codice e riavvia Outlook per attivarlo.

4. D'ora in poi, ogni volta che elimini un elemento, verrà spostato automaticamente nella cartella corrispondente al suo tipo all'interno della cartella Elementi eliminati.

5. Per visualizzare il risultato, fai clic sull’icona in fondo al riquadro delle cartelle, quindi su Cartelle per espandere tutte le cartelle nel riquadro. Vedi le immagini seguenti: